Blue Lacuna — 442 of 467

Section - The Mural

A muralroom is a kind of room. Mural Far West is a muralroom. Mural West is a muralroom. Mural Center is a muralroom. Mural East is a muralroom. Mural Far East is a muralroom.

Report going from a muralroom (called orig) to a muralroom (called dest):

if dest is Mural Center:

say "The meadow widens into a wide circle, where the broad avenue heading up the slope intersects it.";

else if noun is east:

say "You follow the slab of rock with the mural, continuing down the immaculate meadow towards the [unless dest is Mural Far East]distant [end if]cliff.";

else if noun is west:

say "You follow the slab of rock with the mural, continuing up the immaculate meadow towards the [unless dest is Mural Far West]distant [end if]waterfall.".

Report going from Mural Far East to Nursery: say "You walk through the trees until you come into another clearing.".

The great slab is an undescribed backdrop. The slab is not scenery. The initial appearance is "[if location is Mural Far East]Running straight to the edge of the cliff is[end if][if location is Mural Far West]Rising from the ground near the edge of the trees is[end if][if location is Mural West or location is Mural East]Bisecting the meadow is[end if][if location is Mural Center]Stretching from either side of the spire is[end if] [slab]". The great slab is in Mural Far West, Mural West, Mural Center, Mural East, and Mural Far East. Understand "mural" or "rock" or "etchings" or "history" as the slab.

Definition: a thing is unexamined if we have not examined it.

To say slab:

if Mural Far West is unvisited and Mural West is unvisited and Mural East is unvisited and Mural Far East is unvisited, say "a great [o]slab[x] of rock"; otherwise say "the rock [o]slab[x]";

if great slab is unexamined, say ", covered with an incredibly detailed series of etchings";

if we have examined the great slab exactly once, say ", inscribed with the history of this world";

say ". It continues ";

if dir, say "[if location is not Mural Far East]east [end if][if location is not Mural Far East and location is not Mural Far West]and [end if][if location is not Mural Far West]west [end if] through";

otherwise say "down the center of";

say " the meadow";

Before examining the great slab for the first time, say "You step closer to the rock slab, which rises a head shorter than you, and are taken aback by the level of detail. Each square foot of this enormous wall must have taken months of work. Even the finest details are etched, with clinical precision and exactitude."

The description of the slab is "[if location is Mural Far West]The first panel depicts a forest of hundreds of windsigh, each twist and curve in every branch and millions of lemon-yellow leaves chiseled faithfully into the rock. As you follow the mural down the meadow, incredibly faint golden lines begin to connect the trees. The lines quickly multiply and become thicker and stronger, and begin to connect to abstract patterns of gold hovering in the sky above the Trees that grow more and more complex.[end if][if location is Mural West]A single tree stands out on this panel, with large-eyed human-like creatures crawling over and around it. On the farthest branch, a single one stands stricken, hand to her head and eyes open wide with awe, one tiny golden strand reaching out to touch her head.[end if][if location is Mural Center]The slab rises into a great rounded outcrop here, which shows, in giant size and incredible detail, the picture you saw on the egg on Lacuna: a human form, hands outstretched and head a smooth oval, intertwined with the roots of a stretching Tree.[end if][if location is Mural East]An incredibly detailed scene is carved into the rock here. Hundreds of people, each linked to one or more trees by a tiny golden strand, labor to tend trees, carry seeds off to distant lands, and build tools, from baskets to sailing ships to microscopes and stranger vehicles. The people are linked only to the trees; never to each other.[paragraph break]The panel ends showing an elaborate mining operation, with a single man pulling a hexagonal crystal from the ground with a look of reverent awe. All the golden threads near the crystal run through it, and are strengthened tremendously as they pass through it.[end if][if location is Mural Far East]This part of the epic etching shows the whole planet, covered in trees, with the arm of a minutely detailed galaxy behind it. Tiny egg ships depart in all directions, each one carrying a human crew, tree seedlings, and a tiny fragment of the hexagonal crystal. Hundreds of stars in the galaxy glow green, and an impossibly tiny web of golden lines connects them.[end if]".

After examining the great slab, say "[if location is Mural Far East]The mural ends here[otherwise]The mural continues [end if][if location is not Mural Far East]towards the [d]cliff[x][end if][if the player has not been in Mural Far West]. It must begin [end if][if the player has not been in Mural Far West]farther towards the [d]waterfall[x][end if]."

