Blue Lacuna — 222 of 467

Aaron A. Reed

Release 4

Part - The Rain Forest Region

Rain Forest is a region. Forest1, Forest2, Forest3, Forest4, Forest5, Forest6, Forest7, Forest8, Forest9, and Egg Room are in Rain Forest. The printed name of a rainforest-room is usually "In the Rain Forest".

The ambience table of Rain Forest is Table of Rain Forest ambience.

Table of Rain Forest ambience

freqstart timeend timetexttabletriggerflag
commondawnsunset--Table of Rain Forest Insect ambience
commontwilightnight--Table of Rain Forest Night ambience
commondawnsunset--Table of Rain Forest Creature ambience
uncommon----"[if night][nightforest][otherwise][one of][timeofdayrelatedforestamb][or][nottimeofdayrelatedforest][at random][end if]."

Finding-A-Boar is a recurring scene. Finding-A-Boar begins when location is regionally in Rain Forest and location is not Egg Room and ( dawn or sunrise or sunset or twilight ) and a random chance of 1 in 30 succeeds. Every turn during Finding-A-Boar: if wild-boar is not enclosed by location , remove wild-boar from play. Finding-A-Boar ends when wild-boar is off-stage.

When Finding-A-Boar begins: say "Suddenly, in a clearing before you, you spot a wild [o]boar[x], snuffling through the undergrowth."; move wild-boar to location.

A wild-boar is an animal. The printed name is "wild boar". Understand "wild/boar" as wild-boar. The description is "The creature is much larger than you expected, with long tusks and ugly, mud-brown skin.". Instead of attacking wild-boar, say "That's probably not a good idea without some kind of weapon.".

Every turn when wild-boar is in location, say "[boardesc]". To say boardesc: say "[one of]The [o]boar[x] snuffles its hairy snout through the underbrush, searching for grubs[or]Cracking twigs under its cloven feet, the [o]boar[x] moves slowly through the clearing, sniffing for prey[or]Flicking flies off its backside with its long matted tail, the [o]boar[x] makes tired wheezes as it ambles through the clearing[or]The [o]boar[x] stops suddenly, sniffing something in the air, then returns to foraging[in random order].".

Table of Rain Forest Insect ambience

freqstart timeend timetext
frequent----"[one of]A blue-bellied spider weaves a delicate web in a nearby tree[or]A skinny centipede crawls through the fallen leaves near your feet, its countless legs twirling[or]A trio of yellow-blue butterflies flit by, vanishing quickly into the depths of the forest[or]A jet-black slug crawls slowly up a nearby tree trunk, ancient and buried in moss[or]Struggling with her wriggling prey, a blue-bellied spider works tirelessly to wrap a small black fly in silken webbing[or]A pair of small snails inch slowly along a fallen tree trunk[in random order]."
frequent----"[one of]A buzz of flies hovers over the tiny corpse of a dead rodent[or]Black beetles scurry away into the decaying leaves, disturbed by your footsteps[or]A pair of small winged insects, black but for brilliant red dots on their heads, fly by in a complex, whirling mating dance[or]Hundreds of tiny blue ants carry fragments of leaves and twigs industriously into a myriad of holes at the base of the tree roots[or]A line of tiny blue ants crawls industriously down a mouldering fallen tree trunk[or]With a metallic buzzing, some beetle-like insect zips from tree to tree overhead[or]A lone red and cream striped bee zips quickly through the trees, dodging and weaving past a hundred obstacles with ease[in random order]."
rare----"[one of]With a sudden swoop, a bird swoops down from the canopy to snatch a wriggling centipede from a nearby boulder, vanishing again in a heartbeat into the forest[or]With a sudden jerk, you slap your hand to your head and brush away a blue-bellied spider, which skitters hastily away into the underbrush[in random order]."

[[or]A buzz of flies hovers over the tiny corpse of a dead rodent[or]Black beetles scurry away into the decaying leaves, disturbed by your footsteps[or]A pair of small winged insects, black but for brilliant red dots on their heads, fly by in a complex, whirling mating dance[or]Hundreds of tiny blue ants carry fragments of leaves and twigs industriously into a myriad of holes at the base of the tree roots[or]A line of tiny blue ants crawls industriously down a mouldering fallen tree trunk[or]With a metallic buzzing, some beetle-like insect zips from tree to tree overhead[or]A lone red and cream striped bee zips quickly through the trees, dodging and weaving past a hundred obstacles with ease]

