Blue Lacuna — 185 of 467

Section - The Mind Chair

The mind chair is an undescribed enterable supporter. The printed name is "reclined chair". The description is "Angled back in a reclining position, it is constructed of wood and padded with simple cushions. Above, behind, and below the headrest is a frankenstein array of [o]machinery[x], running into the ground beneath the chair." Does the player mean entering the mind chair: it is likely. Check climbing mind chair: try entering mind chair instead.

After entering the chair:

say "Heart racing, you carefully sit down on the chair-- then, after a moment, lean back and rest your head on the padded cushion. ";

if pyramid has power begin;

move icon-case to chair;

if the mind machinery is calibrated begin; say "[paragraph break]After a moment of strange mental tingling, a set of transparent icons winks into view, seeming to hover a few feet in front of you. [mindlink summary].";

otherwise;

if Mindlink Calibration has ended begin;

say "[paragraph break]Once again, something appears hovering in your field of vision: [a list of things in icon-case].";

otherwise;

say "[paragraph break]At first, nothing happens, but then you feel a faint, quiet tickling somewhere inside your head.[paragraph break]A faint [o]brightness[x] suddenly appears in the center of your field of vision. It seems to float there, regardless of where you look, as if it is somehow being projected on top of it.";

move the light-icon to icon-case;

end if;

end if;

otherwise;

say "At first, nothing happens, but then you feel a strange mental tingling, and a fuzzy concept takes shape in your head which slowly resolves into a pair of numbers:[paragraph break][pressure of the related pipe of the pyramid pressure gauge].[paragraph break]22.[paragraph break]Then the tingling fades, and nothing further happens.";

end if.

After entering the chair when the mind machinery is off-stage: [i.e. destroyed] say "You sit down on the chair, but nothing happens; the machinery is ruined."

After getting off the chair: say "[if icon-case is on-stage]As you move to stand up, the icons instantly disappear. [end if]You rise to your feet."; remove icon-case from play; now counter of light-icon is 0. After getting off the chair when the mind machinery is off-stage: say "You get to your feet."

Instead of looking when player is on the mind chair and icon-case is on-stage, say "Floating in midair before you [if tree icons are in icon-case]is an array of icons. [mindlink summary][otherwise][is-are the list of things in icon-case][end if].[paragraph break]The world outside of the chair is hard to focus on until you [d]stand up[x].".

To say mindlink summary:

say "An arc of seven [o]windsigh[x] icons[if the number of contacted windsigh trees is 7], all glowing [color text of yes-icon of mind machinery],[otherwise if the number of contacted windsigh trees is 0], all grey,[otherwise] ([the number of contacted windsigh trees in words] glowing [color text of yes-icon of mind machinery], the [sti_color] dim and grey)[end if] ";

say "floats below a large [o]globe[x] icon ([if the machinery-password exactly matches the text rebel-password or the machinery-password exactly matches the text tree-password]pulsing [color text of yes-icon of mind machinery][otherwise if the number of contacted windsigh trees is 7]still [color text of no-icon of mind machinery][otherwise]a dull [color text of no-icon of mind machinery][end if])";

if the number of contacted windsigh trees is 7 begin;

say ". Above both of these is a stylized lock and [o]key[x]";

if mind machinery is unencrypted, say ", the latter grey and hovering just to the right of the open lock";

otherwise say ", the latter engraved with the word '[machinery-password]' and inserted into the lock";

say ". Finally, floating above the lock is a cloud of thousands and thousands of almost imperceptibly small [o]dots[x][if the machinery-password exactly matches the text rebel-password or the machinery-password exactly matches the text tree-password], all [color text of no-icon of mind machinery] but for a single [color text of yes-icon of mind machinery] speck[otherwise if the machinery-password is blank], all [color text of yes-icon of mind machinery][otherwise], all [color text of no-icon of mind machinery][end if]";

end if.

To say sti_color: if the number of contacted windsigh trees is 6, say "last"; otherwise say "rest".

A mindlink-icon is a kind of thing. A mindlink-icon is usually undescribed. A mindlink-icon is always minor. Last instead of taking a mindlink-icon: say "Your hands move right through it." [bug2: does this work?]

Test mindlink with "tp observatory exterior / knock thrice / clap / sit / l / head".

Icon-case is a transparent open unopenable undescribed container. It is fixed in place.

