Blue Lacuna — 424 of 467

Chapter - Forest9 Flashback

[Phoebe and Lethe hunt for boar, ready to paint their way out of this world.]

Dream-Forest9 is a flashback-room in Dreamlands. The printed name is " In The Rain Forest ".

The description of Dream-Forest9 is "[dforest9desc].". To say dforest9desc:

if boar is enraged or dead-boar is enclosed by location:

say "Everything else fades away";

else if player is D9-Phoebe:

say "The forest is still in the twilight, and your muscles are sore from staying frozen in one position for so long. No matter how many times you dry your sweaty palms the [o]spear[x] still feels slippery, your grip loose. But this must be done, or you will stay here forever. And neither of you want that";

else:

say "The villagers will wear blue. You nod to yourself as you decide this, trying to ignore the quivering cramps in your thighs, the droplets of leftover rainwater spilling down your neck from some high mountain branch. The [o]spear[x] feels awkward in your hand as you crouch behind the [o]windsigh[x]. As evening seeps in to the forest around you, you try to forget it".

Dream-Forest9-stuff is stuff in Dream-Forest9. Understand "forest/twilight/muscles/sweat/cramps" as Dream-Forest9-stuff when location is Dream-Forest9.

The d9-windsigh is a setpiece in Dream-Forest9. Understand "tree9/windsigh" as d9-windsigh when location is Dream-Forest9. The printed name is "windsigh". The description of d9-windsigh is "The wind breathes through the gaps in its branches faintly, a ringing wail that ebbs and flows in pitch and volume, cyclical alien music.". Instead of climbing d9-windsigh, try greeting a random other person enclosed by location.

D9-Lethe is a dream-lethe in Dream-Forest9. Understand "sister" as D9-lethe when location is Dream-Forest9 and player is d9-phoebe. The printed name of D9-lethe is "[if player is D9-Phoebe]your sister Lethe[otherwise]Lethe". Rule for writing a paragraph about D9-Lethe: say "[if boar is enraged and player is boar_victim][otherwise if boar is enraged and dead-boar is not on-stage]Your [o]sister[x] stands paralyzed, directly in the [o]boar[x]'s path.[otherwise]Your [o]sister[x] crouches on the other side of the clearing, near the windsigh, only barely visible under her camouflage.". The description is "[if boar is enraged]The boar's attack has flushed your system with adrenaline; all else is irrelevant.[otherwise if player is d9-phoebe]She {(*[d]lethe[x]*)} has grown up a lot, in the past year. She is starting to become a woman. You both are, you suppose. Not just physically, but mentally as well. Learning to look after yourselves. Watching over dad, making sure he doesn't hurt himself when he has his fits. Yet at the same time, Lethe has become even more lost in fantasy, in dreams. She spends hours staring at her fantastical paintings, as if lost in them, and the rare times you have conversations these days she speaks only about the worlds in her mind, never about this place. Never about dad.[otherwise]You have it all planned out, the world you will go to. Hot meals, warm beds. A large family who will be overjoyed to adopt a friendly orphan girl into their brightly-colored, thatched-roof houses. The warm flabby arms of aunts, the scent of cinnamon and fruit pies. Mountains to explore, people to return to. A home.[paragraph break]You will miss Phoebe. But it is time to move on.".

D9-Phoebe is a dream-phoebe in Dream-Forest9. Understand "sister" as d9-phoebe when location is Dream-Forest9 and player is d9-lethe. The printed name of d9-phoebe is "[if player is d9-lethe]your sister Phoebe[otherwise]Phoebe". Rule for writing a paragraph about D9-Phoebe: say "[if boar is enraged and player is boar_victim][otherwise if boar is enraged and dead-boar is not on-stage]Your [o]sister[x] stands paralyzed, directly in the [o]boar[x]'s path.[otherwise]Somewhere on the other side of the clearing is your [o]sister[x], although she's holding so still and the light is fading so fast you've momentarily lost sight of her.". The description is "[if boar is enraged]The boar's attack has flushed your system with adrenaline; all else is irrelevant.[otherwise if player is d9-phoebe]You are trembling, exhausted, you suppose. Last night the two of you heard dad crying out in his sleep, and you went to him while Lethe slept. He either didn't remember who you were, or pretended not to. You tended to him as best you could, but you have long since lost hope that he would get better.[otherwise]This was Phoebe's {(*[d]phoebe[x]*)} idea, really, but of course the same thought has been running through your mind for weeks. The old canvases dad had made for the two of you, back before his breakdown, before those endless months in the echo cave on the secret island, sculpting, always sculpting... has it been a year ago? ...the canvases have long since been painted and repainted and worn to nothing, but the urge in both of you to paint more, more has only grown. You both know how to make the paints. But this is your first time trying to get the hide.".

