Blue Lacuna — 209 of 467

Aaron A. Reed

Release 4

Section - The Clockwork Head

The clockwork head is a prop in Treehouse. "[if we have examined the clockwork head]The clockwork head rests on a shelf[otherwise]Something round and wooden lies in a dusty corner, forgotten[end if]." Understand "round" or "wooden" or "something" or "dusty" or "corner" or "smooth" or "carving" or "sculpture" or "skull" as the clockwork head. The description is "[if we have not examined the clockwork head]You reach down, pick up the smooth wooden object -- it's surprisingly heavy -- and turn it around to discover that it's a richly detailed carving of a human head. You place it on a shelf and examine it more carefully. [paragraph break][end if]The head[if we have examined Progue], which bears a passing resemblance to [the Progue],[end if] is expertly carved from some richly-grained wood. [cwhead2].". After examining clockwork head for the first time: move clockwork head to shelf. To say cwhead2: say "Within the eye sockets are two wooden [o]spheres[x][eye description]. [cwhead3]". [To say cwhead3: say "A large wooden key on the back [if we have not switched on the clockwork head]looks like it [end if][cwhead4]". ] To say cwhead3: say "A large wooden [o]key[x] on the back looks like it [cwhead4]". [To say cwhead4: say "can be wound[if we have switched on the clockwork head] to activate some internal mechanism[end if][cwhead5]".] To say cwhead4: say "can be wound to activate some internal mechanism[cwhead5]". To say cwhead5: say ". Visible joins at [if left ear is part of the clockwork head]each [o]ear[x] indicate they can be turned to rotate the eyes[otherwise]the head's right [o]ear[x] would seem to indicate it can be moved somehow; the left ear, however, is missing[end if]". Rule for printing the name of the clockwork head while listing contents: say "clockwork [o]head[x]". Instead of attacking the clockwork head: say "You smash it against the side of the treehouse, but other than both surfaces acquiring scuffs and dents, not much else results.". The dream-text of clockwork head is "crates of spare wooden eyes, ears, mouths, and clockwork gears". Instead of pushing the clockwork head: say "You shake it back and forth, but it seems quite solid inside, and all the pieces and gizmos well-attached.". Instead of vague locking or vague unlocking the clockwork head: try turning the large wooden key instead. Check opening the clockwork head: say "The workmanship is so fine, you see no sign of any seams." instead.

The eyes are part of the clockwork head. Understand "eye" or "hright eye" or "hleft eye" or "sphere" or "spheres/gear/gears/dowel/dowels/socket/mechanism/sockets" as the eyes. The description is "Each eye seems to be an independent sphere within the head; you can see inside the mechanism just enough to see a series of dowels and tiny wooden gears inside. Within the sockets are the two wooden spheres[eye description]." Instead of turning or pushing eyes, say "You don't seem to be able to make the eyes move directly; hidden cogs resist you.".

The eye-symbols are part of the eyes. Understand "symbol/symbols" as eye-symbols. The printed name is "symbols". The description is "Delicately inscribed, they are in some strange language you've never before seen, with graceful curls and arcs.".

The wooden mouth is part of the clockwork head. The description is "While delicately carved, the mouth seems only able to move up and down, incapable of more precise articulation. Inside you can dimly see something round and concave, partially concealing a complex mechanism of many tiny wooden gears and cogs." Instead of opening or closing wooden mouth: say "You cannot get your fingers in far enough to make it move, and it feels as if the mechanism inside grips it tight, at any rate.".

To say eye description:

if the reading level of the player is language-knowing begin;

say " inscribed with the symbols for '[head consonant][head vowel]'";

otherwise if the reading level of the player is vowel-knowing;

say " inscribed with symbols; the left (on the head's right) shows one of the vowels, while the other symbol must be [if left ear is part of the clockwork head]a consonant[else]an 'L'[end if]";

otherwise;

say " inscribed with two strange symbols";

end if.

