Blue Lacuna — 61 of 467

Aaron A. Reed

Release 4

Section - Examining Yourself

Conds is a list of indexed texts that varies.

Check examining yourself:

truncate conds to 0 entries;

let legmsg be indexed text; let legmsg be "Your leg still pains you enough that you won't be doing any jumping or climbing";

let rainmsg be indexed text; let rainmsg be "You are soaking wet";

let tire1msg be indexed text; let tire1msg be "You're exhausted";

let tire2msg be indexed text; let tire2msg be "You could really use a good night's sleep";

let rumemsg be indexed text; let rumemsg be "The pain of loss is still sharp in your chest";

let nakedmsg be indexed text; let nakedmsg be "You're naked";

let lovemsg be indexed text; let lovemsg be "Something inside you is giddy and flush with excitement";

let dreammsg be indexed text; let dreammsg be "You're still rubbing the sleep from your eyes";


if the player is wounded, add legmsg to conds;

if raining and location is outdoorsy, add rainmsg to conds;

if sleep debt of yourself > 10 begin; add tire1msg to conds;

otherwise if sleep debt of yourself > 5; add tire2msg to conds;

end if;

if current chapter <= 3, add rumemsg to conds;

if homemade outfit is not worn, add nakedmsg to conds;

if romance of Progue >= 3, add lovemsg to conds;

if the number of entries in list of remembered stuff <= 1, add dreammsg to conds;

let endctr be number of entries in conds;

repeat with ctr running from 2 to endctr begin;

now entry ctr of conds is "[entry ctr of conds in lower case]";

end repeat;

if the number of entries in conds is 0, say "You're not sure what to do next";

say "[conds], but otherwise you're doing all right." instead.

Instead of touching or hugging yourself, try examining yourself.