Blue Lacuna — 196 of 467

Section - Boiler Pipes

The red pipe is a pipe. It is in Volcano Floor and Chasm Floor. The pressure of the red pipe is 0.

The blue pipe is a pipe. It is in Volcano Floor, Chasm Floor, Jumble, Stumps, and Chairlift Base. The pressure of the blue pipe is 0.

The yellow pipe is a pipe. It is in Volcano Floor, Chasm Floor, Chasm Edge, Edge of Ravine, Ravine Floor, and Observatory Exterior. The pressure of the yellow pipe is 22.

Noticing-The-Pipe-Crack is a scene. Noticing-The-Pipe-Crack begins when location is Stumps and pressure of the blue pipe > 0 and puzzle mode and we-are-landmark-going is true. Noticing-The-Pipe-Crack ends when Noticing-The-Pipe-Crack begins. When Noticing-The-Pipe-Crack begins: tidy landmark-go; clean up landmark-go. [Since players tend to miss this clue, we'll stop them if they're landmark-going past it.]

First report examining a pipe (called item):

if item is blue pipe, say "[bluepipedetailmsg].";

if item is yellow pipe, say "[yellowpipedetailmsg].";

if item is red pipe, say "[redpipedetailmsg].".

To say bluepipedetailmsg: [Should end without periods because "first report examining a pipe" prints them.]

if location is Stumps begin;

if the pressure of the blue pipe is at least 1 and puzzle mode begin;

say "Underneath the line of moss is an overgrown bamboo pipe half-buried in the ground, flecks of blue paint still clinging to it, coming from the [dr]shack[x] but disappearing into the jumbled lava rock [up] the rise. The steam seems to be venting from a small crack that runs almost an entire body length through this section of the pipe";

move pipe crack to Stumps;

otherwise; say "A line of moss, barely noticeable unless you look for it, reveals where the half-buried blue pipe runs between the stumps, coming from the [dr]shack[x] but disappearing into the jumbled lava rock [up] the rise";

end if;

otherwise;

if location is Chasm Floor, say "The blue pipe follows the chasm from the volcano [dr]caldera[x] and vanishes into the [dr]jumble[x] of rocks at its far end";

if location is Chairlift Base, say "The blue pipe, arriving from the direction of the [dr]stumps[x], emerges from the ground running parallel to it, then twists up ninety degrees at the shack and connects to the ropeway mechanism[if puzzle mode] via a transparent quartz [o]gauge[x][end if]";

if location is Volcano Floor, say "The blue pipe snakes off from the boiler towards the [dr]chasm[x]";

if location is Jumble, say "The blue pipe comes from the more open [dr]terrain[x] near the stairs and vanishes into a confusion of boulders";

end if.

The pipe crack is a set dressing. Understand "small" as pipe crack. The description is "It looks as if some past impact smashed into the pipe at this exposed spot, sending a long crack down in either direction from the point of impact.". Understand "fix [pipe crack]" or "repair [pipe crack]" or "fix [blue pipe]" or "repair [blue pipe]" as a mistake ("You can't see any way to do so. The high-pressure steam would just burrow straight through any soil you dumped on it, and there isn't even much of that to go around near here."). Instead of attacking the blue pipe, say "That would just make things worse.". Instead of attacking the pipe crack, try attacking the blue pipe.

To say redpipedetailmsg:

if location is Volcano Floor, say "The red pipe snakes off from the boiler towards the [dr]chasm[x]";

otherwise say "The red pipe comes in from the volcano [dr]caldera[x], bends up to follow the wall, and then disappears into the rock by the mechanism[if puzzle mode]. [gauge-description] marks the join[end if]".

To say yellowpipedetailmsg:

if location is Volcano Floor, say "The yellow pipe snakes off from the boiler towards the [dr]chasm[x]";

if location is Chasm Floor, say "The yellow pipe arrives from the volcano [dr]caldera[x], then turns ninety degrees and heads straight [up] the side of the ravine, vanishing over the [if dir]eastern [end if]edge";

if location is Chasm Edge, say "The yellow pipe comes from [down] inside the ravine and vanishes into a cliff near the base of the rockslide";

if location is Edge of Ravine, say "The yellow pipe emerges from the ground some ways back towards the beehive, then follows the edge of the cliff and plunges straight [down] the side of the ravine";

if location is Ravine Floor, say "The yellow pipe comes from [up] above, crosses the ravine at about the height of the seventh rung, and then starts running up the side of the mountain, eventually vanishing into a crack";

if location is Observatory Exterior, say "The yellow pipe snakes up over the side of the mountain and runs into the ground near the [if pyramid is in Observatory Exterior]pyramid[otherwise]chair[end if][if puzzle mode]. Some [o]words[x] are scrawled on its side[end if]".

Instead of touching a pipe, say "The [noun] is [if pressure of the noun > 10]scalding hot to the touch and vibrating slightly[otherwise if pressure of the noun > 4]hot to the touch[otherwise if pressure of the noun > 0]warm to the touch[otherwise]cool to the touch[end if]." Instead of listening to a pipe, say "[The noun] [if pressure of the noun > 10]emits an audible roar of white noise[otherwise if pressure of the noun > 4]makes a faint whooshing noise if you put your ear near it[otherwise]is silent[end if]." Instead of taking a pipe: say "The pipe runs parallel to the ground and is embedded into it; you can't pick it up. "; try touching noun.