Blue Lacuna — 186 of 467

Aaron A. Reed

Release 4

Section - The Calibration Sequence

Mindlink Calibration is a recurring scene. Mindlink Calibration begins when player is on the chair and mind machinery is uncalibrated and pyramid has power. Mindlink Calibration ends when player is not on the chair or mind machinery is calibrated.

The light-icon is a mindlink-icon. Understand "bright/brightness" as light-icon. The printed name of light-icon is "brightness". The light-icon has a number called counter. The counter of light-icon is 0. The description is "It burns bright and intense, hurting your eyes.". Instead of touching or taking or pushing or pulling light-icon, say "You reach out for it but your hands close on nothingness. You can't feel it but your eyes certainly can see it.". Check attacking light-icon: say "You thrash out at the light but your hands go right through it, feeling nothing." instead.

Every turn when the light-icon is in the icon-case and the icon-case is on-stage:

increase counter of light-icon by 1;

let C be the counter of light-icon;

if C is 1 begin; say "The fuzzy [o]brightness[x] grows stronger and more distinct.";

otherwise if C is 2; say "The [o]brightness[x] gets brighter, shimmering and strengthening in the center of your field of vision.";

otherwise if C is 3; say "Growing brighter and brighter, the [o]brightness[x] in front of you is becoming intense.";

otherwise if C is 4; say "The [o]brightness[x] is becoming blinding, searing and bubbling before your eyes painfully.";

otherwise if C is 5; say "A sun boils before you, radiant [o]brightness[x] burning its way into your retinas; you can hardly stand it.";

otherwise if C is at least 6; say "The [o]brightness[x] is a supernova; you can't take another second. Finally, involuntarily, you blink..."; try silently eye closing;

end if.

Instead of eye closing when the light-icon is in the icon-case and the icon-case is on-stage: say "You close your eyes against the intense light and immediately it extinguishes.[paragraph break]Subtle currents of thought touch your mind. A moment of calculation, of consideration...When you open your eyes again, there are two glowing dots, but smaller, dimmer, and less fuzzy. Each [o]dot[x] flits around your field of vision like fireflies."; remove the light-icon from play; move firefly-icons to icon-case.

Instead of eye closing when Mindlink Calibration is happening and light-icon is not in the icon-case: say "You shut your eyes, but can still see the imagery hovering before you. You open them again." instead. Check sleeping when location is Observatory Exterior: say "[if pyramid is not enclosed by location]The chair looks comfortable, but not that comfortable[else]It's too exposed and windy to sleep up here[end if]" instead.

Some firefly-icons are a mindlink-icon. Understand "firefly" or "fireflies" or "dot/dots" as some firefly-icons. The printed name of some firefly-icons is "tiny firefly dot[if multi]s". Some firefly-icons can be either multi or sole. The firefly-icons are multi. The description is "The [if multi]two tiny dots dip and swarm[otherwise]tiny dot dips and swarms[end if] around in front of you, dodging forward and backward, left and right.". Understand "follow [firefly-icons]" as a mistake ("They flit around but seem to stay within a few feet of you.") when location is Observatory Exterior.

Every turn when firefly-icons are in the icon-case and the icon-case is on-stage:

say "The tiny [if firefly-icons are multi][o]dots[x] bob and weave[otherwise][o]dot[x] bobs and weaves[end if] around in strange, circling patterns.".

Instead of touching or taking some firefly-icons:

if firefly-icons are multi begin; now firefly-icons are sole; say "You reach out your hand towards one of the tiny dots; as you brush against it, it becomes fixed in place for a moment, then vanishes with a thrilling quiver.";

otherwise; remove firefly-icons from play; say "You touch the other dot, and it too freezes, then shimmers out of existence.[paragraph break]Another moment of hesitant thought, and then six glowing spheres appear before you, each a different color: [o]red[x], [o]orange[x], [o]yellow[x], [o]green[x], [o]blue[x], [o]violet[x], a spectrum.[paragraph break]A dull nagging sensation floats through your mind, which throws up words that dance around the central concept as it struggles to comprehend: danger, no, negation, closed, locked, unavailable, unready, impermissible."; now every color-icon is in icon-case; remove unassigned light from play; now counter of light-icon is 0;

end if.

A color-icon is a kind of mindlink-icon. A color-icon has some text called the color text. The red glow is a color-icon. The color text of red glow is "red". The orange glow is a color-icon. The color text of orange glow is "orange". The yellow glow is a color-icon. The color text of yellow glow is "yellow". The green glow is a color-icon. The color text of green glow is "green". The blue glow is a color-icon. The color text of blue glow is "blue". The violet glow is a color-icon. The color text of violet glow is "violet". The unassigned light is an undescribed color-icon. The color text of unassigned light is "unassigned". Does the player mean doing something to the yellow glow: it is likely. [because of the yellow pipe.]

The mind machinery has a color-icon called the no-icon. The mind machinery has a color-icon called the yes-icon. The no-icon of mind machinery is unassigned light. The yes-icon of mind machinery is unassigned light.

Every turn when a color-icon is in the icon-case and the icon-case is on-stage:

say "The [one of]nebulous[or]vague[or]uncertain[in random order] [one of]feeling[or]sensation[in random order] of [feeling-word] [one of]continues[or]keeps[in random order] [one of]floating through your mind[or]running through your thoughts[or]nagging at your brain[in random order]."

To say feeling-word: say "[if the yes-icon of mind machinery is unassigned light and the no-icon of mind machinery is unassigned light][one of]negation[or]danger[or]unavailability[in random order][otherwise][one of]readiness[or]permissiveness[or]acceptability[in random order][end if]".

Instead of doing something to a color-icon when the yes-icon of mind machinery is unassigned light and the no-icon of mind machinery is unassigned light:

say "As you focus your attention on the [noun], it suddenly flares along with the intensity of the sensation of negation, and just as suddenly they both disappear.[paragraph break]A new sensation appears: a prickling feeling of readiness, accessibility, openness, okay-ness.";

now the no-icon of mind machinery is noun;

remove noun from play.

Instead of doing something to a color-icon when the yes-icon of mind machinery is not unassigned light or the no-icon of mind machinery is not unassigned light:

now the yes-icon of mind machinery is noun;

say "You have barely focused on the [noun] when it too suddenly brightens, along with a spike in the feeling of permissibility, of readiness-- then both vanish.[paragraph break]There is a long pause, redolent with concealed calculations.[paragraph break]Then, with a satisfied click of finality, a set of glowing icons appear in front of you. [mindlink summary].";

repeat with trash running through color-icons begin; remove trash from play; end repeat;

finish mindlink calibration.

To finish mindlink calibration:

now mind machinery is calibrated;

move icon-case to chair;

remove light-icon from play;

repeat with trash running through color-icons begin; remove trash from play; end repeat;

remove firefly-icons from play;

move the tree icons to icon-case;

move the globe icon to icon-case;

move the key icon to icon-case;

move the tiny dots to icon-case.