Aaron A. Reed

Section - Rebel Convo 4

The dusty-tome has a number called page_num. The page_num of dusty-tome is 1.

First Report opening dusty-tome: say "You open the book[one of], turning past a beautiful frontispiece showing a woodcut of sinewy feet pulling free of entangling roots, and reach the first page, which[or] to the page you were on before, which[stopping] reads: [line break][tryreadingtome]" instead. To say tryreadingtome: try reading dusty-tome.

Instead of reading or opening dusty-tome when page_num of dusty-tome is -1, say "You open the book again, but the strange messages are gone, and all you see now are page after page of thousand-year-old poetry, inscrutable, encrusted with crumbling layers of footnotes.".

Instead of reading dusty-tome:

if dusty-tome is closed, try opening dusty-tome;

let pn be page_num of dusty-tome;

if pn is 1 begin; say "[i]Pleasant dreams. So it looks as if they're telling you about Progue. That was years ago. I was still young. Ish. How strange to have it all start up again, now... because of you.[paragraph break]So I'm curious... have you worked out who *they* are yet?[r][line break]Below that, in a different, elegant font, is printed:[paragraph break][i]If yes, please consult page [t]472[x][i]. Otherwise, kindly refer to page [t]916[x].[r]";

otherwise if pn is 472; say "[i]I thought you might have. You do seem sharper than the last fellow. Well, who are they then?[r][line break]In a smaller font below is the text:[paragraph break][i]Please look up your guess in the index.[r]"; now index_looking is true;

otherwise if pn is 916; say "[i]No? It's really not that hard to figure out. Although I suppose for someone from another world... well, it's best if you work it out for yourself.[paragraph break]But we were talking about your friend Progue. You see, this is our second time round. We tried to reach him, many years ago, but were unsuccessful.[r][line break]Below:[paragraph break][i]Continue on page [t]760[x][i], if you please.[r][x]"; now index_looking is false;

otherwise if pn is 227; say "[i]Very good. You have some sense, then. Yes, the minds you hear speaking to you live within the strange trees on your island. Windsigh, I think Progue called them. Poetic. We have quite a different name for them, you understand. Not natives, you may have gathered, though they want to be. But we were talking about Progue.[r][line break]Below, in another font:[paragraph break][i]To inquire about Progue, consult page [t]760[x][i]. To converse about the windsigh, please turn to page [t]308[x].[r]"; now index_looking is false; now guessed_trees is true;

otherwise if pn is 855; say "[i]Who, us? No, we're not the same as the other voices. I thought you'd realized that by now. Try again.[r][line break]Below:[paragraph break][i]Or, turn to page [t]916[x][i] to give up.[r]";

otherwise if pn is 869; say "[i]How poetic. Appearing in your dreams to give some cry for help he cannot give when awake? No, a good theory, but it makes no sense. Try again.[r][line break]Below:[paragraph break][i]Or, turn to page [t]916[x][i] to give up.[r]";

otherwise if pn is 893; say "[i]Oh, what a white-knuckled hold we sentients keep on our sanity. So much so we'd rather believe we're talking to ourselves than hearing voices without explanation. But which is the saner? No; you're wrong. Guess again.[r][line break]Below:[paragraph break][i]Or, turn to page [t]916[x][i] to give up.[r]";

otherwise if pn is 151; say "[i]Come on now, you can do better than that. I hope so, at least. Well. Want to guess again?[r][line break]Below that, in a different, elegant font, is printed:[paragraph break][i]If yes, please consult page [t]472[x][i]. Otherwise, kindly refer to page [t]916[x].[r]";

otherwise if pn is 760; say "[i]The Beast was still a prototype then... meltdowns and overloads every time we tried to use her. So they had Progue more or less to themselves. We could hack in often enough to get a quick idea of what was going on, but that was about all. If only we'd managed to get the kinks out in a more timely... well, it's all in the past now. Who could have known we'd have a second chance?[r][line break]Below:[paragraph break][i]To inquire further as to the meaning of 'second chance,' kindly consult page [t]97[r][i]. To pursue the enigmatic phrase 'beast,' refer to page [t]692[x].";

otherwise if pn is 97 or pn is 692; say "[i][if pn is 97]Yes. You, of course[else]It's the device, the machine I built, the somenium transceiver that's letting us contact you[end if].[paragraph break]Sorry, time's almost out. Suffice to say at the last minute we did succeed. In fact we were the ones who helped him finally figure out what was going on. One would think he'd have been more grateful, instead of---[r][paragraph break]Below this, centered and in small caps, it simply reads:[paragraph break][i]FIN[r][paragraph break]Thoughtfully, you close the book again."; now dusty-tome is closed; now page_num of dusty-tome is -1;

otherwise if pn is 308; say "[i]My people have a long history with them. Long and not entirely pleasant. Have they told you yet that they are symbiotes? That's how they would think of it, at least. Know this, though: in nature, it is very rare when two species truly coexist, neither getting the best of the other. There are few who---[r][paragraph break]Below this, centered and in small caps, it simply reads:[paragraph break][i]FIN[r][paragraph break]Thoughtfully, you close the book again."; now dusty-tome is closed; now page_num of dusty-tome is -1;

otherwise; say "[i]This page intentionally left blank.[r]";

end if.

index_looking is a truth state that varies. guessed_trees is a truth state that varies.

To index_bit with p_t (pt - an indexed text) and real_word (wd - an indexed text) and p_num (pnum - a number):

say "You look it up in the index, where the entry reads '[pt in upper case]";

if pt is not wd in lower case, say ": see [wd].' Referring to that entry you are directed to page [pnum].";

otherwise say ": see page [pnum].'";

now page_num of dusty-tome is pnum.

After reading a command when index_looking is true:

let p_text be indexed text;

let p_text be the player's command;

replace the regular expression "^\s*(.*)\s*$" in p_text with "\1";

replace the regular expression " " in p_text with "";

if p_text matches the regular expression "(trees?|windsighs?)" begin;

index_bit with p_t p_text and real_word "WINDSIGH" and p_num 227;

replace the player's command with "227";

otherwise if p_text matches the regular expression "progue";

index_bit with p_t p_text and real_word "PROGUE" and p_num 869;

replace the player's command with "869";

index_bit with p_t p_text and real_word "SUBCONSCIOUS" and p_num 893;

replace the player's command with "893";

otherwise if p_text matches the regular expression "(dont know|give up|guess|no)";

index_bit with p_t p_text and real_word "THEY, WHO ARE (giving up)" and p_num 916;

replace the player's command with "916";

otherwise if p_text matches the regular expression "\b(voice|book|you)\b";

index_bit with p_t p_text and real_word "MYSTERIOUS VOICE, THE" and p_num 855;

replace the player's command with "855";

index_bit with p_t p_text and real_word "GUESSES, WILD" and p_num 151;

replace the player's command with "151";

end if.

Understand "[a number]" or "turn to page [a number]" or "turn to [a number]" or "look at page [a number]" or "examine page [a number]" or "x page [a number]" or "examine [a number]" or "x [a number]" or "page [a number]" or "consult page [a number]" or "consult [a number]" or "read [a number]" or "read on [a number]" or "go to [a number]" or "turn to page [a number]" as book-setting when location is Dream4Nexus. Book-setting is an action applying to one number. Check book-setting: if page_num of dusty-tome is -1, try opening dusty-tome instead. Carry out book-setting: now page_num of dusty-tome is the number understood; say "You turn to page [the number understood]. On it is printed:[line break]"; try reading dusty-tome instead.

Blue Lacuna — 406 of 467