Blue Lacuna — 183 of 467

Section - The Pyramid

[There are a confusing number of states here to describe. The machinery here can be unpowered, insufficiently powered (in which case it pulses faintly red) or fully powered (in which case it glows a deep red and shoots a beam of light into the sky, visible at night). The pyramid is either concealing the egg (the source of the glow) and the chair, or gone, exposing them. Also, the machinery might be destroyed. ]

To say pyrstatesummarylong:

if pyramid is in location:

say "crude wooden [o]pyramid[x] only a head taller than you are, completely encircled by huge metallic hoops tilted like the rings of some strange planet. Hundreds of tiny wire filaments run from points across the rings to a junction at the top of the pyramid";

otherwise if destroyed mind machinery is in location:

say "wreckage of the [o]machinery[x], broken glass and twisted filaments and sparking wires";

otherwise:

say "reclined [o]chair[x], surrounded by a medley of strange [o]machinery[x]. Hundreds of noodle-thick metal hoops encircle the chair, joined by thousands of wire filaments that converge at a point suspended above it".

To say pyrstatesummaryshort:

if pyramid is in location:

say "wooden [o]pyramid[x], surrounded by its halo of [o]hoops[x] and [o]filaments[x]";

otherwise if destroyed mind machinery is in location:

say "wreckage of the [o]machinery[x]";

otherwise:

say "[o]chair[x], surrounded by the medley of strange [o]machinery[x] and the halo of hoops and filaments".

To say ventword: say "[o]vent[x]".

The pyramid is an undescribed setpiece in Observatory Exterior. The description is "The pyramid, despite the bizarre implements surrounding it, seems quite plain, constructed from three pieces of triangular wood, weather-worn but quite solid. Each side of the pyramid is adorned with one of three [o][if puzzle mode]drawings[otherwise]words[end if][x][pyrdesc2]". To say pyrdesc2: say "[if pressure of the related pipe of the pyramid pressure gauge > 0 and pyramid is on-stage], and a red glow streams through minute joins along its edges[otherwise if pressure of the related pipe of the pyramid pressure gauge > 0 and pyramid is on-stage], and a red [o]glow[x] pulses inside the egg hotly[end if][pyrdesc2b]". To say pyrdesc2b: say ". Wire [o]filaments[x] run from the [o]hoops[x] surrounding the [if pyramid is on-stage]pyramid to its apex, where they converge and presumably run to the inside[otherwise]structure to a point suspended above the chair, where they converge and run in a thick bundle into the egg[end if][pyrdesc3]". To say pyrdesc3: if puzzle mode, say ".[paragraph break][gauge-description], near [if pyramid is on-stage]the point of the pyramid nearest the cliff[otherwise]the foot of the chair[end if], rises from the ground, connected to a yellow [o]pipe[x] that snakes off towards the dropoff. A"; else say ".[paragraph break]A yellow [o]pipe[x] snakes towards the dropoff and connects to the base of the [if pyramid is on-stage]pyramid[else]chair[end if]; a"; say " stubby outlet [o]vent[x] [if pressure of the related pipe of the pyramid pressure gauge > 24]emits a steady cloud of steam[otherwise if pressure of the related pipe of the pyramid pressure gauge > 22]emits faint wisps of steam[otherwise]rises from the join[end if].". Does the player mean doing something to the pyramid: it is likely. Instead of doing something to distant-pyramid when location is Observatory Exterior: if pyramid is on-stage, try examining the pyramid; otherwise say "The three sides of the pyramid have vanished into slits in the ground.". The dream-text of pyramid is "tiny wooden pyramids".

The red-glow is part of the pyramid. Understand "red/glow" as red-glow. The printed name is "red glow". The description is "It streams out through the three edges of the pyramid, a knife-edge of crimson brilliance, as if something inside is giving off a tremendous light.".

Check opening the pyramid: say "The edges are far too close together to get a finger or even a fingernail between them, and there are no handles or other places to get a grip anywhere on the surface." instead. Check pushing the pyramid: say "You push against the side of the pyramid." instead. Check attacking the pyramid: say "You take a step back and slam into the side of the pyramid with your shoulder; though you are sure now that the interior is hollow, the wood does not come even close to giving." instead. Check entering the pyramid: try opening the pyramid instead. Check closing the pyramid: say "It seems quite closed already." instead. Check climbing pyramid: say "No point, since it's only as high as your head." instead. Check touching pyramid: say "The wood, though weathered a little, is planed smooth." instead.

To decide whether pyramid has power: if the pressure of the related pipe of the pyramid pressure gauge >= 22, decide yes; decide no.

The track is a setpiece in Observatory Exterior.

The pyramid outlet vent is an outflow tube. The pyramid outlet vent is part of the pyramid. The related pipe of the pyramid outlet vent is the yellow pipe.

The pyramid pressure gauge is a pressure gauge. It is in Observatory Exterior. It is undescribed. The target pressure is 22. The related pipe is the yellow pipe.

