Blue Lacuna — 158 of 467

Part - Progue's Domain

Chapter - Hut

Hut is inside from Center Beach.

Check sleeping in Progue's Domain: say "You're not going to sleep very well on these old warped boards.[sleepsuggest]" instead.

The prose name of Hut is "the log cabin". The printed name of Hut is "Abandoned Cabin". The description of Hut is "[hutdesc].". To say hutdesc:

if longform begin; say "Sand drifts around the open doorway, spilling out in tiny dunes across the wooden floorboards[if Back Room is visited or Studio is visited] disturbed only by your footsteps[otherwise], undisturbed[end if]. Bare, water-stained walls frame a small room, empty and abandoned save for a manta ray [o]skeleton[x] hanging from one wall; some frayed ropes tied to one beam are the only other hint of past furnishings";

otherwise if raining or dawn or twilight; say "The cabin's front room is gloomy and indistinct in the dim light that filters from outside, [if raining]though the roof provides welcome protection from the storm[otherwise]still as a tomb[end if]";

otherwise if sunset or evening; say "Evening light floods the room as the setting sun shines through the open doorway";

otherwise if night; say "[if moonup]Pale pink moonlight angles through the open door of the cabin, but illuminates little beyond the sharp edges of shadow it casts on the weather-beaten floorboards[otherwise]The cabin is black in the moonless night, only the dimmest traces of starlight spilling in through the open doorway";

otherwise if sunrise or morning; say "Reflected light from the morn-kissed lagoon bounces into the cabin, bringing hints of color to the water-stained floorboards";

otherwise; say "The white glow of the beach through the open door is brilliant; your eyes struggle to adjust to the dim interior of the cabin instead";

end if;

say ".[paragraph break]";

if Tsunami Sequence has ended begin;

say "The cube must have been smashed against a wall in the earthquake or tsunami; only fractured remnants remain now. The [o]sketchbook[x], waterlogged and awry, seems nevertheless intact";

otherwise if cube is Progue-disturbed;

say "The wooden [o]cube[x] lies upended in the middle of the floor[if cube is closed]. The violence has popped it open, and a worn [o]sketchbook[x] lies half-in, half-out, pages flapping faintly on the floor[otherwise], the [o]sketchbook[x] half-in, half-out, flipped to the page with the tree[end if]";

now wooden cube is open;

otherwise;

say "The room's sole other feature is [if we have examined the wooden cube]the[otherwise]a[end if] [if wooden cube is open]open [end if]wooden [o]box[x][if wooden cube is open and the sketchbook is in cube] (containing [the sketchbook])[otherwise if Hut is unvisited] discarded in a corner[otherwise] lying askew on the floor[end if]";

end if;

say ".[paragraph break][exits]".

Hut-stuff is stuff in Hut. Understand "steps/footsteps" as Hut-stuff when location is Hut.

The manta ray skeleton is a setpiece in Hut. The description is "The skeleton, mounted on the wall, makes a large diamond, and must have once belonged to some flat, manta ray creature with rare elegance. Now, bleached and dusty, it only seems to add to the loneliness and neglect of the cabin.". Check touching manta ray skeleton: say "The bone is cold and hard." instead. Check taking manta ray skeleton: say "It's mounted on the wall." instead.

The exits text of Hut is "Two smaller interior doorways lead [ethut_extended]. You can also step back [d]outside[x]". Understand "porch/studio" as north when location is Hut. Understand "storage" or "interior" as east when location is Hut.

To say ethut_extended:

say "[if dir][north] [end if]to ";

if Studio is visited, say "the [if sunup]brightly-lit[otherwise if dawn or twilight]dim interior of the[otherwise]dark[end if] [dr]studio[x]";

otherwise say "a [if sunup]bright[otherwise if dawn or twilight]dim[otherwise]dark[end if] [dr]porch[x]";

say " or [if dir][east] [end if]to ";

if Back Room is visited, say "the tiny [dr]storage[x] room";

otherwise say "a[if sunup] darker[otherwise if dawn or twilight]n indistinct[otherwise] black[end if] [dr]interior[x]".

The hutsand is a prop in Hut. The printed name is "sand". Understand "sand" or "drifts" or "tiny" or "dunes" as hutsand. The description is "Piled to your ankles near the door, the miniature dunes shrink down to the thickness of grains by the far walls[if Back Room is unvisited], utterly smooth and undisturbed-- though perhaps the beach winds would smooth out footsteps in days[otherwise if Jumble is unvisited], disturbed only by your footprints[end if]." The dream-text of hutsand is "buckets of sand".

The hammock remnants are a minor prop in Hut. Understand "strands" or "rope/ropes/hammock" or "rotten/frayed" as remnants. The description is "It looks as if something like a hammock once hung here, but in some past year of flooding the ropes must have weakened and rotted away. The few remaining strands are useless." The provoke message is "Too rotted and weak to be useful for anything.".

Report going from Hut to Center Beach: say "You step back outside into [if raining]the rain[otherwise if sunup]the sunlight[otherwise]the night[end if], walking down the beach in the direction of the surf." Report going from Hut to Studio: say "You duck through the small doorway into a windowed porch." Report going from Hut to Back Room: say "You step through the doorway into a smaller room at the rear of the cabin."