Blue Lacuna — 287 of 467

Chapter - Summon Progue

[ This is used to bypass the normal movement rules and have Progue instantly appear somewhere. ]

To summon Progue to (place - a room):

if Progue is being debugged, say "// Progue: summoning Progue to [place].";

now Progue is in place;

now Progue is attentive;

now Progue is fulfilling;

now the prior animus of Progue is the animus of Progue;

Progue starts loitering. [The point is it has to be something else, because otherwise Progue might be described swimming or something that makes no sense at his new location.]

[ This is used to give Progue a new activity, and ensure he begins carrying it out. ]

To Progue starts (activity - an endeavour):

if Progue is being debugged, say "// Progue: Progue starts [activity].";

now the next animus of Progue is activity;

pick a new activity for Progue.

[ This is used to move Progue to a certain room, usually to trigger a certain scene if the player discovers him there. ]

To impel Progue to (place - a room):

if Progue is being debugged, say "// Progue: impelled to [place].";

now progue-venue is place;

Progue starts ruminating.

First before greeting Progue when we-are-landmark-going is true (this is the stop landmark-going when Progue speaks rule):

tidy landmark-go;

clean up landmark-go;

continue the action.

Whistling is an action applying to nothing. Understand "whistle" or "yell" or "shout" or "scream" or "make noise" or "make some noise" as whistling.

Carry out whistling:

let atd be indexed text;

let atd be the player's command;

if atd matches the text "shout" or atd matches the text "yell", say "You shout at the top of your lungs.";

if atd matches the text "scream", say "You scream at the top of your lungs.";

if atd matches the text "whistle" or atd matches the text "noise", say "You let out a loud, piercing whistle.";

if Progue is enclosed by location, say "[The Progue] gives you an annoyed glance. 'Sausages, there's no need for that,' he says, 'I'm standing right here.'";

if ( the psyche of Progue is denial or the psyche of Progue is suppression or the psyche of Progue is uncertainty ) and nothing dramatic is up and the animus of Progue is not resting and exploring Progue's turf and a random chance of 4 in 5 succeeds, begin Summoning Progue.

Summoning Progue is a rerunnable guaranteed triggered urgent episode. The expiration date is 40 minutes. The subchange beat is silence. The boredom beat is silence. The bye beat is silence. The abruptbye beat is silence.

A commencement rule for Summoning Progue:

if the location of Progue is Proguevisible, say "[line break][inthedistance], [the Progue] looks in your direction.";

now the icebreaker of Summoning Progue is the summon_beat of Progue.

A completion rule for Summoning Progue:

now the summon_beat of Progue is unspoken;

Progue's life goes on.

[ We actually want to forget what Progue was doing before, since we might have pulled him out of its natural environment, and the message describing him finishing it would be inappropriate.]