Blue Lacuna — 472 of 475

Section - Coda

Epilogue-Ending-A is a scene. Epilogue-Ending-A begins when eplr_another is spoken or eplr_coincidence is spoken.

ep-timer is a number that varies.

When Epilogue-Ending-A begins:

begin chapter 11;

change the time of day to 7:08 AM;

change the time factor to 1;

repeat with thepot running through paintpots begin;

move thepot to Studio;

end repeat;

if Progue is not dead begin;

remove pot of blue paint from play;

change the initial appearance of ep-Progue to "Progue stands nearby[if eea_takebrush is unspoken], holding out your [o]paintbrush[x] expectantly[else], awaiting your response[end if].";

change the description of ep-Progue to "He's been doing much better. You hope soon he'll be ready to leave this world as well.";

otherwise;

move ep-paintbrush to yourself;

end if;

remove artisan tools from play;

now the ep-canvas is in Studio;

move yourself to Studio;

say "You rise slowly to your feet, stretching out aches and pains. You remember now: staring at your blank canvas for hours long into the darkness.".

The ep-canvas is a fixed in place described thing with printed name "canvas". Understand "canvas" or "painting" or "hide" as ep-canvas. The description is "Dried and taut, boar-hide still exuding faint smells of animal, the canvas awaits your paint.".

ep-Progue is a man with printed name "Progue". "Progue is here." Understand "Progue" as ep-Progue. The description is "Progue is here.".

Every turn when location is Studio and current chapter is 11 and ep-timer is not -1:

increase ep-timer by 1;

if ep-timer > 3 and Progue is not dead and Progue is not enclosed by location:

now ep-timer is -1;

remove Progue from play;

move ep-paintbrush to Studio;

move ep-Progue to Studio;

now ep-Progue is attentive;

move pot of blue paint to Studio;

now tempfuse of eea_intro is 5;

force discuss eea_intro;

if ep-timer > 2 and Progue is dead:

say "[one of][eea-noprogue-choice][or][stopping]".

To say eea-noprogue-choice: say "Your brush tingles in your hand, and the paints await you on the workbench: [t]red[x], [t]yellow[x], [t]green[x], [t]black[x], [t]white[x], and [t]blue[x]. To begin you must only choose one to start with.".

EEA is a thread. eea_intro is an exciting beat in eea with reaction "Progue steps in through the open doorway, carrying a wooden pot.[paragraph break]'At last, finished,' Progue says, putting the pot of blue paint down on the counter. 'Voices from the stars would be horrified that we're using their precious somenium for this, but one can't paint anything without blue,' he adds cheerfully.[paragraph break]'Oh,' he says, 'and your [o]paintbrush[x], too.' He pulls the brush out and holds it out to you.". Instead of vague discussing when last beat is in EEA, say "There's so much else to talk about, but, at the same time-- perhaps everything that needs to be said is said.".

The ep-paintbrush is a prop with printed name "paintbrush". Understand "paintbrush" or "paint brush" or "brush" as ep-paintbrush. Instead of examining ep-paintbrush: try taking ep-paintbrush.

Instead of painting or vague painting when ep-canvas is enclosed by location:

if Progue is dead:

say eea-noprogue-choice;

else if eea_intro is unspoken:

say "You can't seem to find your paintbrush.";

else:

force discuss eea_takebrush.

Instead of taking a paintpot when location is Studio and ep-canvas is enclosed by location: say "They are easily accessible where they are.".

Check vague discussing when location is Studio and ep-canvas is enclosed by location: say "You can't think of what to say." instead.

Instead of taking ep-paintbrush when location is Studio: force discuss eea_takebrush. eea_takebrush is a beat in EEA with reaction "The brush tingles your hand with something almost or barely electric. It seems to connect you and Progue along the length of the wooden handle; he holds on for a fraction of a second as your eyes meet, and something ionic passes between you.[paragraph break]Then he lets go. The brush is in your hand, and something in you changes. Or remembers.[paragraph break]'I'll leave and leave you to it, then,' Progue says quietly. 'Seas of canvas need filling, and for me, well, quotas of rock. No need to linger over parting.' He half-turns, on the brink of leaving.". eea_takebrush suggests eea_saynothing. eea_whattopaint replaces eea_takebrush.

[The player is the protagonist; Progue and the trees/rebels has been your antagonist by causing you to realize love is the most important choice. (??)]

Instead of hugging ep-Progue when last beat is eea_takebrush: say "You hug Progue and he hugs back, his weatherworn cheek pressed against your neck, and [weatherwornbit]. You step back and know now you are ready to leave this place."; force discuss eea_whattopaint.

Instead of kissing ep-Progue when last beat is eea_takebrush: say "You kiss Progue [if romance of Progue > 3]gently and tenderly, raising one hand to his weatherworn face[else]on each weatherworn cheek, an old custom from past worlds that seems somehow appropriate[end if], and [weatherwornbit]. You step back and know now you are ready to leave this place."; force discuss eea_whattopaint.

Instead of pushing or attacking ep-Progue when last beat is eea_takebrush: say "Here, at this final moment, all the anger and violence has drained from you; you cannot bring yourself to. You turn wearily from Progue back to your canvas."; force discuss eea_whattopaint.

Instead of saying farewell to or thanking ep-Progue when last beat is eea_takebrush: say "He clutches your outstretched hand warmly for a long moment.[paragraph break][cookiemetaphor].' He smiles and you smile back, then release him and turn to your canvas."; force discuss eea_whattopaint.

Instead of giving something to ep-Progue when last beat is eea_takebrush: say "You hand [the noun] to Progue. Wordlessly he accepts it, holds it delicately and studies it in the light of the setting sun. Then he clutches your hand for a long moment.[paragraph break][cookiemetaphor].'[paragraph break]Finally he releases his grip, and you turn to your canvas."; force discuss eea_whattopaint.

