Blue Lacuna — 142 of 467

Section - The Lagoon

The lagoon is a seen view with base room Center Beach. It is in South Beach, Center Beach, North Beach, Hut, Lower Beach, Ocean Waters, Tidepools, Among the Boulders, Rise, Rim of Volcano, Ledge, Cliffside, Lawn, and Observatory Exterior. Understand "bay/crescent" as lagoon. The lagoon is very near South Beach and Center Beach and North Beach and Hut and Lower Beach and Ocean Waters and Tidepools and Among the Boulders and Rise. The lagoon is very far from Rim of Volcano and Ledge and Cliffside and Lawn and Observatory Exterior.

Check entering the lagoon when location is Center Beach: try going west instead. Check entering the lagoon when location is South Beach: try going northwest instead. Check entering the lagoon when location is North Beach: try going southwest instead.

The description of lagoon is "[lagoondesc].". To say lagoondesc:

if lagoon is very near location begin; say "The lagoon undeniably captivates the eye, aesthetically perfect in some indescribable way. Electric blue water far out to sea fades to a creamy neon turquoise as it enters the shallows of the bay, before crashing in long foamy runners of [o]surf[x] on the white sand beach which rims it. At [if location is South Beach or location is Among the Boulders or location is Tidepools]the far[otherwise if location is Rise or location is North Beach]the nearer[otherwise]one[end if] end of the bay, a rocky rise of black lava tumbles across the sand and into the water, forming a sharp boundary and a shocking contrast of color, while the ";

say "[if location is South Beach]nearer[otherwise if location is North Beach]far[otherwise]other[end if] side is bounded by a lower point filled with tidepools and rounded boulders";

otherwise; say "The lagoon [if evening or sunset or afternoon]sparkles in the distance as the sun reflects off its cerulean waters[otherwise if midday or midmorning or morning or sunrise]arcs gently in the distance, a jewel of blue and cream[otherwise if twilight or dawn]shimmers subtly in the distance, like a dark blue bruise in the shadowless light[otherwise]in the distance is marked by faintly seen blobs of pale moving light[end if]";

end if.

To say a sentence about the lagoon:

if night begin;

if we have examined the rayfish and the distant-rayfish are on-stage begin; say "The faint pale glows of [the rayfish] dance slowly out in the lagoon";

otherwise if distant-rayfish are on-stage; say "Pale [o]lights[x] weave and bob through the waters of the lagoon";

otherwise; say "The lagoon is black and silent in the strange night air";

end if;

stop; end if;

if afternoon or midday or midmorning begin;

say "The ocean [if tidein]stretches to[otherwise]pounds faintly beneath[end if] the western horizon, [if rain clouds are in location]under a grey sky streaked with fast moving [o]clouds[x][end if][if raining] dumping buckets of rain[end if]";

if rain clouds are not in location, say "[one of]where it meets a vast, unclouded sky, so deep a blue your eyes hurt[or]the [o]lagoon[x] practically glowing as it warms in the sparkling sunlight[in random order]";

stop; end if;

if evening begin;

if rained begin;

say "Thunderheads receding westward are lit up like giant floating barges by the sinking sun's rays, which are reflected by the [o]water[x] and the wet, sparkling [o]sand[x]";

otherwise;

say "Reflected sunlight shimmers off the [if tideout]distant [end if][o]tide[x], pointing a straight line towards the sinking sun";

end if;

stop; end if;

if sunset begin;

say "A fantastic tropical sunset dominates the sky, the [if tideout]distant [end if][o]waves[x] westward shimmering magically under deep purples, oranges, and the brilliant yellow gleam of the setting sun";

stop; end if;

if twilight begin;

say "The sky and the colors of the lagoon are slowly fading in the dimming light";

stop; end if;

if dawn or sunrise or morning begin;

say "[one of]Distant clouds glow yellow-pink over the ocean to the west as the rising sun's rays intersect them, but [if dawn]the land[otherwise]most of the beach[end if] is still in shadow[or]The [o]lagoon[x] stretches before you, blue and beautiful, slowly richening in color as the sky brightens above[in random order]";

stop; end if.