The description of Mural Far West is "A bubbling waterfall cascades down a rocky slope here at the edge of [meadow].[paragraph break][initial appearance of great slab].[paragraph break][exits]." The exits text of Mural Far West is "The meadow heads towards a distant [d]cliff[x], while angled paths lead through the trees towards [if Map Room is unvisited]a [d]dome[x][otherwise]the [d]dome[x][end if], [etmfw2]". To say etmfw2: say "[if Shrine is unvisited]a [d]circle[x] of trees[otherwise]the [d]temple[x][end if], or back into the [d]forest[x]". Understand "forest" as south when location is Mural Far West. Understand "dome" as southeast when location is Mural Far West. Understand "cliff" as east when location is Mural Far West. Understand "circle" or "temple" as northeast when location is Mural Far West.

A bubbling waterfall is a setpiece in Mural Far West. The description is "The waterfall trickles down a rocky slope and pools in a small stream, which meanders off and vanishes into the forest of windsigh.". Understand "small/stream/rocky/slope" as bubbling waterfall. Instead of tasting or taking bubbling waterfall, say "The water is just slightly colder than the air and has a pleasant, loamy aftertaste.".

Report going from Mural Far West to Outside the Dome: say "You approach the dome structure.".

The description of Mural West is "[initial appearance of great slab]. Tiny white flowers dot the grass here, gathering in bunches at the base of the slab.[paragraph break][exits].". The exits text of Mural West is "Cutting through the trees, [meadow] continues towards the distant [d]cliff[x] or the [d]waterfall[x], lined by thick windsigh forest on either side". Understand "waterfall" as west when location is Mural West. Understand "cliff" as east when location is Mural West.

The description of Mural Center is "The rock slab crosses the broad avenue sloping up to the high point of the ridge, surrounded by a wide circular lawn. Twin foot [o]bridges[x] cross the mural to either side of a central [o]spire[x] that rises from the slab, rich with inscribed imagery.[paragraph break][exits].". The exits text of Mural Center is "The wide avenue runs [up] towards [the Distant Philosopher] and [down] towards the reflecting pool, while the narrower meadow with the slab runs perpendicular towards a [d]cliff[x] or a [d]waterfall[x]". Understand "waterfall" as west when location is Mural Center. Understand "cliff" as east when location is Mural Center.

The twin foot bridges are a setpiece in Mural Center. The description is "The bridges are carved from stone, delicate etchings of stylized vine twining around their graceful grey supports. They rise up and above the natural stone slab on either side of the central spire, leaving the mural itself untouched.". Understand "bridge" as twin foot bridges. Instead of entering or crossing twin foot bridges: say "You walk across the nearer bridge, moving from one side of the rock mural to the other, where you see an identical scene has been etched.".

The stone spire is a setpiece in Mural Center. Instead of examining the stone spire, try examining the slab.

Report going from Mural Center to Avenue North: say "You cross one of the graceful stone bridges and continue up the grassy avenue, approaching the base of [the Distant Philosopher].".

The description of Mural East is "[initial appearance of great slab].[paragraph break][exits].". The exits text of Mural East is "Cutting through the trees, [meadow] continues towards the nearby [d]cliff[x] and the distant [d]waterfall[x]". Understand "waterfall" as west when location is Mural East. Understand "edge" or "cliff" as east when location is Mural East.

The description of Mural Far East is "A sudden drop-off marks the end of [meadow]. The distant forest below glows in the red light of the giant sun.[paragraph break][initial appearance of great slab].[paragraph break][exits]." The exits text of Mural Far East is "Paths curve into the [d]forest[x] and towards some [d]huts[x] or a [d]nursery[x] closer at hand. The meadow runs towards the distant [d]waterfall[x]". Understand "waterfall" as west when location is Mural Far East. Understand "nursery" as northwest when location is Mural Far East. Understand "forest" as south when location is Mural Far East. Understand "huts" as southwest when location is Mural Far East.

The tree-cliff is a setpiece in Mural Far East with printed name "cliff". Understand "cliff/cliffs" as tree-cliff. The description is "The cliff drops off to a vast expanse of windsigh filling a gently sloping river basin, stretching off to the huge red sun floating above the horizon.". Instead of climbing or entering tree-cliff: say "The drop is tremendous-- even the thought of climbing it makes you queasy.".

To say meadow:

if Mural Far West is unvisited and Mural West is unvisited and Mural Center is unvisited and Mural East is unvisited and Mural Far East is unvisited, say "a long, meandering grassy meadow";

otherwise say "the meadow".