Blue Lacuna — 131 of 467

Section - Landmarks

Carry out landmark-listing when location is regionally in Lacuna:

say "The landmarks you've discovered are: ";

repeat with locale running through visited landmarked rooms regionally in Lacuna begin;

say "[line break] ";

if the landmark name of locale is not "null", say the landmark name of locale; otherwise say locale;

if locale is location, say " (you are here)";

end repeat;

say line break.

The landmark name of Center Beach is "the [d]middle[x] of the beach". Understand "middle/cabin" as Center Beach. Check entering lagoon when Center Beach is visited and location is not Center Beach: try landmark-going Center Beach instead. Understand "lagoon" as Center Beach.

The landmark name of Fork is "the [d]clearing[x] where you first arrived". Understand "clearing" as Fork.

The landmark name of East Marsh is "the [d]marshlands[x]". Understand "marshlands" as East Marsh.

The landmark name of Chairlift Base is "the ropeway base [d]station[x]". Understand "station" as Chairlift Base. Check entering distant-ropeway when Chairlift Base is visited: try landmark-going Chairlift Base instead.

The landmark name of Volcano Floor is "the volcano [d]collapse[x] at the boiler". Understand "collapse" as Volcano Floor. Check entering volcano proper when Volcano Floor is visited: try landmark-going Volcano Floor instead.

The landmark name of Hive Room is "the [d]hive[x]".

The landmark name of Egg Room is "the egg [d]ship[x]". Understand "ship" as Egg Room.

The landmark name of Overhang is "the [d]grotto[x] on the secret island". Understand "grotto" as Overhang.

Instead of landmark-going when location is regionally in Lacuna:

if noun is location, say "You're already here." instead;

if ready to landmark-go begin;

now we-are-landmark-going is true;

unless location is Saddle or location is Atop or location is Top of Cave, now withered vine is closed; [ This prevents going through the ridge, which won't work if the tide is in, but we leave the opposite in so we can get down if we're starting from there. ]

if noun is not a room, try examining noun instead;

while location is not noun and we-are-landmark-going is true begin;

[ now wordgoing-flag is true;]

if location is Ocean Waters, let aim be the best route from the location to noun through visited rooms;

otherwise let aim be the best route from the location to noun through landed visited rooms;

if aim is a direction, let target be the room aim from location;

if aim is not a direction or target is not a room begin;

say "[as the parser]Either you don't know how to get there from here, or something unusual is happening. You'll have to take it one area at a time from here[as normal].";

tidy landmark-go;

stop;

end if;

try silently going aim;

if location is not target or the number of attentive people enclosed by location > 0 begin;

clean up landmark-go;

tidy landmark-go;

stop;

otherwise;

add location to travelogue;

end if;

follow the turn sequence rules;

end while;

tidy landmark-go;

clean up landmark-go;

end if.

To tidy landmark-go: [Lacuna-specific rules after landmark-going.]

if withered vine is unlocked, now withered vine is open.