Blue Lacuna — 136 of 467

Chapter - The Windsigh Trees

A windsigh tree is a kind of setpiece. Understand "tree" or "curious" or "trunk" or "gnarled" or "root" or "roots" or "windsigh" or "bark" or "tree i painted" or "strange" as a windsigh tree. The printed name of a windsigh tree is usually "[if tree1 is named]a windsigh tree[otherwise if location is Fork]the tree you painted[otherwise][tree_rnd][end if]". Rule for printing the name of a windsigh tree (called subj) while asking which do you mean: say "[if tree1 is named]the windsigh[else]the tree[end if] [if subj is tree1]at the path[else if subj is tree2]with the treehouse[else if subj is tree3]on the ridge[else if subj is tree4]on the cinder cone[else if subj is tree5]in the rain forest[else if subj is tree6]by the Egg[else]at the rockslide[end if]". Understand "tree9" as a windsigh tree.

The description of a windsigh tree is usually "Like the other[if trees found is at most 2] one you saw[otherwise]s you've seen[end if], the tree seems stunted and out of place. [the tree spiel].". To say the tree spiel: say "Spirals of [o]vine[x] sprout from the gnarled trunk and wrap tightly around it before spreading out to knobby branches beginning just above your head. The branches bifurcate until they end in tiny, bare pointed twigs. As the vines spiral around them they sprout hundreds of small lemon-yellow [o]leaves[x]. Even more curious is that dozens of [o]holes[x] seem to have organically grown through the branches, as if they split and reconnected to themselves as the tree was growing; these also continue all the way out to the tiny twigs, shrinking in size as they go". To say tree_rnd: say "tree". Check attacking a windsigh tree: say "[if guessed_trees is true]Some part of you shivers at the thought; so defenseless they are, helpless against anything you could do-- but if you do make such a decision, better to wait until the right moment[otherwise]The trees seem fairly sturdy. Without an axe or something you doubt you could do much damage[end if]." instead. The dream-text of a windsigh tree is usually "[one of]miniature models of twisted, perforated trees[or]buckets of lemon-yellow paint[in random order]".

Check listening when a windsigh tree is enclosed by location: say "As the wind gusts through the dozens of holes in the trunk and branches of the tree, a strange, multi-pitched hum sighs and shivers through the air." instead.

Understand "sleep under [a windsigh tree]" as sleeponing. First check sleeponing: if noun is a windsigh tree, try sleeping instead.

A windsigh tree has a number that varies called order found.

To decide which number is trees found:

let highest be 0;

repeat with tmp running through windsigh trees begin;

if the order found of tmp > highest, now highest is order found of tmp;

end repeat;

decide on highest.

To say windsigh phrase of (entity - a thing):

if the order found of entity is 0 begin; [just now finding it]

let highest be 0;

repeat with tmp running through windsigh trees begin;

if the order found of tmp > highest, now highest is order found of tmp;

end repeat;

now order found of entity is highest + 1;

let ord be order found of entity;

if tree1 is named, say "[if ord is 2]another tree like the one you painted -- a [o]windsigh[x][otherwise]another [o]windsigh[x] tree[end if]";

otherwise say "[if ord is 1]the [treeword] you painted[otherwise if ord is 2]-- curious -- another [treeword] like the one you painted[otherwise if ord <= 4]another strange, withered [treeword] like the one that brought you here[otherwise if ord is 5]another withered [treeword] -- the fourth? fifth? -- [otherwise]another withered [treeword][end if]";

otherwise;

let ord be order found of entity;

say "the ";

if entity is tree3, say "huge ";

if entity is tree6, say "tiny ";

if entity is tree7, say "hardy ";

if tree1 is named, say "[o]windsigh[x]";

otherwise say "withered [o]tree[x]";

end if;

To say treeword: say "[o]tree[x]".

A windsigh tree is either uncontacted or contacted. A windsigh tree is usually uncontacted.