The three etchings are part of the pyramid. Understand "drawing" or "drawings" or "konokuk" or "fruits" or "trees" or "square" or "windsigh" or "tree" or "circle" or "galaxy" or "capalla" or "pentagon" or "dot/dots/side/sides" as the etchings. The description is "Each of the three sides of the pyramid bears one of the drawings, along with one, two, or three dots: the first shows [if konokuk trees are named]a konokuk fruit[otherwise]one of the hairy brown sphere-shaped fruits[end if] enclosed by a square, the second shows [if tree1 is named]a windsigh tree[otherwise]one of the ubiquitous twisted trees[end if] surrounded by a circle, and the last shows the night sky's galaxy, [if galaxy is named]Capalla, [end if]surrounded by a pentagon.". Instead of touching or taking the etchings, say "The detailed drawings are done directly on to the sides of the pyramid.". Check pushing the etchings: try pushing the pyramid instead. Understand "say capalla" [or "capalla"] or "say windsigh" [or "windsigh"] or "say konokuk" [or "konokuk"] as a mistake ("You say the word loudly into the air, but there is no response.") when location is Observatory Exterior.

The alternate-etchings are a story-based scrawl. [This is for story mode; a simpler version that bypasses the echo chamber puzzle.] Understand "etchings" or "word/words" as alternate-etchings. The printed name is "words on the pyramid". The standard message is "knock[paragraph break]thrice[paragraph break]clap".

Some metallic hoops are a setpiece in Observatory Exterior. Understand "huge/hoop/tilted/rings" as metallic hoops. The description is "From up close, you can see hundreds of the hoops, all of similar but not identical positions and dimensions. As a whole, they form one large ephemeral torus, tilted about thirty degrees to the ground, and giving the pyramid a wide berth, like some strange probability cloud bound to an origin by one force and repulsed by another. A forest of wooden rods support the strange structure in place.". Understand "huge" or "torus" or "ephemeral" as the hoops. Check attacking metallic hoops: say "It's probably not a good idea to damage this device until you're sure of what it does." instead. Instead of pushing or pulling or touching metallic hoops, say "[if pressure of the related pipe of the pyramid pressure gauge > 20]You reach out to touch the metallic hoops and--[paragraph break][paragraph break]... slowly, you open your eyes to find yourself flat on your back. Woozily, you stand to your feet, feeling faint tingles still arcing through your body. Where your fingertip brushed the hoop is a narrow black band[otherwise if pressure of the related pipe of the pyramid pressure gauge > 10]You reach out to touch the metallic hoops, then jerk your hand back sharply as a searing electric shock runs through it[otherwise if pressure of the related pipe of the pyramid pressure gauge > 0]You touch one metallic hoop and feel an electric current moving through it[otherwise]You touch your finger to a metal hoop, but feel nothing other than smooth coolness[end if].". The dream-text of metallic hoops is "tiny wooden pyramids".

The wire filaments are a setpiece in Observatory Exterior. Understand "filament/tiny/hundreds/junction" as wire filaments. The description is "Thin as human hair, the filaments stretch like a spiderweb from the apex of the pyramid to thousands of points along the metallic hoops surrounding it.". Check attacking wire filaments: try attacking metallic hoops instead. Check touching wire filaments: say "You touch one tentatively; it is incredibly fine and strung so tight you doubt you could move it without slicing your finger." instead. The dream-text of wire filaments is "tiny wooden pyramids".

Understand "knock thrice" or "knock three times" as thrice-knocking. Thrice-knocking is an action applying to nothing. Check thrice-knocking: if pyramid is off-stage, try vague knocking instead; if location is not Observatory Exterior, say "You knock sharply three times, but nothing happens." instead. Carry out thrice-knocking: say "You rap your knuckles sharply three times against the weathered wood of the pyramid's side." Understand "knock thrice on [something]" or "knock three times on [something]" or "knock on [something] thrice" or "knock on [something] three times" as knocking.

Clapping is an action applying to nothing. Understand "clap" as clapping. Carry out clapping: say "You clap your hands together sharply[if location is Observatory Exterior]. The sound is amplified by the round cirque[otherwise if location is Echo Chamber]. The sound echoes like a gunshot around and around, until slowly fading into silence[end if]."

Check vague knocking when location is Observatory Exterior: try knocking the pyramid instead. Check knocking the pyramid: say "You rap your knuckles sharply against the weathered wood of the pyramid's side. The wood seems thick, but the structure is definitely hollow." instead.

Pyract1 is a number that varies. Pyract2 is a number that varies. Pyract3 is a number that varies. Pyract4 is a number that varies.

Every turn when the pyramid is on-stage and location is Observatory Exterior:

now pyract1 is pyract2;

now pyract2 is pyract3;

now pyract3 is pyract4;

if we are clapping begin; now pyract4 is 2;

otherwise if we are thrice-knocking; now pyract1 is pyract3; now pyract4 is 1; now pyract3 is 1; now pyract2 is 1;

otherwise if we are vague knocking or knocking the pyramid; now pyract4 is 1;

otherwise; now pyract4 is 0;

end if;

if pyract1 is 1 and pyract2 is 1 and pyract3 is 1 and pyract4 is 2 begin;

if pyramid has power begin;

remove the pyramid from play;

move the mind chair to Observatory Exterior;

move the mind machinery to Observatory Exterior;

say "Something catches with a tiny click, and then, with a deep groaning, the three sides of the pyramid retract and disappear into black slits in the ground, revealing a triangular platform with a mass of [o]machinery[x] and a single wooden [o]chair[x], reclined and padded.";

print a section break;

try looking;

otherwise;

say "You hear a tiny snick, followed by a dull grinding of wound-down gears. All the steam flowing from the outflow vent immediately stops. The pyramid shutters, but then the noise winds down, and nothing further happens.[paragraph break]Steam begins rising again from the outflow vent.";

end if;

end if.