Section - The Historian and the Market
Room3 is a rebelcity-room. The description of Room3 is "The buildings here are in poorer repair, the streets dirtier. Tiny shops cram the sidewalk here, [if Islander Bombing is happening]now suddenly shuttered and silent[otherwise]throngs of people going in and out[end if]. [A sentence about a rebelcity room].[paragraph break]A small dark [d]alley[x] cuts down a trash-strewn street. [exits].". Understand "alley" as inside when location is Room3.
The historian is a person in Room3. "[if histdone is true]Sitting[else]Standing[end if] on the street corner is [if Room3 is unvisited]a man you take for a [o]beggar[x][otherwise]a [o][historian][x][end if][if histdone is false], orating in a booming voice[end if].". Understand "beggar/begger" or "man" as historian. The printed name is "beggar". The description is "Dressed in a strange costume of fraying old clothes and patches of rag, the [historian] seems oblivious to the pedestrians passing by him[if histdone is false]: he orates in a loud, clear voice, gesturing dramatically into the air as he speaks[else if historian is attentive]: he gives you his full attention[end if].".
Before going when historian is attentive: post-conversation processing; if last beat is in HC, say "'May your thoughts be free,' he says as you leave.".
The cup is an open undescribed container in Room3. It is not openable. Check taking the cup: say "That belongs to [the historian]." instead. Check taking something enclosed by the cup: say "That belongs to [the historian]." instead. Instead of inserting something uncoinlike into the cup, say "Probably the only thing he wants in there is money.". Definition: a thing is uncoinlike if it is not a coin.
Instead of greeting historian when Historian Conversation is not happening and histdone is false: say "He smiles and nods to you, but continues speaking.". Instead of greeting historian when Historian Conversation is not happening and histdone is true: say "He smiles at you. 'Your historian's just taking a break for a moment, since business is slow,' he says in a friendly tone, stretching and somehow managing to discreetly draw your attention to his cup, filled with a handful of coins.". Instead of greeting historian: force discuss hc_who.
[6 / 4 / 4 / 7]
Every turn when location is Room3 and historian is idle and historian is enclosed by Room3: say "[one of]'But cried she not with tears, poor Widow Tall,' he says, 'poor Widow Tall through long nights['] storm and mourning,
And Weaver's eyes were blind, put out by flame, put out by flame in Builder's last endeavor.'[or]The [historian] continues: 'So blinded was he shunned and cast away, and cast away by all those then remaining,
And cried at last the sky in ceaseless rain, in ceaseless rain did Greeneye's old ties sever.'[or]The [historian] continues: 'Alone he sailed away did Weaver Green, did Weaver Greeneyes vanish into Ocean,
But stayed he not alone in years to come, in years to come when cowards sought him ever.'[or]The [historian] continues: 'And Widow Tall was left alone to mourn, alone to mourning and her children's tending; The mourners in the town wept tears for her, wept tears for her, whose own eyes did not quiver.'[or]The [historian] continues: 'For from her grief great thoughts began to form, began to form like rainclouds all a'storming.
And so she called on one she trusted strong, she trusted strong her ally Quick the Counter.'[or]The [historian] continues: 'She asked him for a quill and precious ink, and precious ink and page to be inscribed on.
And Counter Quick said, [']But, my Widow Tall, my Widow Tall, the ink is frozen over.[']'[line break][or]The [historian] continues: 'And Widow Tall replied, [']Then make a flame, then make a flame, my Counter Quick, and quickly.
My Builder's words remain. I must write soon, I must write soon to save his words forever.[']'[line break][or][historydone]The [historian] bows to no one in particular, sits on the curb, and begins smoking a small pipe reflectively.[or][stopping]". histdone is a truth state that varies. To say historydone: now histdone is true.
Instead of giving a coin to historian: say trygivingcoin.
To say trygivingcoin:
if the player holds at least one coin:
if the historian is visible:
move a random coin held by player to cup;
now historian is attentive;
force discuss hc_intro;
else if the hopper is visible:
try inserting a random coin held by player into the hopper;
let bob be a random visible other person;
if bob is a person:
try giving a random coin held by player to bob;
say "You aren't sure how to spend your money here.";
say "You don't have any coins left.".
Understand "toss coin" or "add coin" or "throw coin" or "throw coin to/in/at cup" as a mistake ("[trygivingcoin]").
Instead of exhausting when historian is enclosed by location: say "'We've done that one already, haven't we, friend?' he says.".
Historian Conversation is a recurring scene.
Historian Conversation begins when
a coin is in the cup and historian is enclosed by location and historian is attentive.
Historian Conversation ends when
historian is idle.
To historian cashes in:
remove a random coin enclosed by cup from play.
[The historian has full conversations for Weaver Greeneyes and Builder Tall. There are two other conversations which can randomly be assigned to other colonists requested. (The number of stories is limited by the coins the player carries.) In the rare case a third non-key figure is requested, the historian can refuse the coin, saying he's packing up to go.]
HC is a thread.
hc_intro is a repeatable beat in HC with reaction "The old man nods to you. 'Many thanks for helping out a poor historian, sir,' he says.". hc_intro enqueues hc_who. After discussing hc_intro: change the printed name of historian to "historian"; continue the action.
hc_who is a repeatable beat in HC with reaction "[one of]He chuckles. 'You're a little old, aren't you? But no, one's never too old for history. Well then. [or]'Good to see you again,' he says. 'Now then. [stopping]Who would you like to [hc_who2]?'". hc_who suggests hc_who2. hc_who summons hc_builder1, hc_rosehair, hc_greeneyes.
Understand "meet" as hc_who2 when last beat is in HC. hc_who2 is a repeatable beat in HC with keyword name "meet" and reaction "'Builder [hc_builder1], maybe?' he suggests. 'Always a favorite. Or what about old Mother [hc_rosehair] and the river?'".
First carry out getting bored during Historian Conversation: say "'My pardon,' the historian says cordially, '[if histdone is true]I'm going to get back to my break, if you don't mind.' He sits back down, knees cracking noisily, and sighs.[otherwise]I need to get back to work.'[end if]" instead.
Understand "builder tall" or "builder/tall" as hc_builder1 when last beat is in HC. hc_builder1 is a beat in HC with keyword name "Tall" and fuse 6 and reaction "'Ah,' he says, 'an old favorite. Well, then, have patience. He'll be with you in just a moment.'[paragraph break]The historian bows his head and shifts from foot to foot for a moment, rubbing his hands together.[paragraph break]When he raises his head, he seems like a different person: taller, stronger, more confident. 'The [t]winter[x] has been long and hard, Planter,' he says wearily. 'Please say you bring me news of [t]spring[x].'". hc_builder1 cancels hc_rosehair, hc_greeneyes, hc_who2. hc_builder1 summons hc_bplanter. After discussing hc_builder1: historian cashes in; continue the action.
Understand "winter/spring" as hc_bplanter when last beat is in HC. hc_bplanter is a terminal beat in HC with keyword name "winter, spring" and reaction "Over the course of the next few minutes, you speak with 'Builder Tall'-- at least this historian's rendition of him. You learn a lot about the man who seems to have been the foundation of this society: a man who was willing to lead when none of his companions dared to, and through action and decision saved the life of the struggling, treeless survivors.[paragraph break]Finally, the historian makes one last eloquent pronouncement, then stops and smiles at you, doffing his cap. 'Thanks, friend,' he says.".
Understand "mother rosehair" or "mother/rosehair" as hc_rosehair when last beat is in HC. hc_rosehair is a beat in HC with keyword name "Rosehair" and fuse 6 and reaction "'Yes,' he says, smiling, 'an old favorite. Just a moment, then, let me wake up old Mother for you.'[paragraph break]He bows his head and flexes his fingers, breathing slowly for a long moment.[paragraph break]When he raises his head, he suddenly seems different: old and wiry, but with wits and eyes of steel, and his voice is the warbling alto line of an elderly woman. 'Good of you to visit an old widow, [t]Counter[x],' the historian says, a sparkle in his eye, 'but not often do visitors climb down the long hill to my house by the [t]river[x]. What is it you want?'". hc_rosehair summons hc_rosehair2. hc_rosehair cancels hc_builder1, hc_who2. After discussing hc_rosehair: historian cashes in; continue the action.
Understand "counter/river" as hc_rosehair2 when last beat is in HC. hc_rosehair2 is a terminal beat in HC with keyword name "Counter, river" and reaction "Over the course of a few minutes, you speak with 'Mother Rosehair'-- or at least the historian's rendition of her. You hear firsthand a tale which you gather has become a sort of bedtime story here: how the strong-willed old widow of Builder Tall refused to abandon her house by the river even as the river waters rose higher and higher and threatened to flood. She would stay in the house that Counter had built for her, and would let what happened happen. The river did not flood, and the story seems to have become a sort of parable for sticking to your principles.[paragraph break]Finally, the historian makes one wry point, stops, then smiles at you, himself again, and doffs his cap. 'Thanks, friend,' he says.".
Understand "greeneyes/greeneye/weaver" or "green eye" or "green eyes" as hc_greeneyes when last beat is in HC. hc_greeneyes is a repeatable beat in HC with keyword name "Greeneyes" and fuse 6 and reaction "The historian's smile fades a little. He glances quickly up and down the street. 'Not the best of times for that piece of history, friend,' he says quietly. 'But I believe all history should be told, even that which isn't popular. There are some who disagree.'[paragraph break]He looks are you sharply. 'Are you sure, then?'". hc_greeneyes suggests hc_greeneyesno. Instead of saying no or saying maybe when last beat is hc_greeneyes, force discuss hc_greeneyesno. Instead of saying yes when last beat is hc_greeneyes, force discuss hc_greeneyes1. hc_greeneyes summons hc_greeneyesno, hc_greeneyes1. After discussing hc_greeneyes: historian cashes in; continue the action. hc_greeneyes cancels hc_who2.
hc_greeneyesno is a beat in HC with keyword name "no" and reaction "He seems both relieved and a little disappointed. 'Probably for the best,' he says. 'Now, is there anyone else you want to meet?'". hc_greeneyesno cancels hc_greeneyes1. hc_greeneyesno summons hc_greeneyes, hc_builder1, hc_rosehair.
Instead of getting bored when last beat is hc_greeneyesno or last beat is hc_who or last beat is hc_who2, force discuss hc_credit.
hc_credit is a repeatable terminal beat in HC with reaction "'You just let me know when you've decided,' the historian says, tapping his cup. 'You've got credit now.'".
HGE is a thread.
hc_greeneyes1 is a beat in HGE with keyword name "yes" and reaction "He nods. Glancing again quickly up and down the street, he shakes his arms, then bows his head.[paragraph break]When he raises it, his face is changed: shrewder, eyes half-squints, voice smooth and sweet. But though it is a surprising change, you sense at once that it is not a simple villain, a caricature. There is depth, and, you sense, authenticity behind the performance.[paragraph break]'Builder,' he says, in a droning, sardonic voice, 'I've been expecting you. I know [hc_gewhy] you have come.'". hc_greeneyes1 summons hc_gewhy. hc_greeneyes1 suggests hc_gewhy. hc_greeneyes1 cancels hc_builder1, hc_rosehair.
Understand "why" as hc_gewhy when last beat is in HGE. hc_gewhy is a beat in HGE with keyword name "why" and reaction "'Yes,' he says sweetly, pacing. 'You come to accuse me of whispering against you in the fields. You come to accuse me of slandering your name in the Hall. You come to accuse; not to question, not to reason. You come to have your way. Do you deny it?'". hc_gewhy summons hc_whyyes, hc_whyno. The yes-beat of hc_gewhy is hc_whyyes. The no-beat of hc_gewhy is hc_whyno. hc_gewhy suggests hc_gehistory.
hc_whyyes is a beat in HGE with keyword name "yes" and reaction "'Then you are a liar,' the historian says simply, but there is no hate in the words.". hc_whyyes enqueues hc_gehistory. hc_whyyes cancels hc_whyno.
hc_whyno is a beat in HGE with keyword name "no" and reaction "'Good,' the historian says, nodding. 'Then we shall come straight to it.'". hc_whyno enqueues hc_gehistory. hc_whyno cancels hc_whyyes.
hc_gehistory is a beat in HGE with reaction "'You think I despise you,' he says, pacing. 'You think I am jealous. Again you are wrong. I merely wonder when. When, Builder, when your reign will end.'[paragraph break]'I have not forgotten,' he says before you can respond, 'our first winter. When we froze in those rude huts on the riverbank, [hc_leaderless] and afraid, paralyzed by our inability to act, to think for ourselves. We thought at first it had perhaps been [hc_bred] out of us. We thought without Forest we could not survive.'". hc_gehistory suggests hc_greeneyes3. hc_gehistory summons hc_leaderless, hc_bred. hc_greeneyes3 replaces hc_gehistory.
Understand "leaderless/leader" as hc_leaderless when last beat is hc_gehistory. hc_leaderless is a beat in HGE with keyword name "leaderless" and reaction "'How foolish we were,' the historian says bitterly, 'how naive. Do you remember, Builder? How for days we sat near the wreckage, starving and fearful, pitifully planting the burned seeds and waiting in vain for them to grow? How for weeks the thought did not even enter our heads that without them, we would have to make decisions for ourselves, shape our own destinies?'". hc_leaderless enqueues hc_greeneyes3.
Understand "bred/breed" as hc_bred when last beat is hc_gehistory. hc_bred is a beat in HGE with keyword name "bred" and reaction "'Yes, bred out,' he says bitterly, 'generation after generation selected not for their ability to think, but to follow orders; not to speak, but to hear. That is the history of our race, Builder, until that winter. Until us.'". hc_bred enqueues hc_greeneyes3
hc_greeneyes3 is a beat in HGE with reaction "'But then you, Builder, came to our rescue,' the historian continues, voice dripping with sarcasm. 'You volunteered to make our decisions, knowing that they must stand, unapproved, unvetted by any higher guidance, by any great minds whispering in your ear. That your rules and [hc_laws] would decide who would live and who would die. That all the blame should your plans fail would fall squarely on your shoulders. So noble you were, so heroic. And the [hc_others] stumbled over themselves in their haste to agree.'". hc_greeneyes3 suggests hc_greeneyes4. hc_greeneyes4 replaces hc_greeneyes3. hc_greeneyes3 summons hc_others, hc_laws.
Understand "law/laws" as hc_laws when last beat is hc_greeneyes3. hc_laws is a beat in HGE with keyword name "laws" and reaction "'So fair, so practical,' nods the historian, only a hint of irony in his voice. 'None could complain. [']None shall harm none,['] yes, very good, very good. [']All shall help all,['] very nice. [']All shall obey the Leader;['] now that's where it gets interesting, Builder. And nothing there about how one becomes a leader, is there? For another time such laws will be written, perhaps. A safer time. But when will that be?'". hc_laws enqueues hc_greeneyes4.
Understand "others" as hc_others when last beat is hc_greeneyes3. hc_others is a beat in HGE with keyword name "others" and reaction "He smiles wryly. 'Fools,' he says, 'panting like dogs, wagging their tails in glee that another would finally think for them. And no, Builder, I have not forgotten that the vote was unanimous. Already I sensed something wrong in your visage; something that wanted this new power too forcefully. But how could I speak otherwise? How could I, when all faces were turned in slavish devotion to you? When your honeyed words sweetened the poison of your act for all the others, no choice was left for me at all.' He spits.". hc_others enqueues hc_greeneyes4.
hc_greeneyes4 is a beat in HGE with reaction "'Now thirteen babes have been born ere that dark winter,' the historian says. 'We have built strong houses, sown lusty crops. The danger is past. And yet still you lead us. The others are happy to let you, Builder, but not I. It is a return to the old ways. It is a betrayal of our Pact, to live as free people.'[paragraph break]He steps up to you, close, eyes searching yours intently. 'Would you plant yourself in a Hall of Rulers, Builder?' he asks quietly. 'The first great tree of this new world? Would you arch over your saplings forever?'". hc_greeneyes4 suggests hc_greeneyes5no. The yes-beat of hc_greeneyes4 is hc_greeneyes5yes The no-beat of hc_greeneyes4 is hc_greeneyes5no. hc_greeneyes4 summons hc_greeneyes5yes, hc_greeneyes5no.
Understand "never" as hc_greeneyes5no when last beat is in HGE. hc_greeneyes5no is a beat in HGE with keyword name "never" and reaction "He smiles, and shakes his head sadly. 'No,' he says, 'of course you do not think so. Just as Forest thinks nothing of its dominion over our kind. Just as even we did not realize what had been done to us until---'". hc_greeneyes5no enqueues hc_greeneyesend.
hc_greeneyes5yes is a beat in HGE with keyword name "yes" and reaction "The historian's eyes widen and he steps back. 'Then you've planned this all along,' he whispers, 'you knew, even from the beginning, that it would never be temporary-- that you would hold on to your power, always be leader, always---". hc_greeneyes5yes enqueues hc_greeneyesend.
hc_greeneyesend is a terminal beat in HGE with reaction "He breaks off, suddenly, and looks with alarm down the street. Several soldiers are ambling slowly in your direction, eyes on the historian.[paragraph break]He turns to you quickly. 'Sorry, friend,' he says, grabbing his cup, 'history will have to wait.' And he turns and walks quickly down the street in the opposite direction. The soldiers watch him for a moment, then turn and resume their patrol.". After discussing hc_greeneyesend: remove historian from play; remove cup from play.
Instead of attacking historian when last beat is in HGE, say "The historian leaps backwards, dropping character. 'Calm down,' he says, waving his arms, 'I'm just a historian! ".
Understand "builder/tall" as hc_tall. hc_tall is a beat in HC with reaction "The historian smiles, perhaps a little too broadly. 'Builder Tall,' he says, 'everyone's favorite. All right then, [if player is male]sir[otherwise]madam[end if], prepare to meet our illustrious founder.' The historian bows his head, then quickly raises it, slipping into a role you can tell he's played many times before.[paragraph break][as the parser]BETA: Unfortunately, this conversation has not yet been written.[as normal]". hc_already replaces hc_tall.
hc_already is a repeatable beat in HC with reaction "'Oh, but you've already heard that one,' the historian says. 'Come on, someone else.'".
Every turn when location is Room3 and historian is in Room3 and historian is idle and Historian Conversation is not happening and a random chance of 1 in 2 succeeds and histdone is false: say "[one of][moneygive][or][learnhistorianname][or][moneygive][stopping]". To say moneygive: say "[one of]A passer-by[or]An old woman[or]A well-dressed man[or]Someone[at random] [one of]tosses a coin in[or]drops a coin into[or]adds a coin to[or]puts in coin in[or]tosses a few coins in[at random] the [historian]'s cup.". To say learnhistorianname: say "'Look, matron, a historian!' cries out a little girl passing by in delight; the woman holding her hand shushes her and smiles at the beggar as they continue down the street."; change the printed name of the the historian to "historian".