Blue Lacuna — 456 of 475

Aaron A. Reed

Release 4

Section - Buildings

The buildings are a backdrop. They are in Plaza, Room1, Room2, Room3, and Room4. Understand "building" as buildings. The description is "Mostly brick, mostly eight or nine stories high, and mostly grey or tan, the buildings crowd together closely against the wide streets with few windows but many entrances. Narrow alleyways strewn with rubbish stretch back into dimness beside each one; many have steep concrete steps with wrought-iron railings running up to [o]doors[x] on the second or even third level up.". Check climbing buildings: say "You wouldn't be able to get a grip on the grimy concrete." instead. Check going up when buildings are enclosed by location: try entering buildings instead.

The reb-doors are a backdrop. They are in Plaza, Room1, Room2, Room3, and Room4. Understand "door/doors/entrance/entrances/window/windows/lock/locks" as reb-doors. Does the player mean doing something to reb-doors: it is unlikely. The description is "The buildings have more doors than it seems they strictly need, of all shapes and sizes.". Instead of entering or opening or using reb-doors: try entering buildings. Check closing reb-doors: say "Already shut." instead. Instead of attacking reb-doors: try attacking buildings. Instead of knocking reb-doors: try knocking buildings. Instead of vague unlocking reb-doors: try vague unlocking buildings.

To pick a random rebel door:

say "You pick a [one of]small[or]mid-sized[or]large[or]older-looking[or]newer-looking[at random] [one of]grey[or]tan[or]soot-black[or]darkish yellow[or]beige[as decreasingly likely outcomes] [one of]brick[or]concrete[as decreasingly likely outcomes] ";

say "building, [one of]walk up a set of narrow steps[or]walk down a few flat stairs[or]step up[or]step up a single large stair[or]pass through a tiny covered foyer[at random] to a [one of]tiny[or]paint-drowned[or]elegant old[or]graffiti-strewn[or]splintered[or]double-wide[or]tall[at random] door".

Instead of going or entering buildings:

pick a random rebel door;

say ", and try the handle. ";

say "[one of][noonehome][or][noonehome][or][papersscene][or][noonehome][stopping].".

To say noonehome: say "It's locked. [one of]You move back to the sidewalk[or]You jiggle the handle once again before heading back to the street[or]From a window above you, you see a [random voyeur] scowling down at you, so you beat a hasty retreat back to the street[or]You are about to try again when you spot a uniformed man down the street heading your direction; quickly, you step away from the door[as decreasingly likely outcomes]".

To say papersscene: say "The door opens on a cramped apartment, and a frightened old woman hovering over a stove with a saucepan in her hands.[paragraph break]'What do you want?' she mutters fearfully, then catches sight of your uniform. 'Papers? You need to see my papers?' Her hand trembles, the pungent sauce in the pot shaking crazily as she sets in back on the counter. She quickly rummages through a door and comes up with a handful of documents, which she thrusts into your hands. But some uniformed guards are coming down the street in your direction, so you quickly return the papers to the old woman and shut the door".

To say random voyeur: say "[one of]suspicious old woman[or]wide-eyed young girl[or]bearded man[or]frightened young woman[or]blank pudgy face[in random order]".

[To say burglarcaughtscene: say "A burly uniformed man stands behind you, gripping your arm tightly. 'I've been watching you,' he says unpleasantly, 'and even though you've got a fancy uniform, I don't think you're cleared to bother random citizens. You're going to have to come with me."; print a section break; move player to Holding-Cell.]

Instead of knocking buildings, try vague knocking. Instead of vague knocking when buildings are visible:

pick a random rebel door;

say ", and knock [one of]sharply[or]three times[or]twice[at random]. ";

if a random chance of 10 in 10 succeeds or Islander Bombing has happened begin;

say "You wait for some time, but there is no answer.";


do nothing;

[ UNFINISHED: Write a scene or two here. ]

end if.

Instead of opening buildings, try entering buildings. Instead of vague unlocking buildings, say "The lock seems quite solid, but the door itself seems weak and would probably give easily to a solid attack.".

Instead of attacking buildings for the first time:

increase the rap sheet of DrQuick by 2;

say "Glancing cautiously around to be sure no one is paying attention, you step back and then smash the door with your shoulder. The wood splinters and the door gives. Reaching inside, you slide open the lock and slip quickly inside.";

now former location is location;

move player to Apartment.

Instead of attacking buildings for at least the second time: say "Some black-suited police types are strolling nearby, keeping an eye on you. You'd better not.".

Apartment is a room in Rebelworld. The description of Apartment is "Colorless light filters through a single small paned window into this tiny apartment, odors of distant mildew and unwashed dishes hovering faintly in the air like ghosts.[paragraph break]A large wooden [o]cabinet[x] with dials and a pull cord is placed prominently in the room, in front of a faded, frayed [o]rug[x]. Tucked in a corner is a small [o]fireplace[x], a [o]pad[x] of paper hanging next to it on the wall. [exits].". The exits text of Apartment is "The only way out is [d]back[x] to the street". First Instead of exiting when location is Apartment: try retreating.

