Blue Lacuna — 269 of 467
Aaron A. Reed
Section - Description
The description of Progue is "[description-Progue]".
To say description-Progue:
if Progue is wishing:
if an unimportant episode is playing, say "He looks like he's on his way somewhere.";
else say "He's engrossed in the conversation.";
stop;
repeat through Table of Progue's Description:
if there is an episode entry and current episode is episode entry:
say "[desc entry]";
unless the animus of Progue is resting or the psyche of Progue is emotional:
if ( an episode is playing and current episode is serendipitous ) or no episode is playing, say "[paragraph break][Progue-mood-summary]";
stop;
repeat through Table of Progue's Description:
if there is an animus entry and animus entry is the animus of Progue:
say "[desc entry]";
unless the animus of Progue is resting or the psyche of Progue is emotional:
if ( an episode is playing and current episode is serendipitous ) or no episode is playing, say "[paragraph break][Progue-mood-summary]";
stop;
say "He is a tall and spindly figure whose age has been clouded by castaway years to become unsure and irrelevant, bleached hair and bushy eyebrows lifting a contented face scrubbed clean by sea breeze and sunlight. He wears pants that were once white, and a shirt that was once blue but now falls in grey threadbare tatters and streams from bony arms and scratched elbows, a dancer's costume twirling alike with the breeze and his jittery movements. These seem focused in his large, rough hands, as if they house some sleeping power that swells joints and sharpens sinews in constant, futile struggle to escape.".
Table of Progue's Description
| animus | episode | desc |
| ruminating | -- | "[The Progue] sits on [Progue's perch], seemingly lost in thought." |
| resting | -- | "[if the psyche of Progue is emotional]His skin is pale and clammy, and his breathing labored. He does not look well[otherwise]Sleeping deeply, he seems at first glance the picture of a shipwreck victim: faded and torn rags akimbo on bony joints, long hair touched with grey, matted and thinning, and a sun-worn face.[paragraph break]Even in rest, however, there is some vague power in his figure, some animus that decrepitude has yet to touch[end if]." |
| fishing | -- | "[The Progue] trolls the shallows along the lagoon with a crude line, eyes focused intently on the tiny shapes darting through the water near his ankles." |
| swimming | -- | "Bobbling like a tan cork on the waves, [the Progue] floats serenely, eyes shut, a faint smile on his face." |
| mending | -- | "[The Progue], perched on [Progue's perch], mends his clothes with a needle and thread." |
| hand-standing | -- | "He seems to be utterly enjoying himself." |
| cleaning | -- | "He has made good headway already, throwing everything hopelessly corroded or damaged into a pile and sorting and ordering what's left, while scrubbing the years of dirt and neglect from the workbench." |
| paint-making | -- | "Dotted with specks of color and drenched in sweat, he nevertheless seems cheerful as he mixes the crushed ingredients you brought him in a large pot." |
| frog-catching | -- | "Crawling through the marsh heedless of the muck and grime, [the Progue] is focused intently on [if caught-frog is true]the small frog caught in the cage of his hands[otherwise]the ground, moving his attention slowly from one clump of grass and rocks to another[end if]." |
| beach-combing | -- | "He seems intent on his task, which seems to be nothing less than keeping the entire beach immaculately spotless." |
| hottubbing | -- | "[The Progue] seems to enjoy the hot, swirling waters of the spring." |
| convalescing | -- | "His skin is pale, and he looks incredibly weak. You are not sure he is going to survive." |
| stoicising | -- | "Some inner strength has returned. He looks down at his hands and rubs his fingertips together, and the faintest touch of a smile reaches his lips." |
[ Examining Progue reveals information about his internal state.]
To say Progue-mood-summary:
say "He ";
if submission of Progue is 8 begin; say "practically grovels, flinching at your every sudden move, but";
otherwise if submission of Progue >= 6; say "rubs his hands nervously, watching your every move for cues, and";
otherwise if submission of Progue >= 4; say "stands back a few feet from you respectfully and";
otherwise if submission of Progue >= 2; say "seems hesitant and ready to defer to you, but";
otherwise if submission of Progue >= -1; say "seems a bit out of sorts around you, and";
otherwise if submission of Progue >= -3; say "seems to know what he is doing, and";
otherwise if submission of Progue >= -5; say "seems confident and in command of the situation, and";
otherwise if submission of Progue >= -7; say "commands a wide arc of personal space, and";
otherwise if submission of Progue is -8; say "seems to tower over you commandingly and";
end if;
say " [one of]regards[or]fixes[in random order] you with ";
if romance of Progue > 0 begin;
if romance of Progue is 1, say "a wink";
if romance of Progue is 2, say "a cocky smirk";
if romance of Progue is 3, say "a knowing smile and raised eyebrow";
if romance of Progue is 4, say "a flirtatious smile";
if romance of Progue >= 5, say "a contented, twitterpated smile";
if romance of Progue < -1, say "a dirty, hateful glance";
otherwise;
if affinity of Progue is 8, say "the trusting smile of a lifelong friend";
if affinity of Progue is 7, say "a trusting smile that reaches his eyes";
if affinity of Progue is 6, say "genuine friendliness";
if affinity of Progue is 5, say "a sparkling grin";
if affinity of Progue is 4, say "a friendly smile";
if affinity of Progue is 3, say "a guarded smile";
if affinity of Progue is 2, say "an amused smirk";
if affinity of Progue is 1, say "one corner of his mouth lifted";
if affinity of Progue is 0, say "an indifferent expression";
if affinity of Progue is -1, say "a raised eyebrow";
if affinity of Progue is -2, say "a look of annoyance";
if affinity of Progue is -3, say "a frown";
if affinity of Progue is -4, say "narrowed eyes";
if affinity of Progue is -5, say "unconcealed anger";
if affinity of Progue is -6, say "contempt";
if affinity of Progue is -7, say "a look of hatred";
if affinity of Progue is -8, say "a look of total hatred";
end if;
if paternalism of Progue > 1 begin;
if paternalism of Progue is 8 begin; say ", ";
otherwise if paternalism of Progue >= 6; say ", like ";
otherwise if paternalism of Progue >= 4; say ", almost like ";
otherwise; say ", reminding you a bit of ";
end if;
say "a";
if affinity of Progue > 4 begin; say " proud father";
otherwise if affinity of Progue >= 0; say " father figure";
otherwise if affinity of Progue >= -5; say " disappointed father";
otherwise; say "n angry father";
end if;
end if;
say ".";
continue the action.