Blue Lacuna — 391 of 467

Section - Flashbacks

A flashback-room is a kind of room.

Before printing the name of a room when location is a flashback-room: say "{-(*". After printing the name of a room when location is a flashback-room: say "*)-}".

To begin-flashback-sequence:

if last beat is not silence, now saved last beat is last beat;

post-conversation processing;

if saved location is Treehouse or saved location is Big Tree begin;

now player is DB-Progue;

otherwise if saved location is Fork;

now player is DF-Lethe;

otherwise if saved location is Cinder Cone;

now player is DC-Phoebe;

otherwise if saved location is Rockslide;

now player is DR-Progue;

otherwise if saved location is Forest9;

now player is D9-Lethe;

otherwise if saved location is Egg;

now player is DE-Progue;

otherwise if saved location is Saddle or saved location is Atop;

now player is DA-Progue;

otherwise;

say "Error: dream for this location not yet written.";

end if;

change the command prompt to "{(*[printed name of player]*)}>";

try looking.

A person-trigger is a kind of thing. A person-trigger is undescribed. Instead of doing something other than examining to a person-trigger (called pt) (this is the person triggers are weird rule), try examining pt. A person-trigger has a thing called target. [ This defines our ability to move between different people in a flashback. ]

Carry out examining a person-trigger (called pt):

if player is target of pt, try examining player instead;

ignore the report other people examining rule;

let former player be player;

say " {(*[printed name of player]*)(*[target of pt]*)}|";

now player is target of pt;

say "{(*[printed name of player]*)(*[printed name of former player]*)}[line break]";

change the command prompt to "{(*[printed name of player]*)}>";

try looking instead.

After examining a person-trigger: do nothing.

A dream-lethe is a kind of woman. Understand "Laylay/sister" as a dream-lethe when player is a dream-phoebe. Understand "laylay/daughter" as a dream-lethe when player is a dream-progue. The printed name is "[if player is a dream-phoebe]Laylay[otherwise if player is a dream-lethe]Lethe[otherwise]your daughter Lethe[end if]".

A dream-phoebe is a kind of woman. Understand "sister" as a dream-phoebe when player is a dream-lethe. Understand "daughter" as a dream-phoebe when player is a dream-progue. The printed name is "[if player is a dream-phoebe]Phoebe[otherwise if player is a dream-progue]your daughter Phoebe[otherwise]your sister Phoebe[end if]".

A dream-progue is a kind of man. Understand "dad/daddy/father" as a dream-progue when player is a dream-lethe or player is a dream-phoebe. The printed name is "[if player is a dream-progue]Progue[otherwise]dad[end if]".

To say end-flashback: [When we've finished a flashback.]

now player is yourself;

change the command prompt to ">";

try looking;

if location is Dream5Nexus begin; say "Scratched film flickers through the projector; the catch reel is almost full. Something clunks within the cavernous metal interior, and the reels blur as film is fast-wound back, growing on the back reel like time-lapse footage. After a few moments of whirring there is another clunk, and the machine shuts off again."; now movie projector is switched off;

otherwise; say "[one of]You start back, astonished. It was as if for those few minutes you had completely forgotten your own identity, as if it had been subsumed, submerged in the mind and memory of another, no signs of you even rippling the surface.[or]Again, you almost stagger as you abruptly become yourself again. You sink into these memories or dreams or visions so completely, you don't remember who you are until they end.[or][stopping]"; end if;

if a dream presence is enclosed by location begin;

now a random dream presence enclosed by location is attentive;

now last beat is convo-delay;

if saved last beat is not silence, now convo-delay2 suggests saved last beat;

if dreams are being debugged, say "// Dreams: now ([a random dream presence enclosed by location]) is attentive; now convo-delay2 suggests [saved last beat].";

otherwise;

post-conversation processing; [clean up convos in flashback dreams.]

end if.