Blue Lacuna — 429 of 467

Aaron A. Reed

Release 4

Chapter - Lacunites

A Lacunite-gardener is a kind of Lacunite. The indefinite article of a Lacunite-gardener is usually "the". Understand "planter" as a Lacunite-gardener. Reflecting Pool is a room. Avenue North is a room. Avenue South is a room.

The worker1 is a Lacunite-gardener in Reflecting Pool with printed name "red-robed woman". Worker1 is female. Understand "woman" or "local" as Worker1. "A young [o]woman[x] kneels [if location is Reflecting Pool]near the pool's edge, tending the flowers that grow there[else]here, tending the flowers[end if].". The description is "[if we have not examined Worker1]As you look closer, it becomes apparent that she is not a woman, exactly: at least, not a human woman. The eyes are a little too large, the skin mottled in a strange way. When she is not moving she holds herself so still to be almost statue-like. [end if][if we have not examined Worker1 and skeletons_bit is 0]Then, suddenly, it hits you: this woman is a living, breathing version of the ancient skeletons you saw in the Egg ship on Lacuna. [otherwise if we have not examined Worker1]Another from that race whose skeletons moulder in the egg ship on Lacuna. [end if]She wears long robes, intricately stitched and trailing along the ground behind her, and long white braids descend from either side of her face, though she does not look old."

The worker2 is a Lacunite-gardener in Avenue South with printed name "lanky teenager". "A tall, lanky teenaged boy is carefully clipping back the grass here." Understand "tall" or "lanky" or "teenaged" or "teenager" or "teen" or "boy" as Worker2.

The worker3 is a Lacunite-gardener in Avenue North with printed name "balding man". "A balding man kneels here, tending the flowers." Understand "balding" or "man" as Worker3.

Every Lacunite-gardener has a number called counter. The counter of a Lacunite-gardener is usually 1. [This keeps track of how long each gardener spends working in one room.]

Every turn when the player is in Treeworld and stranger_counter <= 0 (this is the process Lacunite movement rule):

repeat with processee running through idle on-stage Lacunite-gardeners:

increase counter of processee by 1;

if counter of processee > 10 and ( a random chance of 1 in 7 succeeds or counter of processee > 30 ) :

let L-target be Fork;

let loopcounter be 0;

while L-target is not in Plateau or an other Lacunite is enclosed by L-target:

increase loopcounter by 1;

now L-target is a random room adjacent to processee;

if loopcounter > 10, stop;

let way be up;

[Avoid slowdowns from pathfinding]

if L-target is mapped north of location of processee, now way is north;

if L-target is mapped northeast of location of processee, now way is northeast;

if L-target is mapped east of location of processee, now way is east;

if L-target is mapped southeast of location of processee, now way is southeast;

if L-target is mapped south of location of processee, now way is south;

if L-target is mapped southwest of location of processee, now way is southwest;

if L-target is mapped west of location of processee, now way is west;

if L-target is mapped northwest of location of processee, now way is northwest;

if way is up, stop;

if location of Lacunite-Follower is location of processee, say "[The processee] finishes one last bit of gardening and [one of]smiles in satisfaction[or]pats the ground happily[or]leans back to study [hisher] work critically[at random]. Then, [heshe] gets to [hisher] feet, and walks off towards [the room way from location of processee].";

if location of Lacunite-Follower is L-target, say "[The processee] arrives from [the location of processee], kneels next to [one of]a bed of flowers[or]a piece of greenery[or]some mossy brickwork[at random], pulls out a spade, and begins to tend it.";

try processee trying going way;

now counter of processee is 0.

Report a Lacunite-gardener going a direction: do nothing instead.