Blue Lacuna — 427 of 467

Volume - Forest (in Lacuna-Treeworld by Blue Lacuna)

nlt_bit is a number that varies. nlt_bit is 0.

To notice language translation: [ The first time we see someone talk on either world, we'll notice that the language is being translated by the host body. ]

if nlt_bit is 0 begin;

now nlt_bit is 1;

say "Strange. You notice that the sounds [the random other person in the location] makes are actually incomprehensible; [hisher] lips do not make the movements you'd expect them to; and yet you can understand, perfectly.";

end if.

skeletons_bit is a number that varies. skeletons_bit is 0.

Plateau is a region. Plateau is in Treeworld. Overlook is a room in Plateau.

A Lacunite is a kind of person. The description of a Lacunite is usually "Dressed in a flowing red robe that trails along the ground; not quite human, but close enough that it doesn't bother you.". Instead of attacking a Lacunite: say "You savagely attack [the random other Lacunite in the location], who reels back in astonishment. [CHeShe] turns and flees."; remove the random other Lacunite in the location from play; increase the rap sheet of Lacunite-Follower by 3.

Check hugging a Lacunite: say "[The noun] watches you in bemusement as you do so. 'We are as real as you,' [heshe] says, 'not biologically identical, but of remarkably similar physical and even genetic structure.'" instead.

Check vague discussing when location is regionally in Treeworld: say "You are having a hard enough time keeping up with the conversation as it is." instead.

Check getting bored when location is regionally in Treeworld: post-conversation processing; do nothing instead.

A robe is a kind of thing. A robe is worn by every Lacunite. The description is "The robe is fashioned from something thin with the texture of felt. A deep, rich red, it is wrapped simply around the body and trails on the ground behind."

Lacunite-Follower is a person in Overlook [This is the body the player will inhabit while here]. Lacunite-Follower wears a robe. Lacunite-Follower is either identified or unidentified. Lacunite-Follower is unidentified. [Shows whether marked so treeworld people recognize him as the visitor.]

Visiting Treeworld is a recurring scene. Visiting Treeworld begins when the mind machinery is projecting and the machinery-password exactly matches the text tree-password and Visiting Treeworld is not happening.

When Visiting Treeworld begins:

if the player is male, now Lacunite-Follower is male; [ Since we want both worlds to be presented on an even playing field, and to avoid false gender-based assumptions about either Forest or City, we choose to give both bodies the same gender as the player. ]

otherwise now Lacunite-Follower is female;

move Lacunite-Follower to Overlook;

change the player to Lacunite-Follower;

now yourself is asleep; [helps out various rules.]

now the time of day is 7:00 PM;

now the time factor is 0;

try looking.

Visiting Treeworld ends nominally when the player is yourself. Visiting Treeworld ends successfully when gp_outtro is spoken and the player is yourself.

When Visiting Treeworld ends:

if rap sheet of Lacunite-Follower < 5, move Lacunite-Follower to a random room in Treeworld;

unless Visiting Rebelworld ended successfully, set up the endgame storm.

. [The character continues to go about its business.]

[When Visiting Treeworld ends successfully:

now Ditching The Trees is met.]

When Visiting Treeworld ends successfully:

if Visiting Rebelworld ended successfully, set up the endgame afterstorm.

Check sleeping when the player is regionally in Treeworld (this is the close eyes to leave Treeworld rule):

say "You close your eyes deliberately for a long moment, but feel no change. But when you open them--";

now yourself is awake;

change the player to yourself;

print a section break;

say "[bold type][location][roman type][line break][description of location]". [We do this instead of looking because we want to show the description of the area, not the chair controls, to emphasize we've returned to Lacuna.]

Carry out landmark-listing when location is regionally in Treeworld: say "This place is so different and strange, it's hard to get your bearings."

[Reflecting Pool, Outside the Dome, Among the Huts, Nursery, Ancient Temple, and Base of the Great Tree are landmarked. The landmark name of Reflecting Pool is "the reflecting [d]pool[x]". The landmark name of Outside the Dome is "the [d]map[x] room". Understand "map" as Outside the Dome. The landmark name of Among the Huts is "the maker [d]village[x]". Understand "village" as Among the Huts. The landmark name of Nursery is "the thinker [d]nursery[x]". The landmark name of Ancient Temple is "the [d]temple[x] circle". The landmark name of Base of the Great Tree is "[d]base[x] of the Philosopher".

Carry out landmark-listing when location is regionally in Treeworld:

say "The landmarks you can go to are: ";

repeat with locale running through visited landmarked rooms regionally in Treeworld begin;

say "[line break] ";

if the landmark name of locale is not "null", say the landmark name of locale; otherwise say locale;

end repeat.]