Blue Lacuna — 171 of 467

Section - The Ropeway

To say ropewayl: say "Ropeway: p:[pressure of related pipe of ropeway pressure gauge]/[target pressure of ropeway pressure gauge]; bkt:[location of bucket][if bucket is ascending] (asc)[otherwise if bucket is descending] (desc)[end if]".

To say ropewaysteam:

let Q be the pressure of related pipe of the ropeway pressure gauge;

if Q < 3 begin; say "Wisps of steam drift";

otherwise if Q < 6; say "A steady cloud of steam pours";

otherwise if Q < 12; say "Torrents of steam rise";

otherwise; say "A geyser of steam erupts";

end if.

The ropeway-shack is a setpiece in Chairlift Base. The printed name is "shack". Understand "shack" as ropeway-shack. The description is "The small building is open on the side facing the mountain, and crudely shields the ropeway mechanism from the elements.". The dream-text of ropeway-shack is "spare flywheels for the ropeway".

The ropeway mechanism is a setpiece in Chairlift Base. Understand "complex" or "pulley" or "pulleys" or "exquisitely" or "carved" or "wood" or "piston" or "cogwheel" or "cogwheels" or "system" or "counterweight" or "counterweights" or "rope" or "relay" as the ropeway mechanism. The description is "The mechanism is complex yet elegant. [if puzzle mode][gauge-description] marks the spot where a[else]A[end if] faded blue bamboo [o]pipe[x], stretching half-buried in a line towards the [if dir]southeast[otherwise]stumps[end if], joins the main mechanism, which is topped by an outflow [o]tube[x]. An exquisitely carved wood piston drives a system of pulleys, flywheels, and counterweights that connect to two thick [o]cables[x] rising up to the mountain's summit. A large wood [o]lever[x] is the only visible control.". Check attacking ropeway mechanism: say "Better to keep it in working order." instead. The dream-text of ropeway mechanism is "spare flywheels".

The flywheels are part of the bucket. Understand "flywheel" or "wheel" or "wheels" or "brake" or "brakes" as the flywheels. The description is "The wheels, expertly carved from some strong wood, connect the crate's support to the ropes. Each is equipped with a tiny brake, currently [if bucket is in Chairlift Base]engaged[otherwise]disengaged[end if].". Understand the command "disengage" as "unlock". Understand the command "engage" as "lock". Instead of vague unlocking or vague locking the flywheels, say "You don't see any manual way to engage or disengage the brakes on the wheels.". Check attacking flywheels: say "Better to keep it in working order." instead.

The ropeway outlet vent is an outflow tube. The ropeway outlet vent is part of the ropeway mechanism. The related pipe of the ropeway outlet vent is the blue pipe.

The ropeway pressure gauge is a pressure gauge. It is part of the ropeway mechanism. The target pressure is 4. The related pipe is the blue pipe. Does the player mean examining the ropeway mechanism: it is likely. ["ropeway" should default to machinery.]

A ropeway lever is a setpiece in Chairlift Base. Understand "ropeway" or "lever" as ropeway lever. The description of lever is "The lever [if bucket is ascending]is pushed forward[otherwise if bucket is descending]is pulled back[otherwise]stands straight up[end if]. It looks like it can be either pushed forward (towards the mountain) or pulled back." Instead of pushing or pulling the lever when bucket is not stationary, say "You give it a tug, but the lever seems for the moment to be locked into position." Check attacking the ropeway lever: say "You give it a savage kick, to no avail." instead. Instead of switching on or switching off ropeway lever, try examining ropeway lever. The dream-text of ropeway lever is "spare flywheels for the ropeway".

Understand "push forward" or "push [something] forward" as pushing. Understand "pull back/backward/backwards" or "pull [something] back/backward/backwards" as pulling. Rule for supplying a missing noun when pushing and location is Chairlift Base: change noun to ropeway lever. Rule for supplying a missing noun when pulling and location is Chairlift Base: change noun to ropeway lever.

To decide whether the chairlift has power: if puzzle mode and the pressure of the related pipe of the ropeway pressure gauge <= 6, decide no; if pressure of the related pipe of the ropeway pressure gauge < 4, decide no; decide yes. To decide whether the chairlift hasn't power: if the chairlift has power, decide no; decide yes.

Check pushing the ropeway lever: try turning the ropeway lever instead.

Check turning the ropeway lever:

if ropeway mechanism is being debugged, say "// Ropeway: blue pipe has pressure of [pressure of the related pipe of the ropeway pressure gauge] / 6 needed.";

if the chairlift hasn't power begin;

if ropeway mechanism is being debugged, say "// Ropeway: hasn't power.";

respond to unpowered ropeway;

stop the action;

end if;

say "You [if player is in bucket]reach out, [end if]push the lever into the forward position and feel something catch. ";

if bucket is in Lawn begin; say "But immediately a relay snaps shut above you, and nothing further happens other than a momentary surge of steam from the outflow vent.";

otherwise;

