Blue Lacuna — 423 of 467

Aaron A. Reed

Release 4

Chapter - Cinder Cone Flashback

[Progue is working feverishly on egg machinery while the girls, hungry and fearful, watch.]

Dream-CinderCone is a flashback-room in Dreamlands. The printed name is " Inside Caldera, At The [if player is DC-Progue]Collapse[otherwise]Cinder Cone[end if] ".

The description of Dream-CinderCone is "[dreamcinderconedesc]". To say dreamcinderconedesc:

if player is DC-Progue begin; say "Steam scalds your hand, sleep claws at your eyes, but you feel more awake and alive than you have in months.[paragraph break]Before you is the crystal [o]egg[x], the beautiful piece of alien technology you rescued from the crash, and surrounding it are your experimental attempts to activate it. The [o]boiler[x] nearby funnels the steam power of the volcano into the device, which glows dimly, though you're still not sure quite what it does.[run paragraph on]";

otherwise if player is DC-Phoebe; say "The vines of the windsigh on the cinder cone, where you and your sister have crept to spy on dad, feel tingly and warm under your hands, while the rest of your flesh rises in goosebumps. It's not that it's cold, even though it's long after sunset. It's what dad is doing. It's that he hasn't slept in days. It's that he seems to have forgotten all about his children.[run paragraph on]";

otherwise if player is DC-Lethe; say "Your head spins. Maybe it's [if dc-lethe is unfed]because you're so hungry, or maybe it's from being up so late. Or from [end if]the weird shadows the moonlight makes on the black lava. Exploring down here was a lot more fun when you were scared of getting caught. Now you almost wish you would be.[run paragraph on]";

end if.

Dream-CinderCone-stuff is stuff in Dream-CinderCone. Understand "steam/experimental/attempts/volcano/vines/goosebumps/shadows/moonlight/lava" as Dream-CinderCone-stuff when location is Dream-CinderCone.

The d-crystal is a setpiece in Dream-CinderCone. The printed name is "crystalline egg". Understand "crystal/crystalline/egg/technology" as d-crystal when location is Dream-CinderCone. The description of d-crystal is "[if player is dc-progue]The beautiful crystal egg is attached to a nest of wires and cables as you attempt to troubleshoot it.[paragraph break][egg-details].[otherwise]You haven't been able to see it up close. It looks very pretty, but you have no idea what it could be.". To say egg-details: say "[if the number of plugged on-stage d-wires > 0]Running out of the serial interface [is-are] [the list of plugged on-stage d-wires][otherwise]The serial interface of the egg is momentarily unattached[end if]. [if the number of unplugged on-stage d-wires > 0]You hold [a list of unplugged on-stage d-wires] in your hand[otherwise]Your hands are momentarily empty[end if].[paragraph break]The steam outflow gauge reads [38 - crys-power]. The egg [eggglow]". Instead of taking d-crystal: say "[if player is dc-progue]It's heavy, and connected to a rat's nest of cables and machinery right now at any rate.[otherwise]It's too far away.[end if]". Check attacking d-crystal: say "What, smash the most exciting thing you've ever seen in your life? Advanced technology from some other world, a mystery, your mystery? Gushing unlikely." instead.

To say eggglow:

let temp be correct crystal power - crys-power;

if temp < 0, now temp is temp * -1;

if temp < 5 begin; say "glows intensely bright";

otherwise if temp < 10; say "glows moderately bright";

otherwise if temp < 15; say "glows slightly bright";

otherwise if temp < 20; say "glows dimly";

otherwise if temp < 25; say "glows almost imperceptibly";

otherwise; say "is dark";

end if.

The serial interface is part of d-crystal. The description is "This is one of over a dozen input/output points along the fractal surface of the egg, and seems to be some sort of power regulator designed to deliver the correct amount of power to the circuitry inside.".

The dream-gauge is part of d-crystal. Understand "steam/outflow/gauge" as dream-gauge when location is Dream-CinderCone. The printed name is "outflow gauge". The description is "You quickly rigged this up by hollowing out a piece of quartz and attaching it to the main steam pipe running into the power regulator. The ferocity of boiling water trapped inside gives you a rough idea the amount of energy being transfered to the egg.".

A d-wire is a kind of thing. A d-wire is always undescribed. A d-wire has a number called strength. A d-wire is either plugged or unplugged. A d-wire is usually unplugged. A d-wire has some text called key-name. Rule for printing the name of a d-wire (called dw): say key-name of dw. Instead of taking a plugged d-wire (called dw): try examining dw. Instead of taking an unplugged d-wire: say "You're already holding it." Understand "plug [a d-wire] in/into/to [d-crystal]" or "plug [a d-wire]" or "plug in [a d-wire]" as a mistake ("[tryexaminingdwire]"). To say tryexaminingdwire: try examining noun. Instead of inserting a d-wire (called dw) into something, try examining dw. Instead of tying a d-wire to something: try examining noun.

d-wire-ctr is a number that varies.

Instead of examining a d-wire (called wr):