eea_saynothing is a beat in EEA with reaction "You can think of nothing to say or do or think in this moment, suspended somehow from relentless gravities of time. And it seems that neither can Progue. He stares back, also wordless, for long moments.[paragraph break]But finally something passes between you, perhaps without either of you willing it, and you nod, and breathe, and turn to your canvas.". eea_saynothing enqueues eea_whattopaint.

[{Progue hands you a brush.[otherwise]The blue paint, which you pounded all yesterday from mud and somenium crystals, rests atop the counter, the last of the paints to be gathered and prepared.[end if] The canvas is ready. ]

eea_whattopaint is a beat in EEA with reaction "'And do you know, wayfarer,' Progue says quietly, as your eyes ride smoothly over the taut, textured surface of the hide, 'do you know what it is you will paint today?'". The yes-beat of eea_whattopaint is eea_yes. The no-beat of eea_whattopaint is eea_no. eea_whattopaint summons eea_yes, eea_no. eea_whattopaint suggests eea_no. eea_whichcolor replaces eea_whattopaint.

eea_yes is a beat in EEA with keyword name "yes" and reaction "He nods. 'Yes. Yes, I thought you did.'". eea_yes enqueues eea_whichcolor.

eea_no is a beat in EEA with keyword name "no" and reaction "He nods. 'Good,' he says, 'then you will not be disappointed, whatever you find.'". eea_no enqueues eea_whichcolor.

eea_whichcolor is a beat in EEA with reaction "'Well. Your paints await you: [t]red[x], [t]yellow[x], [t]green[x], [t]black[x], [t]white[x], and [t]blue[x]. To begin you must only dip your brush in one.'[paragraph break]He rests his hand on the workbench for a moment, looking searchingly into its grain, then abruptly turns to the open doorway. He pauses one last moment, turning back to watch.[paragraph break]'Go on, then,' he says, 'which will it be?'". eea_whichcolor summons eea-blue, eea-other. eea_whichcolor suggests eea_proguewaits. Instead of examining a paintpot when eea_whichcolor is spoken: if noun is pot of blue paint, force discuss eea-blue; else force discuss eea-other.

eea_proguewaits is a repeatable beat in EEA with reaction "Progue [one of]waits silently for you to make the choice[or]stands quietly, waiting for you to choose[at random].". eea_proguewaits suggests eea_proguewaits.

Understand "blue" as eea-blue when last beat is in EEA. eea-blue is a terminal beat in eea with keyword name "blue" and fuse 99 and reaction "Trembling, you reach your brush towards the blue paint. The swirls of powdered crystal sparkle brilliantly in the morning sun, slanting through the window, and as bristles join its surface, vague whispered ripples disturb some rare medium of thought, memory, longing[unless Progue is dead].[paragraph break]Progue nods once, gives you one last smile, and then is gone[end unless].[paragraph break]You lift the blue-tipped brush to the canvas, eyes closed, and picture Rume. But not just with your mind. You picture [if Rume is male]him[else]her[end if] with each cell in your lone and travelworn body. You picture [if Rume is male]him[else]her[end if] with the hair you once touched and skin once shared. You picture Rume with hand, palm, knuckles, fingers, with every bristle of the blue-stained brush to the potent atoms at its tip, crushed molecules of an impossible substance that dreams with you an impossible dream, and slowly begin to paint.[paragraph break]The bristles touch canvas, and the sound they make is a delicate sigh, clung to the near edge of silence.".

Understand "red/green/yellow/white/black" as eea-other when last beat is in EEA. eea-other is a terminal beat in eea with keyword name "red, green, yellow, white and black" and fuse 99 and reaction "[nonbluecolending]".

To say nonbluecolending:

let tcol be 1;

if the player's command includes "red":

let tcol be 1;

else if the player's command includes "green":

let tcol be 2;

else if the player's command includes "yellow":

let tcol be 3;

else if the player's command includes "white":

let tcol be 4;

else if the player's command includes "black":

let tcol be 5;

say "You reach your brush out and submerge it in the thick [if tcol is 1]red[else if tcol is 2]green[else if tcol is 3]yellow[else if tcol is 4]white[else]black[end if] paint. Soon you will blend it with other colors, but it feels right that your first touch to the canvas should be pure, unmixed[unless Progue is dead].[paragraph break]Progue nods once, gives you one last smile, and then is gone[end unless].[paragraph break]You touch the brush to the hide, tentative, caressing. ";

say "[if tcol is 1]The red smears its surface like blood, rich heart-blood that flows deep inside[else if tcol is 2]The green streaks across its surface, a shock of forest and emerald and spring[else if tcol is 3]A shock of yellow brightens its surface, the lemon-yellow hue that brought you here years or hours ago[else if tcol is 4]Pure white soaks into the hide, snow and clouds and fog-wrapped air[else]Ink black seeps into the hide, midnight and dream[end if]";

say ", and in that instant, with prickles of nerve memory, at last you know the way forward.".

After discussing eea-blue: end the game in victory. After discussing eea-other: end the game in victory.

Instead of landmark-going or going or exiting or retreating during Epilogue-Ending-A: say "You have unfinished business with your canvas.". First check landmark-going during Epilogue-Ending-A: say "You have unfinished business with your canvas.".

After reading a command when Epilogue-Ending-A is happening and Progue is dead: if the player's command matches the text "blue", force discuss eea-blue; if the player's command matches the text "red" or the player's command matches the text "yellow" or the player's command matches the text "black" or the player's command matches the text "white" or the player's command matches the text "green", force discuss eea-other.