Blue Lacuna — 147 of 467

Aaron A. Reed

Release 4

Chapter - Beachfront Scenery

The nearby beach is a view with base room Center Beach. It is in Tidepools, Among the Boulders, South Beach, Center Beach, North Beach, Rise, Lower Beach, and Ocean Waters. It is very near Tidepools, Among the Boulders, South Beach, Center Beach, North Beach, Rise, Lower Beach, and Ocean Waters.

Understand "sand/sands" as nearby beach. The description is "[if night or dawn or twilight]Almost glowing in the faint light[otherwise]Startlingly bright[end if], the beach [if location is Among the Boulders]is interrupted here by the patch of boulders[else if location is not North Beach and location is not South Beach and location is not Center Beach and location is not Lower Beach]is interrupted by pebbles and rubbed-smooth stones[else if cleanliness of location is spotless]is smooth and featureless, white curves unblemished by imperfections[otherwise if cleanliness of location is flecked]is dotted with tiny specks of seaweed and shell fragments[otherwise if cleanliness of location is marred]is strewn with clumps of slimy seaweed and other debris from the ocean[otherwise]is a mess of smelly patches of seaweed, fish carcasses, gull feathers, and pieces of bony driftwood[end if].".

Instead of taking or touching nearby beach:

if rained or raining, say "You scoop up a handful of the wet, almost muddy sand, feeling it ooze in gritty trickles through your fingers."; otherwise say "You let a handful of the [if night or dawn or sunrise or morning]cool[end if][if midmorning or midday or twilight]warm[end if][if afternoon or evening or sunset]scorching hot[end if] sand run through your fingers. So fine they feel almost soft, the grains [if midday or afternoon or evening or sunset]sparkle in the bright sun as they [end if]fall in a thin line back to the beach."

To say a sentence about the nearby beach:

if night begin; say "[one of][nearbybeach1][or][nearbybeach2][in random order]"; stop; end if;

if twilight or dawn begin; say "The stillness of the great crescent [o]beach[x] is magical in the half-light; the whole expanse curving out before you quietly breathtaking"; stop; end if;

if cleanliness of location is spotless begin; say "[one of]Spotless[or]Pristine[or]Gleaming[at random] white [o]sand[x]";

otherwise if cleanliness of location is flecked; say "White [o]sand[x] [one of]flecked with bits of seaweed and debris[or]spotted here and there with flecks of weed or fish bones[or]dotted with small bits of refuse and flotsam[at random]";

otherwise if cleanliness of location is marred; say "[o]Sand[x] [one of]strewn with[or]littered with[or]marred by[at random] [one of]strings of seaweed, stones, and pieces of driftwood[or]jagged broken shells and decomposing seaweed[at random]";

otherwise; say "[one of]Grimy[or]Dirty[or]Yellowing[at random] [o]sand[x] [one of]covered in[or]smeared with[at random] [one of]stinking seaweed, splintered driftwood, broken shells and gull feathers[or]seagull droppings, rotting seaweed, and splinters of driftwood[at random]";

end if;

say " [if midday and cleanliness of location is spotless]almost blinds you as it [end if][one of]curves around the[or]stretches in a great arc around the[in random order] lagoon".

To say nearbybeach1: say "The undulating white sand [o]beach[x] [if moonup]silvers in the moonlight, which sparkles faintly on the [otherwise]is dim and indistinct under the stars, the border between ground and sky defined by the sound of the [end if][if tideout]distant waves[end if][if rising uptide or falling uptide]waves, a stone's throw away[end if][if high tide]runners of foamy surf reaching almost to your feet[end if]". To say nearbybeach2: say "[if falling uptide or falling downtide]Damp sand glistens[end if][if high tide]Foamy breakers lap the shore[end if][if low tide or rising downtide or rising uptide]Smooth stretches of sand spread out[end if] [if moonup]ghostly white [end if]before you, [if location is South Beach]dotted with myriad tiny shells and pieces of wood[otherwise]unbroken save for your own footsteps[end if]".

The surf is a backdrop. It is in Lower Beach and Ocean Waters and Tidepools and Among the Boulders and South Beach and Center Beach and North Beach and Edge of Ravine and Ravine Floor. Understand "wave" or "waves" or "water" or "sea" or "ocean" or "tide" as the surf. The description is "[if location is Ocean Waters]The tide swells around you.[otherwise if high tide]The waves are high, perhaps near the high tide mark.[otherwise if falling uptide]The tide seems to be ebbing out, but the waves are still relatively close.[otherwise if falling downtide]The tide is a good distance away, and seems to be ebbing even farther out.[otherwise if low tide]The waves are a long way down, breaking languidly against the wet beach.[otherwise if rising downtide]The waves are a good distance away, but the tide seems to be flowing back in.[otherwise if rising uptide]The surf is relatively close, each wave seeming to crash a little closer.[end if]". Check tasting the surf: say "Salty." instead.

Check swimming in the surf: if location is in Beachfront, try going down instead; otherwise try vague swimming instead. Check vague swimming when location is in Beachfront and player_imperiled is false: try swimming in the surf instead.

Check touching the surf: say "The warm water feels fresh and alive as it swirls over your hand." instead.

Some beach debris is a backdrop. They are in South Beach, Center Beach, North beach, Lower Beach. Understand "shell" or "seashell" or "seashells" or "pieces of wood" or "wood" or "tiny" or "shells" or "detritus" or "flecks" or "seaweed" or "stones" as the debris. Instead of doing anything to the debris, say "None of it appears particularly valuable." Does the player mean doing something to beach debris: it is unlikely.