The radio is an undescribed device in Apartment. It is fixed in place. The printed name is "wooden cabinet". Understand "wood/wooden/cabinet/radio" as radio when location is Apartment. The description is "Almost as tall as you are, the imposing wooden cabinet is ornately stained and decorated. Three silver [o]dials[x] on the front are set to inscrutable numbers running around their edges, while a chain pull [o]cord[x] extends from the side.". First Report switching on the radio: say "You pull the chain until something plunks inside the wooden cabinet. A whir, a hum, and then pulsating static echo inside the cabinet, before finally resolving into recognizable sound." instead. First Report switching off the radio: say "You pull the chain again. The music fades slowly into muffled silence, a high-pitched whir from inside the cabinet winding down through subsonic tones and then away." instead. Instead of listening when location is Apartment: try waiting. The examine described devices rule is not listed in any rulebook.

Every turn when the radio is switched on and location is Apartment: say "[one of]The cabinet emits a strange tinny sound which finally resolves in your mind to a strange form of music. Frenetic, chaotic, it uses such a wide variety of instruments and contradictory tonal patterns that at first it is overwhelmingly incomprehensible.[or]Gradually, you begin to adapt to the strange music. You can start to pick out a melody line that, despite the chaos around it, is surprising in its simplicity.[or]The strange symphony continues, building in ululating runs and crescendos towards a climax.[or]The music reaches a cacophonous climax, holding an imbalanced chord before abruptly falling silent.[or]'Summer grass summer weed, within the summer sun,' a tinny voice from the cabinet says thrillingly. 'Teacher Frosthair. Once again, once again.'[or]Two discordant notes sound mutedly from the cabinet, twining gently around each other, sustaining.[or]The two notes are joined by others, one strange instrument at a time adding its voice to the musical palette.[or]The strange music continues to blare tinnily from the cabinet.[stopping]".

The three silver dials are part of the radio. They are minor. The description is "You are hesitant to adjust the dials without knowing what they are for.".

The chain pull cord is part of the radio. Instead of pulling chain pull cord when radio is switched off, try switching on the radio. Instead of pulling chain pull cord when radio is switched on, try switching off the radio.

A faded rug is a setpiece in Apartment. The description is "Though well-worn and threadbare, you can still faintly make out a stylized pattern on the rug, showing a foot pulling itself free from vicious entangling roots.".

The apartment-fireplace is a setpiece in Apartment. Understand "fire/fireplace" as apartment-fireplace when location is Apartment. The printed name is "small fireplace". The description is "The fireplace is built into the wall, but seems too small to be used for heat or cooking. On a hook next to it is a small [o]pad[x] of newsprint and a stubby pencil. You notice burnt [o]scraps[x] of paper scattered in the ashes of the fireplace". Understand "light [apartment-fireplace]" as a mistake ("Probably best not to make yourself too at home.").

Some burnt scraps of paper are a minor prop in Apartment. The description is "Kneeling to the ground, you peer at a few of the burnt scraps curiously. Most are completely incinerated, but you can catch a few scraps of writing here and there: '...tell me what to...' '...can't choose oh help...' '...mother were here she...' ' strong I must be...' ' mind. Who can I...'".

A pad of newsprint is a minor prop in Apartment. Understand "stubby/pencil/paper/hook" as pad of newsprint. The description is "The small pad rests from the wall on a ceremonial hook; about half the pages are gone. The stubby pencil is attached to it by a looped piece of black string.".

Instead of retreating when location is Apartment: say "You slip back outside into the city streets."; move player to former location.

Breaking-And-Entering is a scene. Breaking-And-Entering begins when location is Apartment. Breaking-And-Entering ends when location is not Apartment.

BAE-fate is a number that varies. BAE-fate is -3.

Every turn during Breaking-And-Entering:

increase BAE-fate by 1;

if BAE-fate > 0 and a random chance of BAE-fate in 12 succeeds and Burglar-Busted has not happened begin;

move angry renter to location;

say "Suddenly the door swings open, and a middle-aged [o]man[x] wearing wire-rim spectacles and a furious frown barges in.";

end if.

Burglar-Busted is a scene. Burglar-Busted begins when angry renter is in location. Burglar-Busted ends when location is not Apartment or angry renter is not in Apartment.

When Burglar-Busted begins: try greeting angry renter.

The angry renter is a man. "An angry [o]man[x] in a dull red sweater stands near the door, furiously staring you down." Report greeting angry renter: force discuss bbust-intro instead. Understand "man" as angry renter.

BBUST is a thread. bbust-intro is a beat in BBUST with reaction "'What are you doing, in Builder's sight?' he shouts in a reedy, high-pitched wail. 'Who do you think you are, coming in here? What...' He catches sight of your uniform and trails off. 'What is this?' he says, more weakly. 'I haven't done anything wrong. Am I-- are you with the Force?'". Instead of saying yes or saying maybe when last beat is bbust-intro: force discuss bbust_force. Instead of saying no when last beat is bbust-intro: force discuss bbust_noreply2. bbust-intro suggests bbust_noreply. bbust-intro summons bbust_force, bbust_noreply2. bbust-intro summons bbust_force, bbust_noreply2.