Instead of touching or taking the clockwork head when we have not examined the clockwork head: try examining the clockwork head. Instead of taking the clockwork head: say "It's surprisingly heavy, and would be difficult to take down the ladder with you. You may as well leave it here." Instead of touching the clockwork head, say "The detail in the sculpture is remarkable, the wood oiled smooth and warm to your touch." Instead of wearing clockwork head: say "It's solid wood; not something you can wear.".

The clockwork head has a number that varies called consonant. The clockwork head has a number that varies called vowel. The consonant of the clockwork head is 7. The vowel of the clockwork head is 3.

To say head consonant:

let x be the consonant of the clockwork head;

choose row x in Table of Head Consonants;

say sound entry.

To say head vowel:

let x be the vowel of the clockwork head;

choose row x in Table of Head Vowels;

say sound entry.

Table of Head Consonants

sound
"B"
"K"
"D"
"F"
"H"
"J"
"L"
"M"
"N"
"P"
"Kw"
"R"
"S"
"Sh"
"Ch"
"T"
"V"
"W"
"Y"
"Z"

Table of Head Vowels

sound
"ah"
"eh"
"ih"
"oh"
"oo"
"uh"
"aay"
"ee"
"y"

A head ear is a kind of thing. Understand "seam" as a head ear. The description of a head ear is usually "The ear is a remarkable carving, all smooth curves and fine detail[if noun is part of the clockwork head]. Where is it joined to the head is a visible seam[one of], as if the ear can be moved somehow[or], where the ear turns to change the symbol on the adjacent eye[stopping][end if].". Instead of pulling a head ear (called earmo): if earmo is part of clockwork head, say "This one seems stuck fast to the head.".

Instead of turning or pushing a head ear:

if noun is part of the clockwork head begin;

say "The ear rotates as you twist it, and the head's [if noun is right ear]right[otherwise]left[end if] eye moves with it, clunking into place centered on another curious symbol. You quickly rotate the ear backwards and forwards and see that there are [if noun is right ear][the number of rows in Table of Head Vowels][otherwise][the number of rows in Table of Head Consonants][end if] unique symbols it can be set to, before returning it to its original position (number [if noun is right ear][vowel of the clockwork head][otherwise][consonant of the clockwork head][end if]).";

say line break;

speak as the parser "Try typing SET [if left ear is part of clockwork head]LEFT [end if]EAR TO 5, for example, to move the ear more precisely.";

otherwise;

say "The ear is not connected to anything yet.";

end if.

The right ear is a head ear. Understand "hright" as the right ear. The right ear is part of the clockwork head.

The left ear is a head ear. Understand "hleft" as the left ear. The initial appearance of left ear is "Lying on the beach, strewn about with other churned up wreckage and debris, is a small wooden [o]ear[x].". After taking left ear: remove missing-left-ear from play; continue the action.

The missing-left-ear is an undescribed prop in Treehouse. Understand "hleft ear" or "hleft" as missing-left-ear. Instead of doing anything to missing-left-ear: say "You don't see it anywhere.".

Instead of using the left ear in Treehouse, try inserting left ear into clockwork head. Instead of putting the left ear on the clockwork head, try inserting left ear into clockwork head. Instead of tying left ear to clockwork head, try inserting left ear into clockwork head. Understand the commands "join" or "reconnect" or "connect" or "reattach" as "attach". Does the player mean tying the left ear to the clockwork head: it is very likely. Does the player mean inserting the left ear into the clockwork head: it is very likely. Understand "push [a head ear] in/into/to [the clockwork head]" as inserting it into. Understand "fix [the clockwork head]" or "repair [the clockwork head]" as using. Instead of using the clockwork head when left ear is held, try inserting left ear into clockwork head.

Instead of inserting left ear into clockwork head:

move left ear to Treehouse;

now left ear is part of the clockwork head;

say "You carefully line the ear up along the head's left side and push gently. The dowel slides into place and catches with a satisfying snick.".

