Blue Lacuna — 114 of 467

Aaron A. Reed

Release 4

Volume - The Tumble (in Lacuna-Homeworld by Blue Lacuna)

Homeworld-Studio is a landmarked room. The landmark name of Homeworld-Studio is "the [d]studio[x]". Understand "studio" as Homeworld-Studio. The prose name of Homeworld-Studio is "your studio". Your Bedroom is a landmarked room. The landmark name of Your bedroom is "your [d]bedroom[x]".

When play begins: now Homeworld-Studio is visited; change matches to seen; change lacuna-canvas to seen. [ This is all to avoid messages that don't make sense if this is someplace the PC is familiar with; the PC knows where the matches and canvas are and how to get to the studio.]

First report going to Homeworld-Studio for the first time: say "(new [d]landmark[x] discovered)[command clarification break]"; now last landmark turn is turn count; continue the action. [ Manually trigger this since the Studio is "visited" already. ]

Rule for printing the name of a Homeworldish room (called area) while remembering: say "in [prose name of area]". Definition: a room is Homeworldish: if it is regionally in Homeworld, yes; no.

Carry out landmark-listing when location is regionally in Homeworld:

if the number of visited landmarked rooms regionally in Homeworld is 0 begin;

say "No landmarks have been discovered in this area.";

stop;

end if;

say "The landmarks you can go to are: ";

repeat with locale running through visited landmarked rooms regionally in Homeworld begin;

say "[line break] ";

if the landmark name of locale is not "null", say the landmark name of locale; otherwise say locale;

if locale is location, say " (you are here)";

end repeat;

say line break;

if tutorial mode is switched on, say tutorial-landmarks2.

Instead of listening when location is regionally in Homeworld: say "The wind that gusted so cold and fierce around the old timbers when you went to bed has vanished in the depths of night. [if location is Your Bedroom]Muffled sound of the banked fire[otherwise if fireplace is raging]The pops and cracks of the raging fire[otherwise]Faint crackling from the banked fire[end if] and the quiet murmur of the stream intrude only faintly on the silence[tutorial-typeverbs].".

Understand "reject/ignore/resist/fight/itch/scratch/stay" as "[scratch]". Understand "[scratch] call" or "[scratch] here" or "[scratch]" as a mistake ("[if The-Path-Of-Love is happening]Now that Rume is gone, there is nothing left for you here[else]You try to block the Call from your mind, but it whispers endlessly, a bottomless spring that teases, summons, beckons, pulls[end if].") when location is regionally in Homeworld.