Blue Lacuna — 450 of 475

Volume - City (in Lacuna-Rebelworld by Blue Lacuna)

Visiting Rebelworld is a recurring scene. Visiting Rebelworld begins when the mind machinery is projecting and the machinery-password exactly matches the text rebel-password and Visiting Rebelworld is not happening.

When Visiting Rebelworld begins:

if the player is male, now DrQuick is male;

otherwise now DrQuick is female;

change the player to DrQuick;

change the time of day to 12:01 PM;

now yourself is asleep; [helps out various rules.]

try looking.

Visiting Rebelworld ends nominally when the player is yourself. Visiting Rebelworld ends successfully when cl_story7 is spoken and the player is yourself.

When Visiting Rebelworld ends nominally:

move DrQuick to Memorial Park;

now DrQuick wears the cap;

unless Visiting Treeworld ended successfully, set up the endgame storm.

When Visiting Rebelworld ends successfully:

if rap sheet of DrQuick < 5, move DrQuick to Cafeteria;

now DrQuick wears the cap;

move Cloudeye to Cafeteria;

[ now Ditching The Rebs is met;]

remove leader from play;

if Visiting Treeworld ended successfully, set up the endgame afterstorm;

else set up the endgame storm.

Check taking off when the player is regionally in Rebelworld and noun is cap and StraightTalkWithRebelLeader is not happening (this is the remove cap to leave Rebelworld rule):

say "You remove the cap from your head. Within a second your surroundings become fuzzy and indistinct-- a sudden moment of vertigo--";

now yourself is awake;

change the player to yourself;

print a section break;

say "[bold type][location][roman type][line break][description of location]" instead. [We do this instead of looking because we want to show the description of the area, not the chair controls, to emphasize we've returned to Lacuna.]

Carry out landmark-listing when location is regionally in Rebelworld: say "This place is so different and strange, it's hard to get your bearings."

Instead of sleeping when location is regionally in Rebelworld: say "You're far too keyed up to sleep right now.".

Check examining DrQuick: try taking inventory instead.

[

say "The landmarks you can go to are: ";

repeat with locale running through visited landmarked rooms regionally in Rebelworld begin;

say "[line break] ";

if the landmark name of locale is not "null", say the landmark name of locale; otherwise say locale;

end repeat.]

[Plaza and Space Museum are landmarked.]

Memorial Park is inside from Plaza. Rebelworld-Outdoors is a region. Plaza, Room1, Room2, Room3, Room4, Room5 are in Rebelworld-Outdoors. Rebelworld-Outdoors, Lab, Memorial Park, Library-Room, Space Museum, Room6, and Room7 are in Rebelworld.

DrQuick is a person. DrQuick is in Lab. The printed name is "Quick".

DrQuick wears a passcard. The description of a passcard is "It's a small rectangle of baked stone, with an intricate series of notches and holes running along one side, attached to a chain around your neck.". Instead of taking off passcard, say "The rectangle does not seem able to detach from the chain, and the chain in turn loops so closely around your neck you could not pass it over your head." Understand "pass/card" as passcard.

DrQuick wears a cap. The description of the cap is "The cap seems to be part of the uniform, but running your hands around it you can feel all sorts of wires and protuberances woven into the inner lining. A cable snakes down your neck and back to a bulky transmitter unit attached to your belt.". Understand "hat" as cap.

A coin is a kind of thing. DrQuick carries three coins. The description of a coin is "A small disc of some lightweight silver metal, embossed with the image of a stern-looking elderly woman.". Understand "coins/money" as a coin.

DrQuick wears a uniform. The description of uniform is "Stiff, uncomfortable, made of coarse fabric dyed deep charcoal-grey. But something about the large buttons rising up the left-hand side to the shoulder, and the cut of the collar, implies a degree of respect may be given to the wearer.". Instead of taking off uniform, say "But you have nothing else to wear." Understand "jacket" as uniform.

Check eye closing during Visiting Rebelworld: say "You close your eyes deliberately for a long moment, but nothing happens." instead.