Blue Lacuna — 164 of 467

Section - The Color Door

The lava wall is a setpiece in Back Room. Understand "face/flow/crack/surface" as lava wall. The description is "Nearly vertical here, the lava flow's sharp edges drop smoothed and polished from floor to ceiling, a rippling, deep black surface." Check touching the lava wall: say "Smooth and glasslike, although quite hard." instead. Check pushing the lava wall: say "Solid." instead. Check climbing the lava wall: say "The floor, ceiling, and walls run right up against the lava flow, adjoining it at all points and leaving no gap to climb through." instead. Check attacking the lava wall: say "Hard as rock. Which it is." instead. The dream-text of lava wall is "cobblestones made of black lava rock".

Some cobblestones are a setpiece in Back Room. Understand "stones" or "cobble stones" or "cobbles" as some cobblestones. The description is "They have been shaped to neatly fill a crack bisecting the lava flow, from the top of the door to the roof of the shack, fitting together without any seam.". Instead of pushing or pulling or taking or opening cobblestones, say "The cobblestones, set firmly, do not budge at all.". Check attacking cobblestones: try attacking lava wall instead. The dream-text of cobblestones is "cobblestones made of black lava rock".

The lava tunnel door is east of Back Room and west of Jumble. The lava tunnel door is a closed undescribed implemented door. The description is "[if location is Back Room]Only just your height but wider than a normal door, its wooden surface has been planed smooth to bring out a complex grain. [door_details][otherwise]This side of the wide door crawls with a complex mechanism of clockwork [o]gears[x] and cogs, along with a large horizontal [o]lever[x] which can be pulled outwards[end if]." To say door_details: say "[if lava tunnel door is open]It stands open, and is[otherwise]It is[end if] unpainted except for six small [o]bands[x] of vertical color at about eye level. [paragraph break]At about the height you'd expect to see a doorknob runs a smooth arc of [the number of on-stage lava door buttons in words] small [o]buttons[x], each engraved with a stylized symbol". Check vague knocking when lava tunnel door is visible: try knocking lava tunnel door instead. Check knocking the lava tunnel door: say "You rap your knuckles sharply against the door, feeling the firmness of thick wood, but also a faint resonance and echo of space beyond." instead. Check listening to lava tunnel door: say "You put your ear close to the door as you experimentally press a few buttons. You can distinctly hear the snick of dowels and gears moving each time, but can't discern any difference between the buttons. But after some experimentation you're quite sure the machinery on the other side is storing the sequence of buttons pressed, and presumably the correct pattern will open the door" instead. Check listening to a lava door button: try listening to lava tunnel door instead. Check listening to the arc of buttons: try listening to lava tunnel door instead. The can't go through undescribed doors rule is not listed in any rulebook. The dream-text of lava tunnel door is "crates filled with replacement door buttons".

The six small bands of vertical color are part of the lava tunnel door. The description is "Each band seems to have been painted directly on the wood. From left to right, the colors are [o]red[x], [o]yellow[x], [o]black[x], [o]white[x], [o]blue[x], and [o]green[x]." Understand "colors" or "band of color" as small bands of vertical color. Instead of touching or pushing small bands of vertical color: say "You can feel the slightly different texture of each band of color, painted over the wood of the door."; rule succeeds. Check taking small bands of vertical color: say "They're just painted directly on the door." instead.

A color band is a kind of setpiece. Understand "stripe" as a color band. The red band is a color band. The description is "A deep, rich crimson.". The blue band is a color band. The description is "Deep sea-blue." The white band is a color band. The description is "Milky, with a faint pearlescent shimmer." The yellow band is a color band. The description is "The stripe is a rich, vibrant lemon-yellow.". The black band is a color band. The description is "Jet black." The green band is a color band. The description is "A rich emerald green.". Instead of pushing, taking or touching a color band, say "The bands are painted directly on the door.".

Instead of opening or pulling or taking the lava tunnel door when the door is closed and location is Back Room and Jumble is unvisited, say "You can't see any obvious way to open it: no knob or handle, just the row of [o]buttons[x] and the bands of [o]color[x].". Instead of vague unlocking the door: say "You don't see any sort of keyhole." instead.

Check pushing the lava tunnel door:

if the lava tunnel door is open begin;

try closing the lava tunnel door instead;

