Blue Lacuna — 182 of 467

Aaron A. Reed

Release 4

Chapter - Observatory Exterior

The printed name of Observatory Exterior is "[if pyramid is on-stage]Outside the Pyramid[otherwise]At the Machinery[end if]". Understand "lawn" as west when location is Observatory Exterior.

The prose name of Observatory Exterior is "the mountain cirque by the [if pyramid is on-stage]wooden pyramid[else]machinery".

The description of Observatory Exterior is "[observdesc].". To say observdesc:

let vol be the pressure of the related pipe of the pyramid pressure gauge;

if vol >= 22, let outvol be vol - 22; otherwise let outvol be vol;

[pyramid uses 22 units of power if available.]

if longform begin;

say "Nestled into this cirque at the foot of the mountain's summit[if raining], sheltered by the slight overhang from the rain, [end if] is [one of]a[or]the[stopping] [pyrstatesummarylong]";


say "The [pyrstatesummaryshort], ";

if sunup, say "gleams in the [Progue-time-of-day] sunlight";

else say "rests mysteriously in the [light-source]";

end if;

say "[dot][if outvol > 20]Torrents of steam gush from a nearby outflow [ventword], rising high into the sky before dissipating[otherwise if outvol > 15]Steady clouds of steam bellow from a nearby outflow [ventword][otherwise if outvol > 3]Steam pillows from a nearby outflow [ventword][otherwise if outvol > 0]Thick tendrils of steam rise up from a nearby outflow [ventword][otherwise]An outflow [ventword] emits only wisps of humid air[end if] ";

say "at the base of the [if pyramid is on-stage]pyramid[otherwise if destroyed mind machinery is in location]wreckage[else]machinery";

if pyramid has power and destroyed mind machinery is not in location begin; say ", and a steady whir and thrum deep in your bones sighs up from somewhere underneath the ground[if pyramid is on-stage]. A brilliant ruby glow spills through its three vertical seams[compasssqueezebit][otherwise]. The [o]egg[x] pulses with an intense ruby glow, so bright you almost can't look into it[end if][if night or dawn or twilight], and a faint column of crimson light rises from it into the sky[end if]";

otherwise if vol > 0 and destroyed mind machinery is not in location; say ", and a dim crimson glow pulses [if pyramid is on-stage]through the three edges of the pyramid[otherwise]from the [o]egg[x][end if], cycling slowly off and then back to dimness again[if night or dawn or twilight] and casting weird shadows against the walls of the cirque";

end if;

say "[dot]A few paces away a [if vol >= 5][o]spring[x] bursts from the ground[otherwise]dry [o]streambed[x] begins[end if], ";

say "meandering in a shallow channel back towards the lawn[dot]";

say "[exits]".

To say compasssqueezebit: if puzzle mode, say "; where it hits the mountain cirque behind is projected an [o]image[x]".

Check listening when location is Observatory Exterior: if pyramid has power, say "The noise is subsonic, a deep rumbling coming from somewhere [if pyramid is on-stage]beneath the pyramid[else]beneath the chair[end if]." instead; else say "Wind whips through the mountaintop, whistling faintly through the curvature of the cirque." instead.

[[if raining or rained]; drops of water glisten and run along them like dewdrops on a spiderweb[end if]]

The mountain scrawl is a hint-based scrawl in Observatory Exterior with standard message "Not safe. Locked now. This way you have to know my words to get in." and secret message " Just have to finish Echo Cave work first." Understand "word/words" as mountain scrawl.

The exits text of Observatory Exterior is "The only safe place to go is back[if dir] [west][end if] towards the [dr]lawn[x]".

Observatory-stuff is stuff in Lawn. Understand "cirque/foot/whir/thrum/rod/rods" as Observatory-stuff when location is Observatory Exterior.

The projected image is a setpiece. The description is "The red light spills out from the seam in the side of the pyramid, painting the cliff behind in intense crimson light; but some hidden stencil obscures parts of the light to create a detailed image. It shows a compass that looks remarkably like the one [if player wears compass]around your neck[else]you've seen around the island[end if], held in a hand[squeezehint].". Check going to Observatory Exterior: if pyramid has power and puzzle mode, move projected image to Observatory Exterior; otherwise remove projected image from play; continue the action. To say squeezehint: if compass is extruded, say " that is squeezing it tightly"; else say "[one of] that is squeezing it tightly[or] that squeezes it tightly[or]. The hand is squeezing the compass[stopping]".

The ambience table of Observatory Exterior is Table of Observatory Exterior ambience.

Table of Observatory Exterior ambience

freqstart timeend timetexttabletriggerflag
common----"[one of]Wind whips through your hair sharply[or]Birds soar through the air beneath you, catching warm updrafts from the marsh[or]The distant sounds of surf crashing echo up dimly from the ocean far below[in random order]."
frequent----"[if pyramid has power and player is not enclosed by mind chair][one of]A deep, rhythmic thrum[or]A powerful thrumming vibration[or]An almost electric thrum[in random order] [one of]beneath your feet[or]from somewhere beneath the ground[in random order] [one of]surges underneath your feet[or]fills the air[in random order].[end if]"