Some lemon-yellow leaves are a backdrop. They are in Fork, Big Tree, Treehouse, Rockslide, Cinder Cone, Forest9, Egg Room, Saddle, and Atop. The printed name of some lemon-yellow leaves is usually "lemon-yellow leaves". Understand "lemon" or "yellow" or "leaf" or "leaves" or "lemon-yellow" or "circular" or "veined" or "flower" or "flowers" or "disc" or "discs" as lemon-yellow leaves. The description of some lemon-yellow leaves is usually "Each flower or leaf is about the size of your thumbnail, perfectly circular, slightly concave, and the color of a deep, almost fluorescent lemon yellow. Subtle veins run through the semi-translucent skin. They sprout from the vines wrapped around the branches, each about a finger width apart[leafhint].". Check touching some lemon-yellow leaves: move yellow-stain to location; say "They are surprisingly firm under your touch, and have the thick, slightly spongy feel of a heavy leaf when you squeeze one. As you pull your finger away, you see it has picked up a slight yellow stain." instead. Check tasting some lemon-yellow leaves: say "You pull one of the small leaves off the vine-- it is surprisingly difficult-- bite it in half and chew. The texture is crunchy, almost like a carrot slice, but the taste bland and indefinable. Some juice trickles down your chin; when you wipe it off, your finger picks up a bright yellow pigment." instead. Instead of pulling or cutting or attacking some lemon-yellow leaves, say "[takeleafbit]". To say takeleafbit: say "You pull one of the small leaves off the vine-- it is surprisingly difficult-- and rub it between your fingers. It has the thick, somewhat spongy feel of a heavy leaf. As you let it drop to the ground, you see that your finger has picked up a slight yellow stain."; move yellow-stain to location. First Check taking lemon-yellow leaves: say "[takeleafbit]" instead.

To say leafhint: if ( time for excitement or story mode ) and Back Room is visited and Jumble is unvisited, say ".[paragraph break]You notice that the leaves are the exact shade of the yellow band painted on the back room door of the cabin on the beach".

A yellow-stain is a set dressing. Understand "stain/finger" as yellow-stain. The printed name is "yellow stain". The description is "The lemon-yellow pigment inside these leaves is strong and vibrant.". Check tasting yellow-stain: say "There is no taste to it." instead. Check touching yellow-stain: say "It rubs off fairly easily." instead. Check taking yellow-stain: say "It's just a slight smudge on your finger.".

Some treevines are a kind of prop. Some treevines are part of every windsigh tree. Some treevines are portable [well, not really, but allows us to print better taking message]. Understand "vine" or "vines" or "tight" or "spirals" or "of" as some treevines. The printed name of treevines is "vines". The description of treevines is "The vines sprout from orifices about the size of your wrist spread out all over the trunk of the tree, and wrap tightly around it in a helix spiraling up, splitting and shrinking in diameter, until each one leaves the trunk to twine out around a branch, sprouting hundreds of small lemon-yellow [o]leaves[x]." Instead of pulling or taking treevines, say "The vines spring from the trunk and are tightly wrapped around it and the branches. They seem to be attached to the tree by thousands of tiny hook-like hairs.". Check climbing a treevines: try climbing a random windsigh tree enclosed by the location instead. Check attacking a treevines: try attacking a random windsigh tree enclosed by the location instead.

Some sinuous branches are a kind of setpiece. Some sinuous branches are part of every windsigh tree. Understand "branch/branches" or "sinuous" or "dozens" as sinuous branches. The description of sinuous branches is usually "The branches spread out in all directions, beginning at about eye level, angled only slightly to the horizontal as they leave the trunk but then curving upwards to eventually become vertical. Every branch is wrapped in vines sprouting the yellow leaves or [o]flowers[x]. The vines even curve around the strange [o]holes[x] that appear at random along the length of each branch.". Check attacking a sinuous branches: try attacking a random windsigh tree enclosed by the location instead. Check climbing a sinuous branches: try climbing a random windsigh tree enclosed by the location instead.

Some tree-holes are a kind of setpiece. Some tree-holes are part of every windsigh tree. Understand "hole/holes" as some tree-holes. The description of tree-holes is usually "They range in size from knobby round gaps nearly as big as your head, in crooks and splits near the trunk, to tiny pinholes trailing along the ends of the smallest branches, and run all the way through the wood, letting you see through to the other side.". Understand "blow on/in/through [tree-holes]" or "blow [tree-holes]" as a mistake ("You blow through a tiny hole along a low hanging branch, and produce a momentary crystal-clear hum."). The printed name of tree-holes is "holes in the tree". Understand "hole/holes" as tree-holes.