A d-spear is a kind of thing. A d-spear is always undescribed. The printed name of a d-spear is always "spear". Understand "spear" as a d-spear. The description of a d-spear is always "Bamboo, sharpened stone, konokuk husk. You hope it works.". Instead of dropping a d-spear when boar is not enclosed by location: say "You're too nervous to put it down, even for a moment.". Instead of dropping a d-spear: try attacking boar. Instead of throwing a d-spear at something (called attackee): try attacking attackee. D9-Phoebe holds a d-spear. D9-Lethe holds a d-spear. Does the player mean doing something to a d-spear held by player: it is likely. First report taking a d-spear: say "You grab it frantically from the ground, tightening your grip around the muddy, slippery sides." instead.

df9-ctr is a number that varies. boar_victim is a person that varies.

To say d9-yoursister: if player is d9-phoebe, say "Lethe"; otherwise say "Phoebe".

Every turn when location is Dream-Forest9:

increase df9-ctr by 1;

if df9-ctr is 5 begin;

move boar to location;

say "Suddenly, you stiffen. Something moves off to the [if player is D9-Lethe]right[otherwise]left[end if] side of the clearing, a large shape in the darkness. A boar, and a big one. You grip the spear tightly, and across the clearing see your sister do the same. This is what you've been waiting for.";

otherwise if df9-ctr is 100;

say "The boar screams, staring straight into [if player is boar_victim]your[otherwise][d9-yoursister][']s[end if] eyes, pawing at the ground, lowering its head and its two sickly yellow tusks for a charge, blood oozing from the wound in its side.[if player is boar_victim] Its eyes are tiny circles of black on pale white circles, somehow pinning you motionless, huge and commanding.[paragraph break][d9-yoursister] lunges for her spear, scrabbling to grasp it in the dark and the mud.[end if]";

if player is boar_victim begin; if player is d9-phoebe, move a random d-spear in the location to d9-lethe; otherwise move a random d-spear in the location to d9-phoebe; end if;

otherwise if df9-ctr is 101;

say "The boar rears back and then charges [if player is boar_victim]straight towards you[else]straight for your sister[end if].";

otherwise if df9-ctr is 102;

say "The boar leaps forward[if player is not boar_victim] towards [d9-yoursister][end if], snarling, enraged and swelled with the strength of death. [if player is boar_victim]But you cannot move, somehow cannot command your muscles; even your lungs, your heart have stopped...[paragraph break][end if][if player is boar_victim]Some primal instinct jerks you aside, but too late; the boar's tusk rips along the stomach, grazing you with a hot flash of pain, and you cry out, a terrible, animal cry that you finally realize is your own mingled with that of the boar. [d9-yoursister] stands over it, the spear skewered into its hairy flank, and finally, it[otherwise]Just as the terrible creature is almost upon her, she suddenly comes to her senses and twists aside, jabbing down with the spear just as the boar's tusk grazes her side. Both of them let out one piercing, terrible scream... the boar[end if] slumps to the ground, twitching, lifeblood draining into the rainforest floor.";

remove boar from play;

now boar is docile;

move dead-boar to location;

increase df9-ctr by 1;

otherwise if df9-ctr is 104;

say "The world seems to stagger in its strange spin for a long, vertiginous moment, and then you fall into your sister's arms, and she is sobbing or you are, tears and hair running together, hot rainwater soaking through the knees of your fraying clothes or maybe the blood of the boar, and you cry not [if player is boar_victim]from the pain of your wound[else]for your sister's wound[end if], which is light and will easily heal, but from the sudden weight of how you and she came to this moment, crying in the mud, motherless and more or less fatherless and stranded on a deserted island, forced to kill wild animals in the hope of escape.[paragraph break]And the weight, too, that soon you will not even have each other. There is no going together when you leave this place. Only going.[paragraph break]But as you stroke [if player is D9-Phoebe]Lethe[else]Phoebe[end if]'s hair you are not afraid. Something else murmurs that somehow you will always be together.[paragraph break]{(*somehow*)}[line break][end-flashback]";

end if.

Instead of taking d9-lethe when boar is enraged: save-sister-from-boar. Instead of taking d9-phoebe when boar is enraged: save-sister-from-boar. Instead of pushing d9-lethe when d9-lethe is boar_victim and boar is enraged: save-sister-from-boar. Instead of pushing d9-phoebe when d9-phoebe is boar_victim and boar is enraged: save-sister-from-boar. To save-sister-from-boar: say "Charging forward, you slam into your paralyzed sister and push her to the ground just as the boar charges forward. It grazes her side and stomps on your hand as it crashes through the muddy underbrush, scrambling to turn for another pass.[paragraph break][boardiesconclusion]."; remove boar from play; now boar is docile; move dead-boar to location; now df9-ctr is 103.

