Blue Lacuna — 268 of 467
Aaron A. Reed
Section - Initial Appearance
The initial appearance of Progue is "[initialapp-Progue]".
Before writing a paragraph about Progue when Progue is wishing (this is the don't describe Progue when he's about to move rule): now Progue is mentioned. [Since we'll be describing him moving anyway, omit printing an initial appearance.]
To say initialapp-Progue:
repeat through Table of Progue's Initial Appearance:
[say "**[episode entry] (curr is [current episode]: [if current episode is episode entry]Y[else]N[end if])**[line break]";]
if there is an episode entry and current episode is episode entry:
say desc entry;
stop;
repeat through Table of Progue's Initial Appearance:
if there is an animus entry and animus entry is the animus of Progue:
say desc entry;
stop;
say "[The Progue] is here[if Progue is being debugged] ([animus of Progue])[end if].".
Table of Progue's Initial Appearance
| animus | episode | desc |
| fishing | an episode | "[The Progue] is here, trolling the shallows near the beach with a fishing line." |
| ruminating | -- | "[if the psyche of Progue is resolved]Progue stands nearby, trembling, tired, but somehow also suffused with real peace[else][The Progue], perched on [Progue's perch], seems deep in thought[end if]." |
| scrapbooking | -- | "Progue sits on the ledge, rummaging listlessly through his pile of possessions." |
| mending | -- | "[The Progue] is sitting on [Progue's perch], mending his tattered clothes with a needle and thread." |
| hand-standing | -- | "[The Progue] is walking carefully across the [surface-material] on his hands, a look of upside-down concentration on his face." |
| cleaning | -- | "Progue is scrubbing the surface of the workbench, whistling cheerfully." |
| paint-making | -- | "Progue, surrounded by baskets, pots, konokuk leaves, and crude tools, is cheerfully mixing paints." |
| frog-catching | -- | "[The Progue] is here, [if caught-frog is true]kneeling on the ground with a small green frog cradled in his hands[mf2l][otherwise]crawling through the marsh, eyes pinned on the ground[end if]." |
| swimming | -- | "[The Progue] is a few swells away, bobbing lazily as he floats on his back, eyes closed." |
| beach-combing | -- | "[The Progue] is here, walking carefully up and down the beach and studying the sand critically. His arms are full of bits of wood, seaweed, and broken shells." |
| resting | -- | "Lying on the [surface-material] is [the Progue], [if the psyche of progue is emotional]covered in blankets and sleeping uneasily[otherwise]sound asleep[end if]." |
| convalescing | -- | "Progue sits up weakly back against the wall, watching you as you enter." |
| loitering | -- | "[The Progue] [if we are going or we are landmark-going]looks up eagerly as you approach[else]stands nearby, [proguedeciding][end if]." |
| player-seeking | -- | "[The Progue] [if we are going or we are landmark-going]looks up as you approach[else]stands nearby, [proguedeciding][end if]." |
| hottubbing | -- | "[The Progue] relaxes on the edge of the pool, flexing shriveled toes just under the surface." |
| stoicising | -- | "Progue is nearby, solemn, lost within his own thoughts." |
To say mf2l: move frog to Progue.
To say proguedeciding: say "[one of]peering intently at a fingernail[or]idly stretching[or]momentarily distracted by one patchwork-covered sleeve[or]tapping a finger thoughtfully against his nose[in random order]".