otherwise;

say "You brace yourself and shove against the door with your shoulder, but it doesn't even creak, let alone budge." instead;

end if.

Check attacking the lava tunnel door: say "You take a running start and ram the door with your shoulder, but gain nothing save a bruise. The door is solidly constructed and whatever mechanism holds it fast is sturdily built." instead. Check looking under the lava tunnel door: say "The door is almost flush with the floor and surrounding masonry; you cannot see beyond it." instead.

The arc of small buttons is part of the lava tunnel door. The description is "Each is a circle about the size of one made with a thumb and finger, flush with the door but very slightly convex. Stylized symbols are inlaid into each one. From left to right, the symbols are [if story mode][blist8][blist9][otherwise][blist1][blist2][blist3][end if].". To say blist1: say "[o]whale[x], [if rayfish is named][one of]manta -- no, [o]rayfish[x][or][o]rayfish[x][stopping][otherwise][o]manta[x][end if]". To say blist2: say ", [o]tree[x], [o]turtle[x], [o]crab[x], [o]crystal[x], [o]berry[x], ". To say blist3: say "[o]seagull[x], [o]bee[x], [o]spider[x], [o]mussel[x], [o]snail[x]". To say blist8: say "[o]manta[x], [o]tree[x], [o]crystal[x], ". To say blist9: say "[o]berry[x], [o]mussel[x], [o]snail[x]". Check attacking arc of small buttons: try attacking manta ray button instead.

Check pushing arc of small buttons: say "You'll have to say which one you want to press. There are [number of on-stage lava door buttons in words] buttons: [list of on-stage lava door buttons]." instead. Check attacking arc of small buttons: try attacking berry button instead.

A lava door button is a kind of setpiece. Understand "symbol/symbols" as a lava door button. Check taking a button: say "The buttons are flush with the door, the seams so tight you could not even get a fingernail in." instead. Check attacking a lava door button: say "You smash the base of your hand against it, but it simply pops back out again." instead. Check touching a lava door button: say "[if noun is manta ray button or noun is windsigh tree button or noun is crystal button or noun is berry button or noun is mussel button or noun is snail button]The slightly concave surface is rubbed smooth[otherwise]The slightly convex surface feels like roughened wood[end if]." instead. [A subtle hint.] Understand "hold [a lava door button]" as a mistake ("Pressing and holding the button seems to produce the same result as merely pressing it.").

Check pushing a lava door button when night: say "It's too dark to make out which button is which." instead. Check pushing a lava door button when lava tunnel door is open: say "With the door open, the buttons don't seem to depress." instead. Check pushing a lava door button when location is Jumble: say "The buttons are on the other side of the closed door." instead.

jumble_scenery is a setpiece in Back Room. The printed name is "fissure". Understand "fissure" as jumble_scenery when location is Back Room and lava tunnel door is open. The description of jumble_scenery is "Through the open doorway you can see a narrow [dr]chasm[x][if dir] to the [east][end if] cutting through the lava rock and heading to the right.".

chasm_scenery is a setpiece in Back Room. Understand "chasm" as chasm_scenery. Check examining chasm_scenery: try going east instead. The printed name is "chasm".

The whale button is a lava door button. The description is "A fat-bodied whale, one baleful eye peering out.". The manta ray button is a lava door button. Understand "rayfish" as the manta ray button. The description is "[if we have examined rayfish and rayfish is unnamed]A beautiful carving of the glowing manta ray creature in the lagoon[otherwise if we have examined rayfish and rayfish is named]A beautiful carving of Progue's rayfish from the lagoon[otherwise if we have not examined rayfish and rayfish is named]A beautiful manta ray creature you would guess is the one [the Progue] calls a rayfish[otherwise]Some sort of diamond-shaped manta ray creature[end if].". The windsigh tree button is a lava door button. Understand "tree9" as the windsigh tree button. The printed name of windsigh tree button is "[if tree1 is named]windsigh[otherwise]tree[end if] button". The description is "[if tree1 is named]Unmistakably a windsigh tree[otherwise]It's another one of those strange trees like the one you painted[end if].". The turtle button is a lava door button. The description is "A sea turtle, graceful in mid-paddle.". The crab button is a lava door button. The description of the crab button is "A scuttling crab, pincers raised.". The crystal button is a lava door button. The description is "A hexagonal pillar of crystalline mineral.". The berry button is a lava door button. Understand "berries" as berry button. The description is "A bush laden with heavy round berries.". The seagull button is a lava door button. The description is "A seagull in flight.". Understand "gull" as seagull button. The bee button is a lava door button. Understand "bumblebee" as bee button. The description is "A bumblebee, delicate wings spread open." The spider button is a lava door button. The description is "Hairy legs and a fat, smooth body.". The mussel button is a lava door button. The description is "A single oval mussel, its shell lined with tiny ridges." The snail button is a lava door button. The description is "A snail with a large, spiraled shell.".

