Blue Lacuna — 167 of 467

Chapter - Rise

The prose name of Rise is "the top of the rise". The printed name of Rise is "On the Old Lava Flow". Rise is a room in North Island. Understand "rise" as northwest when location is North Beach. The description of Rise is "[risedesc].". To say risedesc:

if longform begin; say "Here is where the lava met the sea, after cutting a long swath across the island. From your position atop the flow you can see both sides of the island: [if former location is North Beach]before you, [Rise-northdesc], and behind [Rise-southdesc][otherwise if former location is Stumps]before you, [Rise-southdesc], and behind [Rise-northdesc][otherwise]to one side, [Rise-northdesc][otherwise][Rise-southdesc]";

say ". [if Rise is unvisited]You are surprised to see a[otherwise if Chairlift Base is visited]The[otherwise]A[end if] [o]ropeway[x] stretch[if Chairlift Base is visited]ing[otherwise]es[end if] from a meadow high atop the mountain to a small base station near the island's [if dir]northwestern [end if]corner[dot]";

otherwise if midday; say "The black lava rock bakes under the soles of your feet, the swaying [if konokuk trees are named]konokuk [end if]trees offering little shade[dot]";

otherwise if evening; say "Black shadows play over black lava in a visual cacophony as the slanting light throws the flow into sharp relief[dot]";

otherwise if raining or ( afternoon and rained ) ; say "Rain pools in tiny puddles and depressions atop the lava flow[if raining], dribbling off the green fronds above you and pattering loudly on the lava rock[otherwise], slowly evaporating in the warm afternoon light[end if][dot]";

otherwise if night; say "Your toes stub on hidden protrusions and uneven ripples in the lava, merging seamless and invisible with the black night[if pyramid has power]. In fact, almost the only light comes from a deep red glow beaming from atop the distant mountain, revealing[otherwise if the pressure of the related pipe of the pyramid pressure gauge > 0 ]. A faint red light pulses from atop the distant mountain, illuminating[end if]"; if the pressure of the related pipe of the pyramid pressure gauge > 0, say " [if pyramid-seen is true]the [o]pyramid[x][else]a man-made [o]structure[x][end if]"; say "[dot]";

otherwise if morning or sunrise; say "The rising light just reaches the lava flow here, pulling the cold shadowed black rock into reluctant hints of relief[dot]";

otherwise if midmorning; say "The grove of [if konokuk trees are named]konokuk[otherwise]tropical[end if] trees casts swaying shadows over the lava flow, still cool from the night[dot]";

otherwise; say "[one of][room ambience][or][time ambience][at random]";

end if;

if fallen trees are in Rise begin; unless Rebelworld-Sequence is solved and Treeworld-Sequence is solved, say "Fallen konokuk trees, felled by the quake or the storm, lay across the top of the rise, partially blocking the way to the hot spring[dot]"; end if;

say "[exits]".

To say Rise-northdesc:

say "the land drops off into a marshy swamp that stretches to the edge of [if North Marsh is visited]the[otherwise]a jagged[end if] [o]mountain[x]".

To say Rise-southdesc:

say "curves the tranquil white crescent of the lagoon, protected by the lava flow as it rises to the shattered side of the distant [o]volcano[x]".

Rise-stuff is stuff in Rise. Understand "swath/side/corner/swamp" as Rise-stuff when location is Rise.

Some fallen trees are a minor setpiece. The description is "They are split near their bases, the white wood splintered and jagged.". The provoke message is "They're too heavy to move, but you can easily clamber over them.".

Check sleeping in Rise: say "The lava rock is too hard and sharp; you'd never be able to get to sleep.[sleepsuggest]" instead.

The exits text of Rise is "From here, you could scramble [bw of North Beach][if dir][southeast][otherwise]down[end if] to the [dr]beach[x] or take an easier route [bw of Stumps][if dir][north][otherwise]down the other side of the flow[end if] towards the [dr]edge[x] of the marsh. [exrise_hotspringsbit]". To say exrise_hotspringsbit: if Hot Springs is unvisited, say "You can also hear the sound of a [dr]waterfall[x]"; otherwise say "The hidden [dr]pool[x] lies"; say " [bw of Hot Springs]through some heavy fronds [if dir][east][otherwise]opposite the sea[end if]". Understand "edge" as north when location is Rise. Understand "waterfall" or "pool" as east when location is Rise.

The ambience table of Rise is the Table of Rise ambience.

Table of Rise ambience

Report going from Rise to Stumps: say "You follow the path down a slight mossy slope[if raining or rained] slick with rainwater[end if]"; if raining, say " into a misty cloud"; otherwise say "[if a random chance of 1 in 2 succeeds][time-of-day-bit][otherwise], enjoying the unobstructed panorama before you[end if]"; say "." Report going from Rise to Hot Springs: say "You push great leafy fronds out of the way[if raining or rained], shivering as water drips all over you,[otherwise if night], pushing forward into thick blackness,[end if] and after a few moments break into a secluded grove." Report going from Rise to North Beach: say "You pick your way [if night or raining or rained]carefully [end if]down the cluster of [if raining or rained]slippery [end if]boulders, [if night or twilight or dawn]taking care not to twist an ankle in the gloom[otherwise]using handholds to steady yourself[end if], till your feet touch the smooth [if raining or rained]wet [otherwise if midday or afternoon or evening]hot [end if]sand again."