increase d-wire-ctr by 1;

if wr is plugged begin;

now wr is unplugged;

say "You unplug [the wr] from the egg.";


now wr is plugged;

say "You plug [the wr] into the egg.";

end if;

unless crys-power is correct crystal power begin;

if d-wire-ctr > 26 and thick cable is on-stage begin;

say "[line break]You're sure now the thick cable isn't needed either. You rip it out too and discard it.";

remove thick cable from play;

otherwise if d-wire-ctr > 13 and sticky wire is on-stage;

say "[line break]You're sure the sticky wire is redundant. Impatiently, you rip is out and toss it aside.";

remove sticky wire from play;

end if;

end unless;

if crys-power is correct crystal power, say "[line break]With a sudden surge, something inside the egg flares into life and begins to rotate. A beam of light flares from the top of the egg, shooting up into the sky...But suddenly everything dies down again.[paragraph break]You slam your hands onto the top of the boiler in frustration. What did you do wrong? Everything was calibrated, the power was finally right, and then... you stare up into the tendrils of steam whirling up into the night sky above you, obscuring the stars. A thought trickles into your mind...[paragraph break]Obscuring the stars. That's it. You've had a gut feeling the egg is designed to send or receive some sort of signal, ever since you laid eyes on it. Here in the volcano, there are too many fumes and too much obscuring mist for it to get a good signal. But the island is plagued with that: morning fog, afternoon rain showers, steam vents...[paragraph break]Your hand reaches for your sketchbook almost unconsciously. You'll have to somehow find a way to get the egg and all this machinery up to the top of the mountain, high above the haze and with a clear line of sight to any point on the horizon. You'll have to get the power up there, and the heavy materials. You start to sketch, frantically, blinking away sleepy crumbs in the corners of your eyes. This is too important to wait until morning. Too important...[paragraph break]{(*important*)}[end-flashback]";

otherwise say "[line break][egg-details].".