The lava tunnel door has a list of objects called the rtl combination. The rtl combination of the lava tunnel door is {mussel button, crystal button, snail button, manta ray button, windsigh tree button, berry button}. The lava tunnel door has a list of objects called the ltr combination. The ltr combination of the lava tunnel door is {berry button, windsigh tree button, manta ray button, snail button, crystal button, mussel button}. The lava tunnel door has a list of objects called the setting.

Check object-debugging a lava door button: try object-debugging lava tunnel door instead. Check object-debugging the arc of small buttons: try object-debugging lava tunnel door instead. Check object-debugging a color band: try object-debugging lava tunnel door instead. Check object-debugging the small bands of vertical color: try object-debugging lava tunnel door instead.

Understand "push [things]" as pushing. [This allows players to push multiple buttons at a time, which saves typing.]

First Report pushing a lava door button:

say "With a gentle snick, the button depresses into the door, then pops back out as you release it.";

truncate the setting of the lava tunnel door to the last 5 entries;

add the noun to the setting of the lava tunnel door;

if lava tunnel door is being debugged, say "// Door: setting is now [the setting of the lava tunnel door].";

if the setting of the lava tunnel door is ltr combination of the lava door and story mode, reverse the setting of the lava tunnel door; [Can go right-to-left or left-to-right for story people.]

if the setting of the lava tunnel door is the rtl combination of the lava tunnel door:

now the lava tunnel door is open;

say "[line break]A heavy clunk and wooden grinding sound from behind the door as it swings open, revealing a [o]fissure[x] running into the black lava rock[one of].[section break][or].[stopping]";

try looking;

otherwise: [Provide some feedback so people know they're on the right track.]

if the setting of the lava tunnel door is ltr combination of the lava tunnel door:

say "[line break]Nothing happens. Odd. You felt sure that was it.";

otherwise if the setting of the lava tunnel door is close to rtl combination of the lava tunnel door or the setting of the lava tunnel door is close to ltr combination of the lava tunnel door:

say "[line break]You slam your palm against the door in frustration. You're sure you've almost got it, but still nothing happens.";

otherwise if the setting of the lava tunnel door is getting close to rtl combination of the lava tunnel door:

say "[one of][line break]Nothing. You have a feeling you're getting closer, though.[or][stopping]";

stop the action.

[Detect entering a combination that's only one symbol off, to print a consolation message to the player, but don't trigger this if we're still in the process of entering it.]

To decide whether (subject - a list of objects) is close to (target - a list of objects):

let tally be 0;

repeat with ctr running from 1 to number of entries in target begin;

if the number of entries in subject is at least ctr and entry ctr of subject is entry ctr of target, increase tally by 1;

end repeat;

if tally is at least ( the number of entries in target - 1 ) and the number of entries in subject is the number of entries in target, decide yes;

decide no.

[Detect a combination in progress that is getting close to correct (this is used to make sure Progue is not in the room if the player is about to enter a correct combination).]

To decide whether (subject - a list of objects) is getting close to (target - a list of objects):

let tally be 0;

repeat with ctr running from 1 to number of entries in subject begin;

if entry ctr in subject is listed in target, increase tally by 1;

end repeat;

if tally is at least ( the number of entries in target - 2 ) , decide yes;

decide no.

First Report opening lava tunnel door when location is Back Room: say "You enter the combination into the door. As you press the final button, it swings open with a heavy clunk and wooden grinding, revealing the narrow [dr]chasm[x] behind it." instead.

When play begins: now all lava door buttons are part of the lava tunnel door. When play begins: now all color bands are part of the lava tunnel door.

Report going from Back Room to Jumble: say "You step through the doorway into a confusion of boulders.".