Table of Rain Forest Creature ambience

freqstart timeend timetext
frequent----"[one of]A steady chorus of bird calls soaks through the rain forest from high in the sunlit canopy above[or]Above you, four or five small squirrel-like creatures deftly leap from branch to branch, on their way to some important destination[or]A pair of birds chase each other through the hanging moss and branches in a sudden flutter of wings[or]A small black squirrel creature watches you guardedly from a high branch, then scampers away[or]A flock of small blue birds descend on a nearby tree, and sit there grooming themselves and chirping loudly[in random order]."

Table of Rain Forest Night ambience

freqstart timeend timetext
frequent----"[one of]Something sticky and tickling brushes at your face; clawing it away in a momentary panic, you realize it was a spider's web[or]A branch snaps loudly, somewhere close by and you freeze for a long moment, but hear nothing further[or]Something unseen scurries away from you in the darkness[or]An unseen animal calls out somewhere nearby in the forest[in random order]."

The exits text of a rainforest-room is usually "[if night]In the blackness, you stumble with every step, and can barely make out possible routes. [otherwise if twilight]The light is rapidly failing, and ways through the forest are growing harder to see. [otherwise if dawn]It's still quite dim, but you can make out a few possible routes. [end if][Forest Exit Routine]".

To say Forest Exit Routine:

if location is Forest1, say "[Forest1Exits]";

if location is Forest2, say "[Forest2Exits]";

if location is Forest3, say "[Forest3Exits]";

if location is Forest4, say "[Forest4Exits]";

if location is Forest5, say "[Forest5Exits]";

if location is Forest6, say "[Forest6Exits]";

if location is Forest7, say "[Forest7Exits]";

if location is Forest8, say "[Forest8Exits]";

if location is Forest9, say "[Forest9Exits]".

Table of Nearby Rain Forest ambience

freqstart timeend timetexttabletriggerflag
uncommondawntwilight"[if night][nightforest][otherwise][one of][timeofdayrelatedforestamb][or][nottimeofdayrelatedforest][at random][end if]."

To say nightforest: say "[one of]A tiny crash echoes from somewhere inside the rainforest, a tiny creature falling prey to some nocturnal predator[or]The rain forest is eerily quiet, like some slumbering beast, huge, humid, and black[or][if moonup]The moon breaks through a cloud and gives momentary form to the edge of the rain forest, details painted in its stark silver-pink light[otherwise]The stars glimmer brightly above the indistinct edge of the rainforest, but penetrate its black interior not at all[end if][in random order]".

To say nottimeofdayrelatedforest: say "[one of]A strange animal cry echoes from somewhere inside the rainforest, muffled and distorted, as if only barely escaping the thick carpet of moss-covered trees[or]A muffled crash sounds faintly from within the rainforest, perhaps some long-dead tree finally giving way to gravity's pull[or]A bird call sounds sharply from some tree on the edge of the rain forest, repeating several times with clockwork regularity before falling silent[or]A gust of wind makes the green tide of the rain forest shimmer and breathe, swaying and waving the humid air[in random order]".

To say timeofdayrelatedforestamb:

if dawn begin; say "[one of]Shapes gradually begin to coalesce out of the dimness of the rain forest: trees, ferns, boulders, and vines coming into being[or]The rain forest is utterly still in the growing light, as if even the wind has yet to wake up[in random order]";

otherwise if morning or sunrise or midmorning; say "[one of]The morning light burnishes the tops of the forest trees, but you sense the deep interior is still cold and unlit[or]A whispering susurrus of sound trickles out of the rainforest, the noise of a million leaves rubbing against each other, a million beetles scurrying[in random order]";

otherwise if midday; say "[one of]The rain forest bakes in the midday sun, waves of steam rising from its dark, hot interior[or]A faint breath of air stirs the trees of the rain forest teasingly, but then vanishes, like a heat mirage under the baking sun[in random order]";

otherwise if afternoon; say "[if raining][one of]The rain forest soaks in the falling moisture like a huge green sponge[or]Channels of water run down huge fronds or rivets in tree trunks at the edge of the rain forest[in random order][otherwise if weather state is decided to rain or rained][one of]Wind whips the fringe of the rain forest, great dark leaves quivering under the scudding clouds[or]Bird cries echo through the rain forest as clouds race by overhead[in random order][otherwise][one of]The dense vegetation of the rain forest burns gold and chartreuse in the afternoon light[or]Birds circle lazily over the rain forest, drinking in the sun's slanting rays[in random order][end if]";