Understand "set [a head ear] to [number]" as headsetting when location is Treehouse or location is Dream-BigTree. Understand "turn [a head ear] to [number]" as headsetting when location is Treehouse or location is Dream-BigTree. Understand "set to [number]" or "set ear" as a mistake ("[as the parser]You need to be explicit: try SET EAR TO 5, for example.") when location is Treehouse or location is Dream-BigTree.

Headsetting is an action with past participle headset, applying to one thing and one number.

Carry out headsetting:

if noun is the right ear, let q be the number of rows in Table of Head Vowels;

otherwise let q be the number of rows in Table of Head Consonants;

if the number understood < 1 or the number understood > q begin; say "There are only [q] possible positions [the noun] can be set to.";

otherwise if check-right-ear or check-left-ear; say "[The noun] is already set to that symbol.";

otherwise;

if the noun is right ear, now the vowel of clockwork head is the number understood;

otherwise now the consonant of clockwork head is the number understood;

say "[The noun] turns under your hand, catching at each number, until the head's [if noun is right ear]right[otherwise]left[end if] eye shows the proper symbol.";

end if.

To decide whether check-right-ear: if the number understood is the vowel of the clockwork head and the noun is the right ear, decide yes; decide no. To decide whether check-left-ear: if the number understood is the consonant of the clockwork head and the noun is the left ear, decide yes; decide no. Does the player mean doing something to the right ear: it is likely. Does the player mean doing something to the left ear: it is likely.

The large wooden key is part of the clockwork head. Understand "handle" as large wooden key. Instead of turning the clockwork head, try turning the large wooden key. Understand the command "wind" as "turn". The description of large wooden key is "It looks like it winds some mechanism inside the head if you turn it.". Instead of taking or pulling large wooden key, say "It is firmly attached to the mechanism. It looks designed to be turned to wind something inside.".

Head-vowels-learned is a list of numbers that varies. Head-consonants-learned is a list of numbers that varies.

Instead of pulling large wooden key: say "You tug at the key, but it seems firmly attached to the back of the head, useful only for turning.".

Instead of turning or pushing the large wooden key:

say "You wind the large handle several times, then release it. Whirs and thunks come from inside the head. The wooden mouth opens and closes slightly and lets out a mechanical exhalation that, while crude, is clearly distinguishable as a sound: '[head consonant][head vowel]. [head consonant][head vowel]. [head consonant][head vowel].' Then, wound down, the mouth stops moving and the sound fizzles out.";

add the vowel of the clockwork head to head-vowels-learned, if absent;

add the consonant of the clockwork head to head-consonants-learned, if absent;

if the number of entries in head-consonants-learned is 3 and the reading level of the player is not language-knowing begin;

say "[line break]Working systematically, you move through each symbol and slowly begin to match the symbols to the sounds. Years of practice learning unfamiliar scripts have made this an easy game. Within a few hours you feel you've gotten a basic mastery of the symbols, and could sound out, if slowly, something simple written in this script.";

now the reading level of the player is language-knowing;

[pass 120 minutes of time;]

end if;

if the number of entries in head-vowels-learned is 3 and the reading level of the player is uneducated begin;

say "[line break]One at a time, you move through all the symbols around the right ear. Each one, it would seem, is a different vowel sound; the [if left ear is not part of clockwork head]missing [end if]left ear must be used to change the beginning of the sound to something other than 'L.'";

[pass 60 minutes of time;]

if the reading level of the player is uneducated, now the reading level of the player is vowel-knowing;

end if;

rule succeeds.

[An unfortunate side effect of Smarter Parser is that if the player types a command related to the head that isn't recognized, it might print an awkward message about how the player doesn't need to refer to body parts. Avoid this.]

The don't act stupid head rule is listed before the stripping body parts rule in the Smarter Parser rules. A smarter parser rule (this is the don't act stupid head rule):

if location is Treehouse and stripping "(head|eye|eyes|ear|ears|nose)" is fruitful:

change rejected command to "[word number 1 in rejected command] clockwork".