Blue Lacuna — 266 of 467

Section - Describing Progue's Animus

[ These are like printed names for each animus.]

To say Progue-animus:

let anim be animus of Progue;

if Progue is wishing begin; say "going somewhere";

otherwise if anim is ruminating; say "thinking";

otherwise if anim is scrapbooking; say "sifting through old things";

otherwise if anim is resting; say "sleeping";

otherwise if anim is fishing; say "fishing";

otherwise if anim is mending; say "stitching";

otherwise if anim is hand-standing; say "hand-standing";

otherwise if the anim is cleaning; say "cleaning the studio";

otherwise if the anim is paint-making; say "mixing paints";

otherwise if anim is frog-catching; say "creeping slowly through the marsh";

otherwise if anim is spying; say "behaving mysteriously";

otherwise if anim is hiding; say "hiding";

otherwise if anim is swimming; say "swimming";

otherwise if anim is conch-blowing; say "[if we have not discussed tcp_greeting]holding some large object in his hands[otherwise]scrutinizing the conch";

otherwise if anim is player-seeking or anim is loitering; say "hesitating";

otherwise if anim is convalescing; say "resting";

otherwise if anim is beach-combing; say "cleaning the beach";

otherwise if anim is hottubbing; say "relaxing";

otherwise; say animus of Progue;

end if.

[ Describe Progue getting back to what he was doing. In certain cases, we want to avoid saying the animus if it would sound awkward in that context; print a more generic message in that case. ]

To say Progue-resumes:

if the animus of Progue is hand-standing:

say "And he suddenly falls forward flat on his face; at the last moment pushing forward with his hands until he's once again balancing on them";

else if the animus of Progue is resting:

say "He [if affinity of Progue < 0]grumpily [end if]lies back down on the [surface-material] and closes his eyes";

else if the animus of Progue is swimming:

say "He kicks a few strokes away from you and stretches out his arms, bobbing lazily in the swell";

else if the animus of Progue is player-seeking or animus of Progue is loitering or animus of Progue is spying or animus of Progue is hiding or Progue is wishing:

say "He [if affinity of Progue >= 0][one of]nods to you[or]waves farewell[or]turns away, glancing at the sky appraisingly[or]looks around vaguely, as if trying to remember what he was doing[in random order][else][one of]turns away angrily[or]pointedly turns his back on you[or]nods curtly to you[at random][end if]";

else:

say "He [if affinity of Progue >= 0][one of]goes back to[or]resumes[or]continues[or]turns his attention back to[or]goes on[in random order][else][one of]angrily goes back to[or]turns away with a frown and resumes[or]nods curtly to you and continues[at random][end if] [Progue-animus]";

if romance of Progue > 1 and a random chance of 1 in 2 succeeds:

say "[one of] with a wink[or], poking you playfully[or], smiling flirtatiously[in random order]";

else if paternalism of Progue > 1 and a random chance of 1 in 2 succeeds:

say "[if affinity of Progue > 0][one of], regarding you fondly[or] with a fatherly smile[at random][else][one of], shaking his head at you disapprovingly[or] with a stern glance in your direction[at random][end if]";

else if submission of Progue > 1 and a random chance of 1 in 2 succeeds:

say "[if affinity of Progue > 0][one of], stepping graciously out of your way[or], first catching your glance to make sure you approve[at random][else][one of], fidgeting nervously in your presence[or], grimacing nervously[or], taking a few nervous steps back[in random order][end if]";

else if submission of Progue < -1 and a random chance of 1 in 2 succeeds:

say "[if affinity of Progue > 0][one of] and whistling cheerfully[or] and cheerfully ignoring you[or] without waiting for any response[in random order][else][one of] and pointedly ignoring you[or] with a dismissive glance in your direction[or], seemingly dismissing you for now[in random order][end if]".

[ "animus-business" is a say tag which can be included after a comma and space to add some color to conversations related to what Progue is doing. ]

To say animus-business:

if Progue is wishing begin; say "[one of]shifting anxiously from foot to foot[or]glancing past you towards his destination[or]tapping one foot rhythmically on the [surface-material][or]drumming his fingers against his thigh[or]a bit impatiently[or]scratching one foot with the other[in random order]";

otherwise if the animus of Progue is fishing; say "[one of]twitching the line absently with his finger[or]pulling in the line and casting it out again[or]snapping the fishing pole reflexively[or]resetting his grip on the fishing pole[in random order]";

otherwise if the animus of Progue is beach-combing; say "[one of]flexing his toes in the spotless sand beneath him[or]running a finger idly along a broken shell[or]frowning at a speck of seaweed near your foot[or]brushing a piece of green weed from his shirt[in random order]";

otherwise if the animus of Progue is mending; say "[one of]tapping the rounded top of the needle absently[or]running his hands across the rags in his lap[or]fingering a hole in the cloth[or]scratching the garments in his lap[in random order]";

otherwise if the animus of Progue is hand-standing; say "[one of]flexing his wrists back and forth[or]poking at a scratch on his palm[or]pinching his knuckles one by one[or]flexing his toes as if he'd prefer they were back in the air[in random order]";

otherwise if the animus of Progue is cleaning; say "[one of]wiping dust from the workbench with a bit of rag[or]stacking old pots of paint[or]pulling up a vine that's crept through the window[or]frowning at a spot of spilled paint on the workbench[in random order]";

otherwise if the animus of Progue is paint-making; say "[one of]stirring a pot of paint vigorously[or]wiping a droplet of paint from his forehead[or]scraping some paint from the sides of a pot[or]studying the consistency of the paint in a nearby pot with a frown[in random order]";

otherwise if the animus of Progue is hottubbing; say "[one of]flicking the water absently with his fingers[or]sinking down till the water reaches his chin[or]kicking his legs languidly in the water[or]tickling water from an ear with one finger[or]pulling up his knees till they just poke out of the water[or]ducking his head half-under the water for a moment to blow little bubbles before resurfacing[in random order]";

otherwise if the animus of Progue is swimming; say "[one of]floating serenely[or]opening one eye to squint balefully at you[or]scissoring his arms gently at his sides[or]bobbing gently on a swell[in random order]";

otherwise if the animus of Progue is frog-catching; say "[if caught-frog is true][one of]rocking his frog-cage hands gently back and forth[or]peering at his caught frog[or]holding his frog close to his body[in random order][otherwise][one of]peering under an overhanging rock[or]making patterns in the mud with one bare toe[or]slapping a mosquito[or]brushing some wet grass from his knees[or]keeping one eye trained on a patch of rustling weeds[or]wiping his brow in the humid marsh air[or]tilting his head at a half-heard distant croak[in random order][end if]";

otherwise; say "[one of]scratching his elbow[or]flexing a tanned foot appraisingly[or][attitude-business][or]shuffling his feet over the [surface-material][in random order]";

end if.