Correct crystal power is a number that varies. Correct crystal power is 22. [Because that's how much power it has back in the waking world. We expect most players will just get this by trial and error, but this may allow one or two to feel exceedingly clever.]

To decide what number is crys-power:

let tot be 0;

repeat with wire running through plugged on-stage d-wires begin;

increase tot by strength of wire;

end repeat;

decide on tot.

A braided wire is a d-wire in Dream-CinderCone with strength 12 and key-name "[o]braided[x] wire". A silver wire is a plugged d-wire in Dream-CinderCone with strength 2 and key-name "[o]silver[x] wire". A coarse wire is a d-wire in Dream-CinderCone with strength 4 and key-name "[o]coarse[x] wire". A sticky wire is a plugged d-wire in Dream-CinderCone with strength -17 and key-name "[o]sticky[x] wire". A copper tube is a plugged d-wire in Dream-CinderCone with strength 20 and key-name "[o]copper[x] tube". A thick cable is a d-wire in Dream-CinderCone with strength -3 and key-name "[o]thick[x] cable".

Instead of doing anything to a d-wire when player is not dc-progue: say "You can't really make out the individual parts of the experiment from this far away.".

Instead of taking inventory when location is Dream-CinderCone and player is dc-progue: say "You are holding [the list of unplugged on-stage d-wires]."

The dream-boiler is a setpiece in Dream-CinderCone. Understand "boiler" as dream-boiler when location is Dream-CinderCone. The printed name is "boiler". The description is "Over the past few days, you've built this boiler over one of the larger steam vents to capture the tremendous thermal energy boiling up from the depths of the volcano. The egg, you've learned, seems to require a significant amount of power to do whatever it is that it does.".

Understand "cluster/cone/chasm/entrance" as up when location is Dream-CinderCone. Understand "cave" as down when location is Dream-CinderCone.

First Instead of going up when location is Dream-CinderCone: say "[if player is dc-progue]No, no, no. You have to get the egg working.[otherwise]No, you can't risk it. If dad sees either of you down here, he'll know you figured out the code to the door, and maybe he'll change it, and then you might never be able to figure out what's happening to him...". First instead of going down when location is Dream-CinderCone: say "[if player is dc-progue]You don't know of any caves in this part of the island.[otherwise][one of]You hesitate for a moment. You aren't sleepy at all, but there's no way to sneak past dad without him seeing you. Maybe you and your sister should just try to get some sleep.[or]'Come on,' you whisper to your sister, tugging her sleeve. Together, the two of you turn away and tread lightly down the slope of the cinder cone's smooth slope, crawling into the darkness of your secret cave. Maybe in the morning things will change...[paragraph break]{(*change*)}[line break][end-flashback][stopping]".

The dc-windsigh is a setpiece in Dream-CinderCone. Understand "tree9/windsigh/vine/vines" as dc-windsigh. The printed name is "windsigh on the cinder cone". The description is "[if player is dc-progue]You can't really be bothered to do more than glance at it right now.[otherwise]The tree provides good cover for the two of you to sneak up behind it and watch dad. Not that you get the idea he'd notice you if it weren't there, anyway. Or remember that you're absolutely forbidden to be here in the first place.". Instead of climbing dc-windsigh: if player is dc-progue, try examining dc-windsigh; otherwise say "There's no reason to; you can see just fine from here.". Instead of touching dc-windsigh: if player is dc-progue, try examining dc-windsigh; otherwise say "You run your fingers idly along the vines and trunk of the windsigh distractedly.".

Does the player mean greeting dc-progue when the player is dc-lethe or the player is dc-phoebe: it is very unlikely. First instead of greeting when player is dc-progue: say "There's no one here to greet."

Instead of greeting when player is dc-progue: say "There's no one here to greet." Instead of greeting dc-lethe, say "You open your mouth to whisper something to Laylay, but she holds up a finger to her lips and shakes her head.". Instead of greeting dc-phoebe, say "You try to get Phoebe's attention, but her gaze is fixed on dad, chewing a frowning lower lip in frustration.".

DC-Progue is a dream-progue in Dream-CinderCone. The description is "[if player is dc-progue]Your hair is disheveled, your clothes a mess, and you feel like you've been up for days, probably because you have. The egg has become an obsession; have you ever had so important a task, so exciting a mandate? Solving the mystery of what you found in the rain forest is up to you and you alone.[otherwise]Dimly illuminated in the rising and fading red glow of the weird glass egg thing he found in the rain forest, your father {(*[d]progue[x]*)} hunches obsessively over the strange contraptions he has built around it, tinkering. He looks thin and hungry and half-dead, but what's scary is that he looks like he doesn't even realize it.".

DC-Lethe is a dream-lethe in Dream-CinderCone. Rule for writing a paragraph about dc-lethe: if player is dc-progue, say "The collapse stretches towards the [d]chasm[x], and dimly in the moonlight you spot the [d]cluster[x] of steam vents and the cinder [d]cone[x][if a random chance of 1 in 2 succeeds]. For a moment, you think you catch a glimpse of movement {(*[d]phoebe[x]*)} {(*[d]lethe[x]*)} in that direction. Probably birds[end if]."; if player is dc-phoebe, say "Your [o]sister[x] crouches near your feet, peeking around the trunk of the tree with wide eyes at [o]dad[x], halfway across the volcano floor by the chasm [d]entrance[x]. Behind you, the entrance to your secret [d]cave[x] is barely visible in the moonlight."; now dc-phoebe is mentioned; now dc-progue is mentioned. The description of dc-lethe is "[if player is dc-progue]You can't see any such thing.[otherwise if player is dc-phoebe]Laylay {(*[d]lethe[x]*)} looks scared, and you can't really blame her. You put your hand on your shoulder and she hugs your leg fiercely.[otherwise]You're tired and hungry. But more than that, you want to know what's happening to dad." DC-Lethe can be fed or unfed. dc-lethe is unfed.

Instead of sleeping when location is Dream-CinderCone: say "[if player is dc-progue]Your body needs it, but your mind is still racing, and you know if you lay down right now you'd never be able to sleep.[otherwise]You're worried, but tired too. Curling up the [d]cave[x] for a nap might not be too bad an idea. You have an idea dad will still be here and working in the morning...[end if]".

Instead of greeting DC-Progue: say "You open your mouth to shout something, but your sister grabs your mouth and pulls you down. She shakes her head.".

DC-Phoebe is a dream-phoebe in Dream-CinderCone. The description is "[if player is dc-progue]You can't see any such thing.[otherwise if player is dc-lethe]Phoebe {(*[d]phoebe[x]*)} stands next to you, and you're so glad to have her here now. It almost feels like the two of you are all that's left of the family.[otherwise]Your heart is racing and you feel sweaty, even though you've been standing here for almost half an hour.". Rule for writing a paragraph about DC-Phoebe: say "Your [o]sister[x] stands next to you, gripping the trunk of the windsigh, while you sit just to the side of it, watching [o]dad[x]'s weird experiments across the volcano. The secret [d]cave[x] is behind you both."; now dc-progue is mentioned.

DC-Phoebe holds a d-berries. The printed name of d-berries is "handful of berries". Understand "berry/berries" as d-berries when location is Dream-CinderCone. The description of d-berries is "Your last handful of berries, shoved into the pocket of your exploring pants.". Instead of eating d-berries, say "You munch a few of the berries[if dc-lethe is unfed]. Laylay looks up at you hungrily[end if].". Instead of giving d-berries to dc-lethe: say "You give half of your berries to your sister, who gratefully begins to munch on them."; now dc-lethe is fed.

c-progue-trigger is a person-trigger in Dream-CinderCone with target DC-Progue. Understand "progue" as c-Progue-trigger when location is Dream-CinderCone.

c-lethe-trigger is a person-trigger in Dream-CinderCone with target DC-Lethe. Understand "lethe" as c-lethe-trigger when location is Dream-CinderCone.

c-phoebe-trigger is a person-trigger in Dream-CinderCone with target DC-phoebe. Understand "phoebe" as c-phoebe-trigger when location is Dream-CinderCone.