Blue Lacuna — 138 of 467

Part - Distant Views

Section - The Mountain

The mountain-view is a seen view with base room North Marsh. Understand "mountain/peak/summit" as mountain-view. The printed name is "mountain". It is in East Marsh, North Marsh, Ravine Floor, Top of Ravine, Ledge, Cliffside, Lawn, Observatory Exterior, Chair-lift2, Chair-lift3, Edge of Ravine, Viewpoint, West-Marsh, Stumps, Rise, Chairlift Base, Hive Room, Chair-lift1, Lower Beach, Ocean Waters, South Beach, Among the Boulders, Tidepools, Rim of Volcano. The mountain-view is very near East Marsh and North Marsh and Ravine Floor and Top of Ravine and Ledge and Cliffside and Lawn and Observatory Exterior and Chair-lift2 and Chair-lift3 [anywhere we can't see the whole thing]. The mountain-view is near Edge of Ravine and Viewpoint and West-Marsh and Stumps and Rise and Chairlift Base and Hive Room and Chair-lift1. The mountain-view is far from Lower Beach and Ocean Waters and South Beach. The mountain-view is very far from Among the Boulders and Tidepools and Rim of Volcano. Understand "summit" or "cliff" as the mountain-view when location is not Lawn and location is not Observatory Exterior.

Check examining the mountain-view:

if location is Lawn or location is Observatory Exterior begin; say "The summit of the mountain is only a short scramble above you from here";

otherwise if location is North Marsh; say "The cliff rises straight up out of the marsh in a vertiginous climb to the summit, as if in some past geologic epoch half the mountain split and sunk into the sea. Indeed, a deep [o]crack[x] runs nearly straight up from here, harbinger perhaps of further destruction";

otherwise;

say "The mountain is [distance of mountain-view]. It dominates [if dir]the northeastern[otherwise]one[end if] corner of the island, one side a sheer cliff face, the other tumbling treacherously into the sea. The rocky sides [if mountain-view is very near location or mountain-view is near location]seem to be composed of weathered volcanic rock[otherwise]are black and smooth[end if]";

if the mountain-view is not very far from location, say ".[paragraph break]Perched near the summit is [if night and pyramid has power]a small [o]structure[x], shining with a deep red glow that illuminates the whole summit of the mountaintop[otherwise if night and pressure of the related pipe of the pyramid pressure gauge > 0]a small pyramid structure. A faint red glow pulses from somewhere inside it, disappearing and then reappearing in a slow and steady cycle[otherwise if Lawn is unvisited]some sort of man-made [o]structure[x][else]the [o]pyramid[x][end if]";

end if;

say "." instead.

First instead of climbing the mountain-view when location is North Marsh: try going up instead. First instead of climbing the mountain-view when location is Lawn: try going down instead. First instead of climbing the mountain-view when location is Observatory Exterior: say "The mountainside drops off a dizzying distance into the sea-swept gorge far below; there is no visible route down from here." instead. First instead of climbing the mountain-view when location is East Marsh: say "The cliff face is smooth and softened with slick moss here, and you cannot get a good enough grip to climb." instead.

To say a sentence about the mountain:

if we have not examined the mountain-view, say "A large, craggy [o]mountain[x] looms up into the clouds, [distance of mountain-view]";

otherwise say "The [o]mountain[x], [distance of mountain-view], glowers [if evening or sunset]in the fiery glow of the fading sun[end if][if sunrise]in shadows as the sun rises behind it[end if][if moonup]in a pillowy glow of moonlight[end if]".

To say a phrase about the mountain:

if raining begin;

say "but mist shrouds the rest of the island";

otherwise if night; say "and [if we have examined the mountain-view]the great dark shape of the [o]mountain[x][otherwise]a great dark shape[end if]looms over the island";

otherwise; say "[one of]while the [o]mountain[x] rises dramatically over the landscape[or]and, like a titan, the [o]mountain[x] looms over the island[in random order]"; say "[if rained], head shrouded in clouds[end if][if sunrise or morning], its peak catching the morning light[end if][if sunset or twilight], the top of its peak glowing a dull red[end if]";

end if.

Table of Mountain ambience