Blue Lacuna — 386 of 467

Aaron A. Reed

Release 4

Book - Dream Related Stuff

Emergency waking is an action applying to nothing. Understand "alarmclock" as emergency waking.

Check emergency waking: if yourself is awake, say "You're awake.". Carry out emergency waking: now player is yourself; now yourself is awake; now time factor is 3; let lucky be a random windsigh tree in saved location;

if lucky is not a thing and saved location is Saddle, let lucky be tree3;

if lucky is not a thing and saved location is Treehouse, let lucky be tree2;

now lucky is contacted.

Check vague discussing when location is regionally in Dreamlands: say "The conversation seems to move inexorably forward, despite your attempts to direct it." instead.

Check requesting the exits text when location is regionally in Dreamlands: say "You can't seem to get your bearings here." instead.

Definition: a room is treecontacted: if it encloses a contacted windsigh, yes; if it is Treehouse and tree2 is contacted, yes; no.

To say sleepsuggest: [ If the player has tried to sleep somewhere inappropriate, we suggest a place for them, subtly encouraging them to sleep near a windsigh tree. ]

say "[line break]";

let the tree room list be {Treehouse, Fork, Forest9, Cinder Cone, Egg Room, Saddle, Rockslide};

remove the list of unvisited rooms from the tree room list;

remove the list of treecontacted rooms from the tree room list;

if the number of entries in the tree room list is 0:

say "There's got to be someplace to sleep around here.";

stop;

let nmb be a random number from 1 to the number of entries in the tree room list;

let selection be entry nmb of the tree room list;

if selection is Treehouse:

say "The hammock in that treehouse you found looked like a nice place for a night's sleep.";

else if selection is Fork:

say "The leafy nook at the foot of the tree you painted to reach this place springs to mind. It might be comfortable enough for sleep.";

else if selection is Forest9:

say "The [tree5] in the rain forest had that mossy boulder at its base-- that might be a good place to drop off.";

else if selection is Cinder Cone:

say "The smooth slopes of the small cinder cone in the volcano near the [tree4] might be a smooth and warm place to sleep.";

else if selection is Egg Room:

say "The hidden hollow by the egg shape in the rain forest might be a soft place to get some sleep.";

else if selection is Saddle:

say "That high saddle at the top of the water cave might be a good place to sleep, and there would definitely be a spectacular view of the sunrise in the morning.";

else if selection is Rockslide:

say "The mossy hollow up by the [tree7] on the rockslide might be a good place to sleep.".