say "[if pressure of related pipe of ropeway gauge is 6]Steam stops flowing from the outflow vent[otherwise]The volume of steam from the outflow vent drops dramatically[end if] and the ropes, cogwheels, and counterweights around you start to move. [paragraph break]With a groan, the thick main flywheel begins to rotate. The rope moves, and the crate, wheels tightly locked, swings and follows it, picking up speed as it [if player is in bucket]and you move[otherwise]moves[end if] forward out of the station.";

now bucket is ascending;

if Lawn is unvisited and player is in bucket begin;

now ever-used-ropeway is true;

end if;

if player is in bucket, reset the boredom meter with "riding ropeway";

end if;

stop the action.

ever-used-ropeway is a truth state that varies.

Instead of pulling the ropeway lever:

if the chairlift hasn't power begin;

respond to unpowered ropeway;

stop the action;

end if;

say "You [if player is in bucket]reach out, [end if]pull the lever into the back position and feel something catch. ";

if bucket is in Chairlift Base begin; say "But immediately, a relay snaps shut above you, and nothing further happens other than a momentary surge of steam from the outflow vent.";

otherwise;

say "[if pressure of related pipe of ropeway gauge is 6]Steam stops flowing from the outflow pipe[otherwise]The volume of steam from the outflow pipe drops dramatically[end if] and the ropes, cogwheels, and counterweights around you start to move. But moments later a clunk sounds in the machinery above, and everything smoothly comes to a halt again. [paragraph break]From high up on the mountain, you see the crate come over the edge and begin quickly descending, rolling freely down the ropes above it.";

now bucket is descending;

rule succeeds;

end if.

To respond to unpowered ropeway:

if ropeway mechanism is being debugged, say "// Ropeway: respond to unpowered ropeway.";

if the pressure of the related pipe of the ropeway pressure gauge is 0 begin; say "You [if player is in bucket]reach out and [end if][if we are turning something]push against[otherwise]pull back on[end if] the lever, but nothing seems to happen, and when you release it, it snaps back up to vertical.";

otherwise if puzzle mode and the pressure of the related pipe of the ropeway pressure gauge is less than 4; say "You [if player is in bucket]reach out, [end if][if we are turning something]push the lever forward[otherwise]pull the lever back[end if] and feel something catch. Immediately steam stops rising from the outflow vent, and you a hear a hiss and groan as cogwheels start to turn; but almost immediately they grind to a halt again, seemingly lacking the oomph to get going. [paragraph break]Steam begins to rise again from the outflow vent.";

otherwise; say "You [if player is in bucket]reach out, [end if][if we are turning something]push the lever forward[otherwise]pull the lever back[end if] and feel something catch. Immediately steam stops rising from the outflow pipe, and you a hear a hiss and groan as cogwheels start to turn. The ropes begin to move above you, but just as everything seems about to kick into gear, the mechanism slowly loses speed and finally grinds to a halt. [paragraph break]Steam begins to rise again from the outflow vent.";

end if.

Instead of pushing or pulling or turning the bucket:

if player is in bucket begin; say "You can't push it while you're inside it.";

otherwise if location is Chairlift Base; say "You give the crate a solid push. It swings heavily back and forth in place, but does not otherwise move. Looking up, you see the wheels connecting it to the ropes seem to be locked.";

otherwise; say "You give the crate a gentle push. It begins to roll gently forward, the unlocked wheels turning against the taut ropes above."; now the bucket inertia counter is 1;

end if.

To advance the bucket:

if bucket is ascending begin;

if location of bucket is Chairlift Base, move bucket to Chair-lift1;

otherwise move bucket to the room up from the location of bucket;

otherwise;

if location of bucket is Lawn, move bucket to Chair-lift3;

otherwise move bucket to the room down from the location of bucket;

end if.

Every turn when the bucket is ascending or the bucket is descending (this is the report on ropeway excitement rule):

if ropeway mechanism is being debugged, say "// Ropeway: report on ropeway excitement rule (bucket in [location of bucket]).";

if the player is in the bucket begin;

if bucket is in Lawn begin;

say "The crate swoops over the edge of the cliff and plummets down the rope.";

if player is in bucket, reset the boredom meter with "riding ropeway";

otherwise if bucket is ascending;

say "You continue [one of]your ascent[or]rising[or]ascending[at random][if a random chance of 1 in 2 succeeds][time-of-day-bit][end if].";

end if;

otherwise if the player is in Chairlift Base;

if bucket is ascending, say "The ropes above you continue to move through the flywheel, which rotates noisily.";

otherwise say "[if bucket is in Chair-lift1]The suspended crate sails gracefully into the station[otherwise]The stationary ropes above you vibrate as the crate rolls down them towards you[end if].";

otherwise if the player is in Lawn;

say "[if bucket is in Lawn]The crate swoops over the edge of the cliff and plummets down the rope[otherwise if bucket is in Chair-lift2]Far below, you see the crate slow drastically, then stop as it pulls into the base station, swinging crazily back and forth[otherwise]The ropes above you vibrate tautly as the suspended crate flies down the track below you[end if].";

end if;

advance the bucket;

if ropeway mechanism is being debugged, say "// Ropeway: bucket advanced to [location of bucket].";

if location is Chair-lift1 or location is Chair-lift2 or location is Chair-lift3, try looking;