bbust_force is a beat in BBUST with keyword name "yes" and reaction "His eyes widen, and he takes a half-step back, putting a hand to his chest. 'I've done nothing!' he cries, 'nothing! What, is this because I went to hear that Greeneyes [t]sympathizer[x] speak last winter? I didn't like him, didn't want to go. Wrote a letter to the Spirit denouncing him afterwards. I'm not a sympathizer, not!'". bbust_force summons bbust_sympathizer. bbust_force suggests bbust_noreply. bbust_force cancels bbust_dontbelieve.

Understand "greeneye/greeneyes/sympathizer" as bbust_sympathizer when last beat is in BBUST. bbust_sympathizer is a beat in BBUST with keyword name "sympathizer" and reaction "'Abhorrent philosophy,' the man says, nodding vigorously, 'we can't survive without leaders. It's different, can't they see that? Not the leaders that are bad but that we weren't them; the Forest were leaders, not us. Now we lead ourselves. Don't they see? Greeneyes, bah,' he spits. 'Not for me! Not for me! Please, you believe me, don't you?'". The yes-beat of bbust_sympathizer is bbust_believe. The no-beat of bbust_sympathizer is bbust_dontbelieve. bbust_sympathizer suggests bbust_dontbelieve. bbust_sympathizer summons bbust_believe, bbust_dontbelieve.

bbust_dontbelieve is a beat in BBUST with keyword name "no" and reaction "He pales for a moment, then straightens a bit, thought not quite out of a cower. 'Then please, I need to see your [bbust_passcard],' he says. 'My rights.'". bbust_dontbelieve enqueues bbust_noreply. bbust_dontbelieve cancels bbust_force.

bbust_believe is a beat in BBUST with keyword name "yes" and reaction "He smiles, tension fading from his shoulders. 'Oh, yes, oh, of course yes. Thank you. Yes. Then you'll go, if you don't mind. Or if not I'll need to see your [bbust_passcard]. My rights.'". bbust_believe suggests bbust_noreply. bbust_believe summons bbust_passcard.

Instead of showing passcard to angry renter, force discuss bbust_passcard. Instead of giving passcard to angry renter, force discuss bbust_passcard. Understand "credentials" as bbust_passcard when last beat is in BBUST. bbust_passcard is a beat in BBUST with keyword name "credentials" and reaction "You hold out the passcard around your neck to the small man's squinting eyes. He studies it for a moment, then shoves his spectacles back up your nose with a sniff. 'Top scientist,' he says, 'no Force privileges. You can't be here, then. Not your right. I should report you. You'd best [bbust_leave] now, before, before I get angry.'". bbust_passcard suggests bbust_noreply2.

bbust_noreply is a beat in BBUST with reaction "'Now, now, answer me!' the man says, stepping forward [if radio is switched on]and switching off the radio[otherwise]timidly into the room[end if]. 'I'm entitled. Under Builder's Law I'm entitled if you're with the Force, to know your letters and see your [bbust_passcard]. I'm entitled, entitled!' He quivers indignantly before you.". bbust_noreply suggests bbust_noreply2. bbust_noreply2 replaces bbust_noreply. After discussing bbust_noreply: now radio is switched off. bbust_noreply summons bbust_passcard.

bbust_noreply2 is a beat in BBUST with keyword name "no" and reaction "'Now, well that's it,' the man says, his voice rising to a high-pitched squeal. 'I'm calling the Force. You can't do this, can't. I'm entitled.' He backs fearfully up to the door and calls 'Help! Help! Burglary, help!'". bbust_noreply3 replaces bbust_noreply2. bbust_noreply2 suggests bbust_noreply3.

bbust_noreply3 is a terminal beat in BBUST with reaction "'Help!' the man continues to cry. 'A burglary, burglary, help!'". After discussing bbust_noreply3: now the rap sheet of DrQuick is 10.

Instead of attacking angry renter: say "You tackle the man, who collapses feebly to the ground, crying 'Help, help!' He batters at you ineffectually, eyes rolling back in his head as he appears to go into some sort of panic attack."; now rap sheet of DrQuick is 10.

Instead of retreating when Burglar-Busted is happening and ( we have not discussed bbust_passcard and we have not discussed bbust_noreply2 and we have not discussed bbust_noreply3 ) : force discuss bbust_leaveearly. bbust_leaveearly is an ephemeral beat in BBUST with reaction "'Wait now just a slim there,' the man says, stepping in your path and holding out a hand. 'I have explanations to hear.". bbust_leaveearly2 replaces bbust_leaveearly. bbust_leaveearly2 is a terminal beat in BBUST. After discussing bbust_leaveearly2: force discuss bbust_leave; remove angry renter from play; try exiting. Before retreating when location is Apartment and we have not discussed bbust_leaveearly2: force discuss bbust_leave; continue the action.

bbust_leave is a terminal beat in BBUST with reaction "'Your superiors will be hearing about this!' the man cries weakly after you as you slip past him and out into the street.".