Blue Lacuna — 261 of 467

Section - Attitude Business

[ "attitude-business" is a say statement that can be inserted after a comma and space outside of quotes in Progue dialog. It adds a clause to the sentence that gives hints as to how Progue feels about you. ]

To say attitude-business:

if the psyche of Progue is denial begin; [Early on, Progue's feelings may only be temporary; we don't want to push the player towards thinking Progue is particularly friendly/unfriendly/etc until they have a chance to develop a bit of a history.]

say "[animus-business]";

otherwise if ( romance of Progue > 1 or romance of Progue < -1 ) and a random chance of 1 in 2 succeeds;

if romance of Progue >= 5 begin; say "[one of]rubbing a hand up and down your back[or]kissing your cheek[or]eyeing you suggestively[in random order]";

otherwise if romance of Progue >= 3; say "[one of]flashing a mad, flirtatious grin in your direction[or]tousling your hair playfully[or]touching his hand to yours for a brief moment[in random order]";

otherwise if romance of Progue >= 1; say "[one of]poking you playfully in the side[or]giving you a surreptitious wink[or]smiling wryly at you[in random order]";

otherwise if romance of Progue < -1; say "[one of]pointedly looking away[or]apparently trying hard to keep his tone civil[or]using a nasty, sarcastic tone[in random order]";

end if;

otherwise if paternalism of Progue >= 2 and a random chance of 1 in 2 succeeds;

if affinity of Progue > 0 begin;

if paternalism of Progue >= 4 begin; say "[one of]in a fatherly tone[or]putting a strong hand on your shoulder[in random order]";

otherwise; say "[one of]regarding you fondly[or]tapping you on the knee[or]seeming to find quiet reassurance in your company[in random order]"; end if;

otherwise;

if paternalism of Progue >= 4 begin; say "[one of]conveying [if affinity of Progue < -3]strong[otherwise]faint[end if] disapproval with his body language[or]frowning disapprovingly at you[in random order]";

otherwise; say "[one of]sternly[or]in a stern tone[or]shooting you a look of mild disapproval[in random order]"; end if;

end if;

otherwise if ( submission of Progue >= 2 or submission of Progue <= -2 ) and a random chance of 1 in 2 succeeds;

if submission of Progue >= 4 begin; say "[one of]watching nervously for your reaction[or]moving quickly aside as you lean forward[or]hesitantly, as if afraid of your reaction[or]with an embarrassed laugh[in random order]";

otherwise if submission of Progue >= 2; say "[one of]glancing surreptitiously at your reaction[or]a bit hesitantly[or]awkwardly[or]drawing back a little[in random order]";

otherwise if submission of Progue <= -3; say "[one of]enjoying your reaction[or]watching with interest to see your reaction[or]loudly[or]holding your gaze[in random order]";

otherwise; say "[one of]confident and commandingly[or]without waiting for a reply[or]clapping you roughly on the back[or]stepping forward a little[in random order]";

end if;

otherwise;

if affinity of Progue >= 4 begin; say "[one of]touching his hand warmly to your shoulder[or]regarding you fondly[or]smiling broadly at you[in random order]";

otherwise if affinity of Progue >= 2; say "[one of]smiling a little[or]giving you a cautious smile[or]nodding at you[in random order]";

otherwise if affinity of Progue < 2; say "[one of]cautiously glancing in your direction[or]weighing your reaction[or]watching you intently[in random order]";

otherwise if affinity of Progue <= -2 and affinity of Progue > -5; say "[one of]avoiding your eyes[or]after an awkward silence[or]a bit distantly[or]studiously avoiding your glance[in random order]";

otherwise; say "[one of]making sure to keep his distance from you[or]with harsh sarcasm[or]coldly[or]in an unfriendly tone[in random order]";

end if;

end if.