Instead of touching sinuous branches, tree-touch. Instead of touching treevines, tree-touch. To tree-touch: if location is Treehouse begin; let bub be Tree2; otherwise if location is Saddle; let bub be Tree3; otherwise; let bub be a random windsigh tree enclosed by the location; end if; try touching bub.

Instead of touching or pushing a windsigh tree:

if Endgame is happening begin;

say "You feel the warm thrum of consciousness flow through the tree, but there is no time for dream games now.";

otherwise if the number of uncontacted windsigh trees is 0;

say "You place your hand against the side of the tree and at once the familiar thrum runs through you. You slip into dreamspace....";

now pseudo-dream is 1;

now old time factor is time factor;

now time factor is 0;

now the player is asleep;

otherwise if mind machinery is calibrated;

if noun is contacted begin; say "You feel the warm thrum of consciousness flow through the tree, and a teasing touch of familiarity. This one has shared its message with you already. You must find the others to learn more.";

otherwise;

say "Finding a spot of bare grayish bark between the spiraling vines, you touch the tree. [one of]A gust of wind kicks a pile of leaves into the air. [or][stopping]The trunk seems warm to the touch, and your fingers feel something else: a miniscule vibration? The faint buzz of an electric current? Suddenly the sensation magnifies, as if caught in some feedback loop, and before you can pull away it completely overwhelms you....";

[We want to fudge a bit here in case the player has gotten this far without seeing the Tsunami. We need to advance Progue to at least uncertainty (the post-Tsunami psyche) for his dramatic resolution to make sense, and this ensures that we'll get the Tsunami even if we're no longer sleeping.]

if Tsunami Sequence has happened begin;

now pseudo-dream is 1; [normal behavior; pass no time while dreaming]

else if The Conch Portends is completed;

change the time of day to 10:30 PM; [to trigger Earthquake]

else;

change the time of day to 5:55 PM; [to trigger Tsunami Sequence / The Conch Portends]

end if;

now old time factor is time factor;

now time factor is 0;

now the player is asleep;

end if;

otherwise;

say "Finding a spot of bare grayish bark between the spiraling vines, you touch the tree. The trunk seems warm to the touch, and your fingers feel something else: a miniscule vibration? The faint buzz of an electric current? You draw your hand back and rub it curiously.";

end if.

Check climbing a windsigh tree (called the climbee) when mind machinery is calibrated and the number of uncontacted windsigh trees > 0: try touching the climbee instead.

Check climbing a windsigh tree when location is not Big Tree and location is not Saddle and location is not Egg and location is not Treehouse:

if we have not touched noun, try touching the noun;

pass 10 minutes of time;

say "The vines and gnarled branches [if player is wounded]would make for an easy climb if your leg wasn't still tender[else]make it an easy climb[end if][if raining or rained], though they are slippery in the rain[end if]. The tree is not too high, and before long you are standing at a crook in the trunk where it finally splits. Yellow flowers surround you. [if location is Fork or location is Big Tree]You can see that the tree stands on a great forested slope, stretching up to the summit of a volcano and down to a white sand crescent beach[otherwise if location is Cinder Cone]The whole volcano floor stretches out before you: the multitude of steam vents, the great rent in the side of the caldera leading off towards the beach, and the jumble of lava rocks all around[otherwise if location is Forest9]Though you're still below most of the treetops, you can see that you're near the eastern edge of the forest, as the land suddenly drops off not far in that direction[otherwise if location is Rockslide]You can see clearly how the treacherous lava flow neatly bisects the island, forming the cliffs against the beach on its west half and marking the edge of the rain forest on its east half. In the north, the flow merges with a steep arm of the mountain[end if]. [paragraph break]After enjoying the view for a while, you climb back down to solid ground again." instead.

Check climbing tree2: try going up instead. Check climbing tree3: try going up instead.

A nook is a kind of supporter. A nook is usually undescribed and enterable. Understand "nook" as a nook. Check taking a nook: say "It's just a hollow in the ground." instead. The dream-text of a nook is usually "[one of]worn blankets[or]deadwood[in random order]". Check putting something on a nook: say "Better hang on to it; you don't want to lose it." instead.