Blue Lacuna — 213 of 467

Chapter - The Bees

The dancer bee is an undescribed animal in Hive Interior. Understand "single" or "lone/lead" as dancer bee. The description is "[if the hive bees are watching or hive bees are collecting]The bee performs his strange little dance carefully, with a precision doubtless refined by eons of evolution[otherwise]The dancer bee has vanished back into the rest of the swarm[end if]." Does the player mean doing something to the dancer bee: it is likely.

The swarm of bees are an animal in Hive Interior. Understand "bee" or "handful/red/stripe/stripes/wing/wings" as the swarm of bees. The description is "The bees are unnervingly large, about the size of your fist, with alternating red and cream stripes and fat wings. As you look closer, though, you see they don't appear to have stingers, and at any rate are paying you no attention at all.". Instead of attacking the swarm of bees, say "That probably isn't the smartest idea." Instead of taking or touching the swarm of bees, say "You put your hand near one of the fat creatures. Obligingly, it climbs onto it, quivering its wings every few moments, and does a few complete circuits, before flying off disappointed.". Instead of remembering swarm of bees: say "The main body of the swarm is no longer in sight.". After going to Jumble for the first time: now swarm of bees is seen; continue the action. [So that we can "Remember" them even if we haven't yet examined them.]

The initial appearance of the swarm of bees is "[if not raining and not night][swarmdesc].[end if]".

Instead of object-debugging swarm of bees, try object-debugging beehive. Instead of object-debugging dancer bee, try object-debugging beehive. Instead of object-debugging hive bees, try object-debugging beehive.

To say swarmdesc:

if location is Hive Room or location is Hive Interior, say "A slowly steady stream of [o]bees[x] flies in and out of the hive through its [o]skylight[x] [if location is Hive Interior]just above your head[otherwise]high above[end if]";

otherwise say "A swarm of [o]bees[x] mills about the flowers here, delicately gathering nectar".

First report remembering when noun is the swarm of bees: say "They have already vanished from sight." instead.

The bee target is a room that varies. The bee target is Hive Room. The bee dance tracker is a number that varies. The bee dance tracker is 0.

Every turn when the hive bees are asleep and the player is awake and the player is in Lacuna and sunup (this is the wake up the bees rule): now the hive bees are awake; if beehive is being debugged, say "// Bees: waking up.".

After waiting when location is Hive Interior (this is the watching the bees isn't as boring as all that rule): now the time of day is 7 minutes before the time of day; continue the action.

Every turn when the player is awake and the hive bees are awake and the player is in Lacuna and we are not landmark-going (this is the bee plan rule):

if beehive is being debugged, say "// Bees: follow the bee plan rule.";

if night begin;

remove swarm of bees from play;

now hive bees are asleep;

stop;

otherwise if sunset or twilight;

if swarm of bees are in Hive Interior begin; now hive bees are asleep; if beehive is being debugged, say "// Bees: going to sleep."; stop;

otherwise; [ tell them it's time to go home ]

if beehive is being debugged, say "// Bees: heading home because sundown.";

now hive bees are collecting;

now counter of hive bees is 99;

end if;

end if;

increase the counter of the hive bees by 1;

if hive bees are hesitating and the counter of the hive bees is at least 2 and a random chance of 2 in 3 succeeds begin; [bees need to pick a plan]

if beehive is being debugged, say "// Bees: starting to watch (because hive bees are hesitation and counter of hive bees is at least 2 ([counter of the hive bees]) and a random chance of 2 in 3 succeeded).";

now hive bees are watching;

if there is a selected of 0 in Table of Bee Dance Recipes begin;

sort Table of Bee Dance Recipes in selected order;

otherwise;

repeat through the Table of Bee Dance Recipes begin; change selected entry to 0; end repeat;

sort the Table of Bee Dance Recipes in random order;

end if;

choose row 1 in Table of Bee Dance Recipes;

if beehive is being debugged, say "// Bees: chose [dest entry] as next destination.";

change the selected entry to 1;

now bee target is dest entry;

now the counter of the hive bees is 0;

otherwise if hive bees are watching or hive bees are collecting and counter of hive bees < 24; [dancer bee shows his stuff]

choose row 1 in the Table of Bee Dance Recipes;

let dancex be 99;

increase the bee dance tracker by 1;

let z be the bee dance tracker;

if z is 1, now dancex is 8;

if z is 2 and there is a move1 entry, now dancex is move1 entry;

if z is 3 and there is a move2 entry, now dancex is move2 entry;

if z is 4 and there is a move3 entry, now dancex is move3 entry;

if dancex >= 1 and dancex <= 9 begin;

[now bee dance tracker is 0;]

if location is Hive Interior begin;

choose row dancex in the Table of Bee Dances;

say "[dance move entry].";

[If this is the last move of the dance, jigger things so we'll see the bees fly off immediately.]

choose row 1 in the Table of Bee Dance Recipes;

unless there is a move2 entry begin;

if z is 2 begin; say line break; now bee dance tracker is 0; end if;

end unless;

unless there is a move3 entry begin;

if z is 3 begin; say line break; now bee dance tracker is 0; end if;

end unless;

if z is 4 begin; say line break; now bee dance tracker is 0; end if;

end if;

otherwise;

now bee dance tracker is 0;

if counter of hive bees > 15, now counter of hive bees is 30;

end if;

end if;

if hive bees are collecting and counter of hive bees is 24 and location is Hive Interior begin;

say "The empty space disappears in a flash, the dancer bee disappearing back into the crowd.";

end if;

if ( hive bees are watching or hive bees are collecting ) and bee dance tracker is 0 and counter of hive bees > 1 and counter of hive bees <= 30 begin;

if hive bees are watching begin;

if beehive is being debugged, say "// Bees: starting collecting.";

now hive bees are collecting;

now the counter of the hive bees is 0;

end if;

if location is in East Island or location is Forest2 or location is Chasm Edge or location is Sloping Meadow or location is Crater Pond or location is Forest3 or location is Egg Room or location is Grassy End, process bee movement; [saves computation time]

move swarm of bees to bee target;

otherwise if hive bees are collecting and the counter of the hive bees >= 25 and ( the counter of the hive bees > 30 or a random chance of 1 in 3 succeeds ) ;

if beehive is being debugged, say "// Bees: starting hesitating.";

now hive bees are hesitating;

now bee dance tracker is 0;

now the counter of the hive bees is 0;

if location is in East Island or location is Forest2 or location is Chasm Edge or location is Sloping Meadow or location is Crater Pond or location is Forest3 or location is Egg Room or location is Grassy End, process bee movement; [saves computation time]

remove swarm of bees from play;

now bee target is Hive Interior;

end if;

if beehive is being debugged, say "// Bees: status: swarm in [location of swarm of bees]; counter is [counter of hive bees].".

Table of Bee Dances

To say describe dancer: say "[one of]The bees have all left a wide empty gap around one [o]dancer[x] bee, seemingly identical to all the rest, who[or][describe dancer2][stopping]". To say describe dancer2: say "The [o]dancer[x] bee".

Table of Bee Dance Recipes

To say lpbmbit: say "[if bees are hesitating and location is Hive Interior], climb industriously through the hole in the ceiling of the beehive, and spread out to all the honeycombs[otherwise if bees are hesitating], and climb industriously into the hive[otherwise if location is Hive Interior]. Meanwhile, others and new arrivals continue milling in a wide circle around the [o]dancer[x] bee, who quivers expectantly[end if]". To say lpbmbit2: say "[if dir]to[otherwise]towards[end if] [if hive bees are hesitating and dir]north[otherwise if hive bees are hesitating and not dir]the chute[otherwise if bee target is Crater Pond and dir]southeast[otherwise if bee target is Crater Pond and not dir]the meadow[otherwise if bee target is Sloping Meadow and dir]southwest[otherwise if bee target is Sloping Meadow and not dir]the chasm[end if]".

To say southorrockslide: say "[if dir]south[otherwise]rockslide[end if]". To say eastorrainforest: say "[if dir]east[otherwise]rain forest[end if]". To say northwestorgap: say "[if dir]northwest[otherwise]gap in the lava flow[end if]".

To say beesl: say "bees ([if hive bees are asleep]asl[otherwise]aw[end if]): [if hive bees are dormant]dormant[otherwise if hive bees are hesitating]hesitating[otherwise if hive bees are watching]watching[otherwise if hive bees are collecting]collecting[end if]; bdt:[bee dance tracker]; c:[counter of hive bees]; swrm:[location of swarm of bees]; targ:[bee target]".

To process bee movement:

[ if this routine is running, there's a possibility we may witness some bee movement.

If we're in the Hive Room, deal with that.

If the bees are returning to the Hive, deal with that.

If we're in the location the bees are arriving in, deal with that.

Otherwise, determine if our location is along the flight path of bees.

If so, print a description mentioning where they're coming from and going to.]

if ambience_on is 0, stop; [ Don't print bee descriptions while the player is napping.]

if beehive is being debugged, say "// Bees: process bee movement.";

if location is Hive Interior or location is Hive Room begin; [ If we're in the Hive Room, deal with that.]

say "[if location is Hive Interior and swarm of bees is in location]The dancer bee stops its strange dance. A number of bees immediately take flight and fly off towards the[otherwise if swarm of bees is in location]A [o]swarm[x] of bees in the hive take wing and fly out the hole in the top. They do a graceful arc in the air and zoom off towards the[otherwise if hive bees are collecting]A [o]handful[x] of bees emerge from the hive and fly off towards the[otherwise]A [o]swarm[x] of bees arrives from the[end if] "; say "[if bee target is Sloping Meadow or bee target is Crater Pond][southorrockslide][otherwise if bee target is Forest2 or bee target is Egg Room][eastorrainforest][otherwise if bee target is Grassy End][northwestorgap][otherwise if dir]north[otherwise]edge of the ravine[end if][lpbmbit].";

otherwise if swarm of bees is in location; [If the bees are returning to the Hive]

if hive bees are collecting begin; say "A few new [o]bees[x] arrive and land gracefully on empty flowers, while others depart and fly off ";

otherwise; say "[one of]One by one, the [o]swarm[x] of bees rise from their flowers and fly off[or]First in ones and twos, and then all at once, the [o]swarm[x] of bees lift off from their flowers and fly off[at random] "; [move bee-ghost to location;] end if;

say "[if dir]to[otherwise]towards[end if] [bee exit desc].";

otherwise if location is bee target; [If we're in the location the bees are arriving in.]

if hive bees are collecting, say "A [o]handful[x] of bees trickle in from ";

otherwise say "A [o]swarm[x] of bees arrives from ";

say "[bee exit desc]";

say ", and settle gracefully on the wildflowers.";

otherwise; [Otherwise, determine if our location is along the flight path of bees.]

if ( location is Chasm Edge and bee target is Sloping Meadow ) or ( location is Rockslide and bee target is Sloping Meadow ) or ( location is Rockslide and bee target is Crater Pond ) or ( location is Forest2 and bee target is Egg Room ) or ( location is Forest3 and bee target is Egg Room ) , say "From somewhere overhead you hear the vague drone of bees zipping through the air.";

end if.

To say bee exit desc: say "[if location is Egg Room]the way out of the crater[otherwise if location is Crater Pond and dir]the northwest[otherwise if location is Crater Pond]the rockslide[otherwise if location is Sloping Meadow and dir]the east[otherwise if location is Sloping Meadow]the chasm[otherwise if location is Grassy End]the hive[end if][bedesc2]". To say bedesc2: say "[if location is Forest2 and dir]the west[otherwise if location is Forest2]the edge of the forest[otherwise if location is Edge of Ravine and dir]the south[otherwise if location is Edge of Ravine]the hive[otherwise if location is Grassy End and dir] to the southeast[end if]".

To say random bee noun: say "[if hive bees are collecting][beefewnoun][otherwise][beeswarmnoun][end if]". To say beeswarmnoun: say "[one of]A [o]swarm[x] of bulbous red bees[or]With a chest-vibrating zoom, a [o]swarm[x] of bees[or]A [o]swarm[x] of huge red bees, lazily dipping and swaying,[at random]". To say beefewnoun: say "[one of]A small group of huge red [o]bees[x][or]A pair of oversized [o]bees[x][or]A cluster of melon-sized [o]bees[x][at random]".

To say random bee verb: say "[one of]comes flying through the air[or]flies past[or]flies by[or]zips through[or]passes through[at random]".