otherwise if evening or sunset; say "[one of]The rain forest lies quiet in the shadow of the lava flow[or]Birds chirp restlessly from atop some tree in the rain forest, anxious for the long shadow of the lava flow to give way to night[in random order]";

otherwise if twilight; say "[one of]Insects buzz quietly in strange syncopations and harmonies within the depths of the rain forest[or]The rain forest shimmers under a faint wind and the fading sky, settling in for another long night[in random order]";

end if.

To say a sentence about the forest profusion:

if night begin; say "The interior of the rain forest is almost pitch black in the night; strange undefined shapes and sourceless noises surround you on all sides";

otherwise; say "[if a random chance of 2 in 3 succeeds and not raining][forestprofusiongen][otherwise][forestprofusiontod][end if]";

end if.

To say forestprofusiongen: say "[one of]Living things grow on every side, on top of and overtaking each other like a closet too full of unneeded things[or]Light filters warily through the forest canopy high above, filtered green by countless huge leaves and shadowed by dozens of moss-encrusted branches[or]The living forest surrounds you on every side, a verdant chaos of leaves, branches, trunks, moss, and vines of all shapes and sizes[or]Damp air mists through the rain forest, perceptible only in fits[or]Greenery clusters in on all sides, and daylight descends only in timid shafts to touch the odd lucky branch or twist of root[or]Waves of humid air buffet you gently, soaking in smells of earth and vegetation from the huge trees and endless mossy roots that press in on every side[in random order]".

To say forestprofusiontod:

if dawn or twilight begin; say "[one of]Only the faintest light filters through the canopy to the floor of the rainforest, painting it in dull half-shades and shadows[or]The forest seems half asleep in the faint light, and you tread quietly, as if fearful of waking it up[or]Indistinct shapes and dimensionless forms loom up on all sides in the dim light[in random order]";

otherwise if sunrise or morning; say "[one of]Wisps of mist hover strangely in the rain forest, like lost cloud children hiding from the punishment of sunlight[or]Bright light turns the canopy far overhead to glowing greens and golds, but only reflected light, shadowless and strange, makes it to the forest floor[in random order]";

otherwise if raining; say "[one of]Water spatters noisily on the canopy overhead, gurgling down to your level along tree trunks, sudden showers, and huge, endless tear drops[or]The muddy ground sucks at your feet as you slog through the rain forest, stepping carefully over slimed boulders and mouldering deadwood[or]The rain has turned the forest to shades of deep soaked green, slimy earth browns, and rich crinkled blacks[or]Wet leaves slap at your face and water-swelled logs catch at your feet, but you finally manage to stop and catch your breath[or]The humid air is made so thick by the rainfall you are almost afraid to breathe, lest you drown amidst the mud puddles and shivering palm fronds[or]As rain penetrates the canopy and drizzles down to the rain forest floor, you can almost feel the great, twisting tree roots drink it in, the carpet of fallen leaves dissolving gradually into dirt[in random order]";

otherwise if rained; say "[one of]Water drips continuously from the canopy far above, as the muddy ground struggles to drink in the afternoon's rain[or]The forest steams in the aftermath of the rain, wisps of moisture dancing restlessly through the ancient gnarled trunks and moss-draped vines[or]Rivulets of water trickle into mud puddles, as the rain forest quietly absorbs the rain shower's output[in random order]";

otherwise if midmorning or midday or afternoon; say "[one of]The rain forest is a symphony of life, heat, moisture, and movement, pressing in on you from all sides oppressively[or]The afternoon heat hangs oppressively in the rain forest, water beading like sweat on moss-swamped trees and twisted, fallen branches[or]The rain forest is hot and heavy in the midday sun, shielding you from its direct light but baking nonetheless in its own moist fire[or]A hot wind gusts through the rain forest, creaking branches, shimmering fronds, and sending a scudding whirl of dead leaves past your feet[in random order]";

otherwise if evening or sunset; say "[one of]Insects hum and chirp restlessly in the rain forest evening, settling invisibly on high branches and blending imperceptibly into the trunks of ancient, gnarled trees[or]The rain forest is dim and sleepy in the muffled evening light[in random order]";

end if.