To say boardiesconclusion: say "Faster than thinking you are on your feet and gripping the spear, and as the terrible creature leaps for you, you drive the weapon deep into its flank. A monstrous squealing scream echoes through the forest, and it is a long moment before you realize it is your own mingled with that of the boar.[paragraph break]It slumps to the ground, twitching, lifeblood draining into the forest floor".

Instead of jumping when boar is enraged and location is Dream-Forest9: save-sister-by-chutzpah. Instead of entering or pushing boar when location is Dream-Forest9: save-sister-by-chutzpah. To save-sister-by-chutzpah: say "Charging forward, you jump on the back of the wild boar, not thinking, only hoping to save your sister, and only as you touch its hideous skin and it shudders and squeals under your grasp do you realize the terrible danger... but your sister suddenly finds her courage too and throws her spear right at the creature's head. The blow glances, the wild animal bucks and throws you off, but the distraction gives you time to grasp your spear again.[paragraph break][boardiesconclusion]."; remove boar from play; now boar is docile; move dead-boar to location; now df9-ctr is 103.

The boar is an undescribed animal. It is either enraged or docile. It is docile. The description is "[if docile]There were pigs back home, but nothing at all like these huge forest creatures, which come up almost to your waist and have thick, yellowed tusks. But their hides, when dried and prepared, will provide canvas. And canvas is what you need to leave this place. If you have your father's magic, that is.[otherwise]The boar is in a maddened frenzy.".

Every turn when the boar is in location and boar is docile: say "[boardesc]".

Instead of attacking the boar when location is Dream-Forest9 and player is not holding a d-spear: say "The [o]spear[x] was pulled from your grasp; it lies on the ground nearby, dripping with the creature's blood.".

Instead of attacking the boar:

if boar is docile begin;

say "With a shout, you leap from your hiding place, [if player is D9-Phoebe]Lethe[otherwise]Phoebe[end if] following a moment later, and stab your spear into the boar's side. A terrible squeal rises from its slimy throat, and it twists away, pulling the spear from your sweat-slicked grip as your heart slams into overdrive.[paragraph break]The animal veers away from you to escape, directly into the path of your sister. But she is paralyzed, white hands gripping the spear, eyes wide, as the creature snarls at her.";

if player is D9-Phoebe, now boar_victim is d9-lethe;

otherwise now boar_victim is d9-phoebe;

now boar is enraged;

if player holds a d-spear (called weapon), move weapon to location;

now df9-ctr is 98;

otherwise;

if player is boar_victim, say "The boar leaps forward, snarling, enraged and swelled with the strength of death. But your instincts return, and with some hidden strength you thrust the spear forward and skewer the horrible creature right through the neck. It crashes into you, one tusk grazing a sharp hot flash down your side, and lets out one piercing, terrible scream... then slumps to the ground, twitching, lifeblood draining into the rainforest floor.";

otherwise say "The boar leaps forward towards [d9-yoursister], snarling, enraged and swelled with the strength of death. You stab forward viciously with every ounce of strength you have, and skewer the creature through its hairy flank, just as its hideous tusk grazes your sister's side... then lets out a piercing, terrible scream and slumps to the ground, twitching, lifeblood draining into the rainforest floor.";

remove boar from play;

move dead-boar to location;

now df9-ctr is 103;

end if.

Instead of hugging someone when dead-boar is enclosed by location: say "Yes. Yes, that's best.". Instead of attacking dead-boar, say "It's dead now. It's over.".

The dead-boar is a setpiece. Understand "boar" as dead-boar. The printed name is "dead boar". Instead of attacking the boar: say "It's already dead.". The description is "It lies in a pool of blood, twitching, in its last moments of life.".

Instead of greeting when location is Dream-Forest9: say "Only if you stay silent can you hope to make a kill.".

Instead of going when location is Dream-Forest9: say "This is your third day in the forest stalking the boar; grim determination says you won't give up until the last shred of light is gone.".

9-lethe-trigger is a person-trigger in Dream-Forest9 with target D9-Lethe. Understand "lethe" as 9-lethe-trigger when location is Dream-Forest9. Instead of pushing 9-lethe-trigger: try pushing d9-lethe.

9-phoebe-trigger is a person-trigger in Dream-Forest9 with target D9-phoebe. Understand "phoebe" as 9-phoebe-trigger when location is Dream-Forest9. Instead of pushing 9-phoebe-trigger: try pushing d9-phoebe.