if the bucket is in Lawn or the bucket is in Chairlift Base begin;

if player is enclosed by bucket begin; say "[if bucket is in Lawn]As the crate crests the lip of a sharp mountain ledge, you pass another support pole and flatten out almost completely as you pass just above a wide green lawn.[paragraph break]With a shudder, the ropes above stop moving, but some catch snaps open and the brakes on the car's wheels unlock. You roll forward under the crate's momentum up a gradual slope, slowing until finally coming to a gentle halt against a round wooden bumper[otherwise]The crate continues braking as you fly above the surface of the marsh towards the base station. Just as you think you're about to smash into it, the brakes clunk into place above, arresting your forward motion. The crate sways dramatically forward, then backwards; your stomach will take a bit more time to settle[end if].";

otherwise if the player is in Chairlift Base; say "[line break][if bucket is in Lawn]Atop the distant mountain, you see the suspended crate crest the edge of the cliff[otherwise if bucket is in Chairlift Base and bucket is descending]The crate sails over the marsh, swooping towards you as half-engaged brakes squeal alarmingly. Just as it arrives at the station, the brakes snap shut, and the crate swings dramatically forward, backward, and finally comes to a stop[end if]. Moments later the lever near you snaps back to upright and a cloud of steam spurts from the outflow vent[if bucket is ascending]. The ropes slow to a halt[end if].";

end if;

now the bucket is stationary;

if player is in bucket, try looking;

end if.

First check going up when location is Chairlift Base: say "You'll have to operate the ropeway mechanism somehow, if you hope to do that." instead. First check going up when location is Lawn: say "You scramble up the pile of loose rocks and boulders to the summit, and stand for a moment in the wind on the island's highest point, enjoying your victory and the [o]view[x]. But the constant wind becomes wearisome before long, so you climb back down to the relative shelter of the lawn." instead.

The bucket is a open unopenable enterable undescribed container in Chairlift Base. It is fixed in place. The printed name is "crate". Understand "large" or "open-topped" or "wooden" or "wood" or "box" or "long" or "narrow" or "crate" or "coffin" or "seat" or "chair" as bucket. The description is "Roughly coffin-shaped, the open crate is scratched and nicked all over the inside, where ghosts of sawdust and grime still linger. A cross-brace near the support pole connecting the crate to the ropes above provides a crude wooden seat." The bucket can be ascending, descending or stationary. The bucket is stationary. Does the player mean entering the bucket: it is likely. Check taking bucket: say "It's attached to the cables overhead." instead. Check opening the bucket: say "There's no top; it's open to the air." instead. Instead of sleeponing bucket, say "It doesn't look very comfortable.[sleepsuggest]". Check climbing bucket: try entering bucket instead. The dream-text of bucket is "spare flywheels for the ropeway".

First report entering bucket: if bucket is in Lawn, increase the bucket inertia counter by 1; say "[one of]The seat is covered with years of accumulated grime, and spiderwebs and birds['] nests thrive near the join where the suspended crate hangs from the rope. You spend a few minutes clearing the detritus away, wondering how long it's been since this equipment was operated.[paragraph break][or][stopping]You grip the central support of the crate and climb unsteadily onto the seat as it rocks slowly beneath you[if location is Chairlift Base]. Once seated, you see that you can easily reach out and manipulate the [o]lever[x][end if]." instead. First report exiting when player was in bucket: say "You rock the crate as you push your legs over the edge onto solid ground again." instead.

The bucket inertia counter is a number that varies.

The check for bucket stranding rule is listed before the report on ropeway excitement rule in the every turn rulebook. Every turn when bucket inertia counter > 0 (this is the check for bucket stranding rule) :

if ropeway mechanism is being debugged, say "// Ropeway: bucket inertia counter at [bucket inertia counter].";

if the bucket inertia counter is 1 and player is in bucket, say "The addition of your weight causes the crate to pull loose from its berth. It begins to inch slowly forward as the wheels above start to turn.";

if the bucket inertia counter is 2 begin; say "The crate picks up speed, the wheels above turning faster and faster as it approaches the edge of the cliff."; end if;

if the bucket inertia counter is 3 begin;

if player is not in the bucket and ( the player is wounded or the mountain-spring is pristine ) begin; arrest the bucket;

otherwise; now the bucket is descending;

end if;

now the bucket inertia counter is -1;

end if;

increase the bucket inertia counter by 1.

Before going when location is Lawn and bucket inertia counter > 0 and ( the player is wounded or the mountain-spring is pristine ) : arrest the bucket.

To arrest the bucket: say "Quickly, you grab the crate and arrest its forward motion. If it were to go over the edge without you in it, you'd be stuck up here. You pull it back to its starting position."; now the bucket is stationary; now bucket inertia counter is 0; move bucket to Lawn.

Instead of pulling or taking the bucket when bucket inertia counter > 0 and player is not in the bucket: now the bucket inertia counter is 0; now the bucket is stationary; move bucket to Lawn; say "Grabbing the crate with both hands, you manage to stop its momentum and pull it back up to the end of the line, where it once again rests motionless.". Understand the command "stop" as "take".