The seven tree icons are a mindlink-icon. Understand "windsigh" as the tree icons. The description is "As you focus on the icons you [if the number of contacted windsigh trees is 0]feel a strange, distant pull from somewhere below you on the island[otherwise if the number of contacted windsigh trees is 7]feel a powerful tingling in your mind, and recognize the trees you have found, the seven spread around the island. They are ready[otherwise if guessed_trees is false]feel a powerful tingling in your mind, like the presences from your dreams. Only it's stronger now; and you sense that you no longer need to dream under the trees to speak to the presences-- you must still find the rest, but now you can merely touch them to hear their message[otherwise]feel a powerful tingling in your mind, and recognize the [number of contacted windsigh trees in words] mind[s] you have already found, and the eagerness of the [7 - number of contacted windsigh trees in words] other[s] you have yet to contact. You sense that the calibration has helped them; now, you do not need to be in sleep to speak with them. Merely touching the trunks of the windsigh trees will be enough for the minds to reach you[end if].".

The globe icon is a mindlink-icon.

Instead of examining the globe icon when mind machinery is calibrated:

say "You focus on the globe icon";

if the number of contacted windsigh trees < 7:

say ". It does not change, but the [the number of uncontacted windsigh trees in words] grey windsigh icon[if the number of uncontacted windsigh trees > 1]s below it flash[otherwise] below it flashes[end if] [color text of no-icon of mind machinery] a few times.";

otherwise if the machinery-password is blank:

say ", but immediately all the colored [color text of yes-icon of mind machinery] dots turn [color text of no-icon of mind machinery]. A few random single dots turn [color text of yes-icon of mind machinery], one at a time, before the whole group returns to [color text of yes-icon of mind machinery] again.";

otherwise if the machinery-password exactly matches the text rebel-password or the machinery-password exactly matches the text tree-password:

say "-- and an impossibly bright red glow flares into your eyes. You fling your hand up to shield them---";

if ( Being-In-Rebelworld is unsolved and the machinery-password exactly matches the text rebel-password ) and Lab is unvisited, begin chapter 9;

if ( Being-In-Treeworld is unsolved and the machinery-password exactly matches the text tree-password ) and Overlook is unvisited, begin chapter 8;

now the mind machinery is projecting;

otherwise:

say ". Nothing happens, except that the cloud of dots and the lock and key icons blink [color text of no-icon of mind machinery] for few moments.".

The key icon is a mindlink-icon.

Instead of examining the key icon when mind machinery is calibrated and the number of contacted windsigh trees >= 7:

say "As you activate the key, [if the machinery-password is blank]it moves forward into the lock with a mental click. The key begins pulsing with an expectant quiver, and you can feel intuitively that it is waiting to swallow your next utterance[otherwise if the machinery-password exactly matches the text rebel-password or the machinery-password exactly matches the text tree-password]it pulls back out of the lock and the single [color text of yes-icon of mind machinery] dot above becomes just one in a sea of [color text of yes-icon of mind machinery] dots[otherwise]it pulls back out of the lock[end if][if the machinery-password is not blank]. The engraved word, '[machinery-password],' fades away until the key is once again featureless[end if]";

if the machinery-password is blank begin;

now the key icon is feeding;

change the command prompt to ">>";

otherwise;

change the machinery-password to "no.thing";

end if;

if the machinery-password is not blank, say ", [if the machinery-password exactly matches the text rebel-password or the machinery-password exactly matches the text tree-password]and the single [color text of yes-icon of mind machinery] dot becomes lost as all the [color text of no-icon of mind machinery] others fade to join it in uniform [color text of yes-icon of mind machinery][else]and all the dots fade from [color text of no-icon of mind machinery] to [color text of yes-icon of mind machinery]";

say ".";

The key icon is either satiated or feeding. The key icon is satiated.

After reading a command when the key icon is feeding:

let testtext be indexed text;

let testtext be the player's command;

if testtext is an invalid password, reject the player's command;

otherwise replace the player's command with "setkey machpw [the player's command]".

After defining a password while key icon is feeding:

change the command prompt to ">";

now the key icon is satiated;

now the mind machinery is crypted;

say "As you visualize the word, you can feel neurons firing in your brain, and sense intuitively somehow that unique pattern, the precise electrical, neurological relationship between your brain and that word -- [machinery-password] -- is being recorded and copied. Slowly, the word becomes etched into the key above[if the machinery-password exactly matches the text rebel-password or the machinery-password exactly matches the text tree-password]. When it is finished, a single dot in the [color text of yes-icon of mind machinery] cloud above retains its color, while all others fade to [color text of no-icon of mind machinery]; the [o]globe[x] icon also lights up [color text of yes-icon of mind machinery][otherwise], as all the tiny dots above wink from [color text of yes-icon of mind machinery] to [color text of no-icon of mind machinery], until they are one solid band of color[end if].".

The tiny dots are a mindlink-icon. The description is "[if the machinery-password exactly matches the text rebel-password or the machinery-password exactly matches the text tree-password]The single [color text of yes-icon of mind machinery] dot and the globe icon seem to pulse together as you activate it, but otherwise nothing happens[otherwise]They are so small they are only barely perceptible as individual points, floating in a loose halo above and around the lock and key... almost in the shape of a galaxy[end if]."