"Lacuna " by "Aaron A. Reed"

Include Text Variations Improved by Aaron Reed. Include Basic Screen Effects by Emily Short.


Volume One - Custom Code

Chapter - Not For Release

Section - Changing the time rate

Changing the time factor is an action out of world applying to one number. Understand "tf [a number]" as changing the time factor. Carry out changing the time factor: change the time factor to the number understood. Report changing the time factor: say "set to [the number understood]."

Section - Random time

When play begins: let ntod be a random number from 1 to 23; change the time of day to ntod hours after the time of day; now tide counter is a random number from 1 to 1000.

Chapter - Grinform

Section - Eliminate inappropriate noun guessing

Vague unlocking is an action applying to one thing. Understand "unlock [something]" as vague unlocking. Carry out vague unlocking: if noun is lockable, say "You don't have a key."; otherwise say "That's not something you can lock." [Rule for supplying a missing noun when vague unlocking: if a random locked thing is visible, change the noun to a random locked visible thing.]

Rule for supplying a missing second noun: speak as the parser "You'll need to specify what you want to do that with."

Section - Views

[ Here is how views work.

All views are everywhere relevant. (Usually outdoors.) There are three types of descriptions we can get at a view: a look description, a sentence about, and a phrase about. With varying levels of detail. The latter two are used in room descriptions.

]

A view is a kind of backdrop. Instead of doing something other than examining to a view, say "You are too far from [the noun] to do anything but look."



Section - The Parser

Parser style is a number that varies. The parser style is 1.

To say open bracket: (- print "["; -)

To say close bracket: (- print "]"; -)

To say as the parser:
	if parser style is 1, say "[red letters]";
	if parser style is 2, say "[bold type]";
	if parser style is 3, say "[open bracket]".

To say as normal:
	if parser style is 1, say "[default letters]";
	if parser style is 2, say "[roman type]";
	if parser style is 3, say "[close bracket]".

To speak as the parser (str - some text):
	say "[as the parser][str][as normal]".

Before printing a parser error: say "[as the parser]". After printing a parser error: say "[as normal]". 

To set the preferred parser style:
	if the player consents begin;
		speak as the parser "[line break]Excellent. ";
		stop;
	otherwise;
		say "[line break]Oh dear. My apologies. ";
		now the parser style is 2;
		speak as the parser "How about this, then? ";
		say "Was that last phrase highlighted and readable? ";
		if the player consents begin;
			speak as the parser "[line break]Excellent. ";
			stop;
		otherwise;
			say "[line break]You must be using different software than I'm used to, but that's perfectly all right. ";
			now the parser style is 3;
			speak as the parser "I'll just enclose myself in brackets like this so you'll know it's me.";
			say "[paragraph break]";
		end if;
	end if.

When play begins: change the right hand status line to "[approximate time]/[the number of filled rows in Table of Hash Numbers]/[the number of filled rows in Table of Room Description Hashes]"

[When play begins:
	say "Have you played '[story title]' before? ";
	if the player consents begin;
	otherwise;
		say "[line break]Welcome, then. I am the Interpreter. It's my job to help you talk to the Narrator of this interactive story. I'll be in the background most of the time, but ";
		speak as the parser "you'll always know it's me by my colored text";
		say "... that last phrase was in a different color, right? ";
		set the preferred parser style;
		speak as the parser "As I was saying, I'm here to make sure the Narrator understands you. If the Narrator is confused by something you've typed in, I'll try to help interpret what you meant.
			
Mostly, however, you two should be able to get along just fine without my interference. There's really just three things you need to know. Press any key to see them.";
		wait for any key;
		say "[paragraph break]";
		speak as the parser "1) As the Narrator describes the world you're exploring, type any word you see and press enter to focus your attention on that object. If you encounter people to talk with, type HELLO or any word they've said to you (or they're likely to know about) to direct the conversation.
			
2) You can use basic commands like JUMP, CLIMB TREE, READ BOOK, OPEN DOOR, GO WEST, and so on to take an active role in shaping the world around you. Some commands like moving have abbreviations; I'll tell you what these are as they come up.
			
3) Time doesn't pass until you type something, unless you press enter without typing anything. You can type SAVE to save your game and RESTORE to come back to it later. Of course, QUIT will end your game.
			
That's all you need to know to get started. If you ever need me, just type HELP and I'll try to assist you. Have fun!";
	end if;
	pause the game;
	
	stop.]

[When play begins: now the player is in the Great Forest Overlook.]

Section - Ambiance

A region has a table-name called the ambiance table. The ambiance table of a region is usually the Table of No Ambiance. A room has a table-name called the ambiance table. The ambiance table of a room is usually the Table of No Ambiance. 

Table of No Ambiance
value
0

Table of Temp Messages
frequency		text		table			trigger	flag
a frequency	text		a table-name	a thing	a number
with 20 blank rows

Table of Potential Messages
frequency		text		table			trigger	flag
a frequency	text		a table-name	a thing	a number
with 20 blank rows

The frequency is a kind of value. The plural of frequency is frequencies. The frequencies are guaranteed, frequent, common, uncommon, rare, superrare, uberrare, and singular.

To add potential messages from (msg - a table-name), only one:
	repeat through msg begin;
		if there is a start time entry begin;
			if moonrise and start time entry is moonrise, change flag entry to 1;
			if high tide and start time entry is high tide, change flag entry to 1;
			if falling uptide and start time entry is falling uptide, change flag entry to 1;
			if falling downtide and start time entry is falling downtide, change flag entry to 1;
			if moonset and start time entry is moonset, change flag entry to 1;
			if low tide and start time entry is low tide, change flag entry to 1;
			if rising downtide and start time entry is rising downtide, change flag entry to 1;
			if rising uptide and start time entry is rising uptide, change flag entry to 1;							
			if there is an end time entry begin;
				if start time entry <= current and current <= end time entry, change flag entry to 1;
				otherwise if start time entry is current, change flag entry to 1;
			end if;
		otherwise;
			change flag entry to 1;
		end if;
	end repeat;
	sort msg in random order;
	repeat with N running from 1 to the number of rows in msg begin;
		if there is a flag in row N of msg and flag in row N of msg is 1 and the number of blank rows in Table of Potential Messages > 0 begin;
			choose a blank row in Table of Potential Messages;
			change frequency entry to the frequency in row N of msg;
			if there is a text in row N of msg, change text entry to the text in row N of msg; 
			if there is a table in row N of msg, change table entry to the table in row N of msg; 
			if there is a trigger in row N of msg, change trigger entry to the trigger in row N of msg; 
			if only one, let N be the number of rows in msg;
		end if;
	end repeat;
	repeat through msg begin;
		change flag entry to 0;
	end repeat.			
	
To fire one off by frequency from (msg - a table-name), definitely selecting:
	if the number of filled rows in the Table of Temp Messages is 0 begin;
		repeat with N running from 1 to the number of filled rows in msg begin;
			choose a blank row in Table of Temp Messages;
			change frequency entry to the frequency in row N of msg;
			if there is a text in row N of msg, change text entry to the text in row N of msg;
			if there is a table in row N of msg, change table entry to the table in row N of msg;
			if there is a trigger in row N of msg, change trigger entry to the trigger in row N of msg;
		end repeat;
	end if;
	repeat through Table of Temp Messages in frequency order begin;
		if frequency entry is guaranteed, change flag entry to 1;
		if frequency entry is frequent and a random chance of 1 in 2 succeeds, change flag entry to 1;
		if frequency entry is common and a random chance of 1 in 4 succeeds, change flag entry to 1;
		if frequency entry is uncommon and a random chance of 1 in 8 succeeds, change flag entry to 1;
		if frequency entry is rare and a random chance of 1 in 16 succeeds, change flag entry to 1;
		if frequency entry is superrare and a random chance of 1 in 32 succeeds, change flag entry to 1;
		if frequency entry is uberrare and a random chance of 1 in 64 succeeds, change flag entry to 1;
		if frequency entry is singular and a random chance of 1 in 128 succeeds, change flag entry to 1;
	end repeat;
	let success be 0;
	if there is a flag of 1 in Table of Temp Messages begin;
		choose row with a flag of 1 in Table of Temp Messages;
		if there is a text entry begin; now success is 1; say "[text entry][paragraph break]"; end if;
		if there is a table entry begin; let xz be table entry; repeat through Table of Temp Messages begin; blank out the whole row; end repeat; now success is 1; fire one off by frequency from xz, definitely selecting; end if;
		if there is a trigger entry begin; now success is 1; move the trigger entry to location; end if;
	end if;
	if definitely selecting and success is 0 begin;
		repeat through Table of Temp Messages begin;
			if frequency entry is not guaranteed, change frequency entry to the frequency before frequency entry;
		end repeat;
		fire one off by frequency from Table of Temp Messages, definitely selecting;
	end if.

Every turn when the player is awake and we are not going (this is the ambient messages rule):
	Repeat with area running through regions begin;
		if in area and the ambiance table of area is not the Table of No Ambiance, add potential messages from the ambiance table of area;
	end repeat;
	if the ambiance table of location is not the Table of No Ambiance, add potential messages from the ambiance table of location;
	fire one off by frequency from Table of Potential Messages;
	repeat through Table of Potential Messages begin;
		blank out the whole row;
	end repeat;
	repeat through Table of Temp Messages begin;
		blank out the whole row;
	end repeat.


Section - Acknowledging out-of-scope objects

[ This doesn't quite work yet. It breaks if there are objects in the game that can be referred to with the same word, for example. ]

[Include Epistemology by Eric Eve.

Remembering is an action applying to one thing. Understand "examine [any seen thing]" or "x [any seen thing]" or "[any seen thing]" as remembering. Understand "examine [any unseen thing]" or "x [any unseen thing]" or "[any unseen thing]" as a mistake ("You can't see any such thing.").

After deciding the scope of the player while remembering: repeat with the item running through all seen things begin; place the item in scope; end repeat.

A procedural rule while remembering: ignore the can't reach inside rooms rule. A procedural rule while remembering: ignore the basic accessibility rule.

[Check remembering: if the noun is touchable begin; say "Visible!"; try examining the noun instead; end if.]

Report remembering: say "To the best of your knowledge, [the noun] is still at [the location of the noun]."
]

Section - Fallback Actions

A procedural rule: ignore the can't search unless container or supporter rule. Check searching: if the noun is not a container or supporter, try examining the noun instead.
	
Section - Punctuation

Include Punctuation Removal by Emily Short.

After reading a command: remove stray punctuation; if the player's command includes "&", replace the matched text with "and".

Section - Exits

A room has some text called the exits text. The exits text of a room is usually " ". 

Requesting the exits text is an action applying to nothing. Understand "exits" as requesting the exits text. Report requesting the exits text: say "[exits]."

A room has some text called the exits line. The exits line of a room is usually " ".

Definition: a direction is viable if the room it from the location is a room.

Instead of going nowhere, say "You can't move in that direction. [exits]."

To say exits: 
	if the exits text of the location is not " " begin; say "[the exits text of the location]"; 
	otherwise; 
		let count of exits be the number of viable directions; 
		if the count of exits is 0, say "You appear to be trapped in here.";
		if the count of exits is 1, say "From here, the only way out is to [list of viable directions]"; 
		if the count of exits > 1, say "From here, the viable exits are to [list of viable directions]";
	end if;

Section - Help

[Understand "who" or "what" or "when" or "where" or "why" or "how" or "who's" or "what's" or "when's" or "where's" or "why's" or "how's" as "[query]".

Understand "[query] [text]" as a mistake ("[as the parser][story title] understands commands, such as '[command prompt]examine [a random thing that can be seen by the player]', but not questions. For more instructions, type HELP.[as normal]").]

Displaying the basic help text is an action out of world. Understand "help" as displaying the basic help text.

[Before displaying the basic help text for the first time, speak as the parser "Hello there. It's the Interpreter here again. ";]   [This does not work. Why? ]

Carry out displaying the basic help text: speak as the parser "I can show you the OPTIONS for the game, tell you how to INTERACT with it, what VERBS and ABBREViations you can use, how you can get HINTS, or show you the ABOUT text, ACKNOWledgements, or LICENSE. You can also read the PREFACE, or I can give you a PRIMER on interactive fiction in general so you can learn about other games like this.";
	say "[line break]".

After displaying the basic help text for the first time: speak as the parser "[line break]Oh... you can type any of those capitalized words to activate those commands, if that wasn't clear."

Displaying the options text is an action out of world. Understand "options" as displaying the options text. Carry out displaying the options text: speak as the parser "You can save your progress in the game by typing SAVE, and return to the same point later by typing RESTORE. You can QUIT to end the game immediately, or RESTART to begin from the beginning. If you want to take back your last move, type UNDO.

You can adjust the display of messages from the Interpreter (that's me!) by typing INTERP. COMPASS ON or COMPASS OFF will toggle between using relative directions and the more traditional compass directions."

[Displaying the hints text is an action out of world. Understand "hint" or "hints" as displaying the hints text. Carry out displaying the hints text: speak as the parser "In many cases, the best way to make progress in Lacuna is simply to explore more. The scenery changes with both the time of day, the tides, the weather, and of course, you leave your own mark as well. It also may help to sleep on your problem, particularly in a comfy, shady spot.

However, if you find you still need hints, visit http://www.aaronareed.net/lacuna.html to find a proper hint guide, starting with gentle nudges and working up to full solutions."]

Displaying the about text is an action out of world. Understand "about" as displaying the about text. Carry out displaying the about text: speak as the parser "[banner text][paragraph break]Lacuna was first released on January 1, 2007. ~Myst~ and all related characters and concepts are copyright Cyan Worlds, Inc., and are used with permission. This work may not be redistributed or archived without the express permission of Cyan Worlds. Type LICENSE for more information. "

Displaying the preface is an action out of world. Understand "preface" as displaying the preface. Carry out displaying the preface: speak as the parser "My goals with Lacuna were twofold: first, to tell an original, interesting story that would both commemorate and honor the excellent games in the Myst series, and second, to make a text adventure that is every bit as straightforward and invisible to use as the groundbreaking interface to the original Myst.^^~Lacuna~ takes place between the events of Myst III: Exile and Myst IV: Revelation."

Displaying the verbs text is an action out of world. Understand "verbs" as displaying the verbs text. Carry out displaying the verbs text: speak as the parser "Here are some of the verbs that may be useful in this story: TAKE, DROP, LOOK, EXAMINE, TOUCH, PULL, PUSH, CLIMB, GO, OPEN, CLOSE, WAIT, SLEEP, READ, JUMP.

Remember, you can EXAMINE anything by just typing its name, and you can GO any direction by typing it. See also the list of ABBREViations for some other shortcuts."

Section - Using

Understand "use [an edible thing]" as eating.

Understand "use [a wearable thing]" as wearing.

Understand "use [a closed openable container]" as opening. Understand "use [an open openable container]" as closing.

Understand "use [a switched off device]" as switching on.

Understand "use [something]" as using. Using is an action applying to one thing. Carry out using: say "You will have to be more specific about your intentions."

Understand "use [a door]" as opening. Understand "use [an open door]" as entering.

Section - Going Back

The former location is a room that varies.

First carry out going rule: 
    change the former location to the location.

Understand "go back" as retreating. Understand "back" or "return" or "retreat" as retreating.

Retreating is an action applying to nothing.

Carry out retreating: 
    let way be the best route from the location to the former location, using doors; 
    if way is a direction, try going way; 
    otherwise say "You can't see an open way back."

[When play begins: change the former location to Beach.]

Instead of retreating when the former location is the location: say "You haven't gone anywhere yet."

Section - Type nouns alone to examine them

The focus is a thing that varies. The last focus is a thing that varies. The focus count is a number that varies. The focus count is 0.

Before doing anything to a thing (called item):
	now the last focus is the focus;
	now the focus is the item;
	if the last focus is not the focus, now the focus count is 0.

Understand "[a view]" as examining. Understand "[something]" as acting on the focus. 

Acting on the focus is an action applying to one thing.

Carry out acting on the focus:
	increase the focus count by one;
	if focus count is 1, try examining the noun;
	if focus count is 2, try touching the noun;
	if focus count is 3, try taking the noun;
	if focus count is at least 4, try using the noun.

Section - Navigate by room names

Understand "go [any adjacent room]" or "go to [any adjacent room]" or "[any adjacent room]" as going by name. 

Going by name is an action applying to one thing.

Check going by name: 
    if the noun is the location, say "You're already in [the location]." instead; 

Carry out going by name: 
    let aim be the best route from the location to the noun, using doors; 
    if aim is not a direction, say "You can't think how to get there from here." instead; 
    try going aim; 

Understand "[door]" as entering.

Section - Hints (Experimental)

Hinting is an action applying to nothing. Understand "hint" as hinting.

Definition: a thing is qualified if it is a prop or it is an other person or it is a setpiece. Definition: a thing is relevant if it is visible and it is qualified.

Carry out hinting:
	say "[as the parser]You could try ";
	let count be 0;
	let numprops be the number of relevant things in the location;
	let numdirs be the number of viable directions;
	let numpeeps be the number of other people in location;	
	if numprops is greater than 0 begin;
		say "examining [list of relevant things in the location]";
	end if;
	if numdirs is greater than 0 begin;
		if numpeeps is 0 and numprops is not 0, say " or ";
		if numpeeps is not 0 and numprops > 0, say "; ";
		say "going [list of viable directions]";
	end if;
	if numpeeps is greater than 0 begin;
		let numbeats be the number of visible beats;
		if numdirs + numprops is greater than 1, say "; or ";
		if numdirs + numprops is 1, say " or ";
		if a random other person in the location is idle begin;
			say "greeting [the random other person in the location]";
		otherwise;
			say "speaking with [the random other person in the location] about [list of visible beats]";
		end if;
	end if;
	say ".[as normal]".

	
		
		

Section - Conversation Redirection.

Understand "talk to [someone]" or "ask [someone] about [text]" or "tell [someone] about [text]" as a mistake ("[as the parser]To converse with people, you can try saying HELLO, or just type a topic word you think they might be interested in.[as normal]"). 

[This needs to also deal with orders.]


Section - Hello and Goodbye

Definition: a person is other if it is not the player.

Definition: a person is idle if it is not transparent. Definition: a person is conversing if it is transparent.

Understand "hello/hi/greet/greetings" as "[greeting word]". Understand "goodbye/bye/farewell" or "good bye" as "[farewell word]".

Greeting is an action applying to one visible thing. Understand "[greeting word] [someone]" or "say [greeting word] to [someone]" as greeting.

Check greeting (this is the can't greet someone you're talking to rule): if noun is conversing, say "You're already talking to [the noun]." instead.

Carry out greeting: now the noun is transparent.

Report greeting: say "You greet [the noun]."

Vague hello is an action applying to nothing. Understand "[greeting word]" or "say [farewell word]" as vague hello. Check vague hello: if no other people are contained by the location, say "You can't see anyone here to greet." instead. Carry out vague hello: let conversee be a random other person in the location; try greeting conversee instead.

Saying farewell to is an action applying to one visible thing. Understand "[farewell word] [someone]" or "say [farewell word] to [someone]" as saying farewell to.

Check saying farewell to (this is the can't farewell someone you're not talking to rule): if noun is idle, say "You aren't talking to [the noun] right now." instead.

Carry out saying farewell to: now the noun is opaque.

Report saying farewell to: say "You say goodbye to [the noun]."

Vague farewell is an action applying to nothing. Understand "[farewell word]" or "say [farewell word]" as vague farewell. Check vague farewell: if no other conversing people are contained by the location, say "You aren't talking to anyone right now." instead. Carry out vague farewell: let conversee be a random conversing other person in the location; try saying farewell to conversee instead.

After going: now all transparent people are opaque; continue the action.
	



Section - Conversation Beats

[ People carry whatever initial beats they can talk about, but these beats are not available until the person has been greeted. When a beat is spoken, any subsequent beats are activated (by making the parent beat transparent). ]

A beat is a kind of container. Instead of doing anything other than examining or acting on the focus a beat, say "That doesn't make sense." A beat is always closed, unopenable and undescribed. A beat has some text called the followup. The followup of a beat is usually " ".

Understand "[a visible beat]" as examining.

After examining a beat (called b): now b is transparent; continue the action.

Before examining a beat (called b) (this is the can't converse if haven't greeted rule):
	if b is carried by an idle person, say "You aren't speaking to anyone right now." instead.
	
Before examining a beat (called b) (this is the can't converse if no people are present rule):
	if no other people are contained by the location, say "You aren't speaking to anyone right now (no people here)." instead.

Before examining a beat (called b) (this is the say followup text rule):
	if we have examined b and the followup of b is not " " begin;
		say "[the followup of b][paragraph break]" instead;
	otherwise;
		continue the action;
	end if;
		





Chapter - Lacuna Specific Code

Section - Wishlist

[ Shouting (Scream, Yell) -- useful to attract Progue? ]


Section 1 - Improved Status Line 

To turn screen black: 
    say white letters; 
    turn the background black; 
    clear the screen; 
    leave space; 
     
To turn screen white: 
    turn the background white; 
    say black letters; 
    clear the screen; 
    leave space. 

To leave space: 
    say paragraph break; 
    say paragraph break; 
    say paragraph break; 
    say paragraph break. 

To say world:
	if location is in Treeworld, say "Treeworld";
	otherwise say "Lacuna".

To say weather:
	if raining begin; say "Raining";
	otherwise; if weather state is gathering clouds or weather state is dispersing clouds, say "Cloudy";
	otherwise say "Clear";
	end if.
	 
     
Table of Fancy Status
left	central	right
" [location]"	 ""	 "[top rose]"
" [approximate time] [tide counter]"	 "" 	 "[middle rose]"
" 'HELP' summons the Interpreter."		""	"[bottom rose]"

Table of Normal Status
left	central	right
" [world]"	""	"[location]"
" [approximate time]"	""	"[weather]"
" Nearby: [exits line of the location]"	""	""

To say red reverse: 
    turn the background red. 
     
To say black reverse: 
    turn the background black. 
     
To say white reverse: 
    turn the background white. 

Definition: a room is discernible: 
    if it is lit, yes; 
    if in darkness, no; 
    yes. 

To say top rose: 
    let place be the room up from the location; 
    if the place is a discernible room, say "[if the place is unvisited][red reverse][end if]U [default letters]"; otherwise say "  "; 
    let place be the room northwest from the location; 
    if place is a discernible room, say "[if the place is unvisited][red reverse][end if]NW[default letters]"; otherwise say " "; 
    let place be the room north from the location; 
    if place is a discernible room, say "[if the place is unvisited][red reverse][end if] N [default letters]"; otherwise say " "; 
    let place be the room northeast from the location; 
    if place is a discernible room, say "[if the place is unvisited][red reverse][end if]NE[default letters]"; otherwise say " ". 
     
To say middle rose: 
    say " "; 
    let place be the room west from the location; 
    if place is a discernible room, say "[if the place is unvisited][red reverse][end if]W [default letters]"; otherwise say " "; 
    say " - "; 
    let place be the room east from the location; 
    if place is a discernible room, say "[if the place is unvisited][red reverse][end if] E[default letters]"; otherwise say " ". 
     
To say bottom rose: 
    let place be the room down from the location; 
    if the place is a discernible room, say "[if the place is unvisited][red reverse][end if]D [default letters]"; otherwise say "  "; 
    let place be the room southwest from the location; 
    if place is a discernible room, say "[if the place is unvisited][red reverse][end if]SW[default letters]"; otherwise say " "; 
    let place be the room south from the location; 
    if place is a discernible room, say "[if the place is unvisited][red reverse][end if] S [default letters]"; otherwise say " "; 
    let place be the room southeast from the location; 
    if place is a discernible room, say "[if the place is unvisited][red reverse][end if]SE[default letters]"; otherwise say " ". 

Showing the compass rose is a number that varies. Showing the compass rose is 0.

Changing the compass rose is an action out of world applying to nothing. Understand "rose" as changing the compass rose. Carry out changing the compass rose: if showing the compass rose is 0, now showing the compass rose is 1; otherwise now showing the compass rose is 0.
     
Rule for constructing the status line: 
	if showing the compass rose is 1 begin;
		fill status bar with Table of Fancy Status; 
		say default letters; 
	otherwise;
		fill status bar with Table of Normal Status;
		say default letters;
	end if;
	rule succeeds. 

Section - Directions

Using compass directions is a number that varies. Using compass directions is 0.

Changing the compass is an action out of world, applying to nothing. Understand "compass" as changing the compass. Carry out changing the compass: if using compass directions is 1, now using compass directions is 0; otherwise now using compass directions is 1.

To decide whether dir: if using compass directions is 1, decide yes; decide no. To decide whether not dir: if dir, decide no; decide yes.

Section - Swimming

Swimming in is an action applying to one visible thing. Understand "swim in [something]" as swimming in.

Carry out swimming in: say "You don't see a good place to swim here."

Vague swimming is an action applying to nothing. Understand "swim" or "go swimming" as vague swimming.

Carry out vague swimming: say "You don't see a good place to swim here."

Section - Visibility

Sightlining relates various views to various regions.

The verb to sightline (he sightlines, they sightline, he sightlined, it is sightlined, he is sightlining) implies the sightlining relation.

The verb to be visible from implies the sightlining relation.

After deciding the scope of the player: repeat with thingie running through views begin; place thingie in scope; end repeat.

[ This doesn't work. With the below commented out, the effect is as if all views are visible from everywhere. ]

[Before examining a view (called item):
	let unseen be 1;
	if item is in the location, let unseen be 0;
	repeat with area running through regions begin;
		say "[area]";
		if the player is in area and item is visible from area, now unseen is 0;
		say "([unseen])";
	end repeat;
	if unseen is 1, say "You can't see that from here." instead.]

A room has a number called x. A room has a number called y. A view has a number called x. A view has a number called y. The x of a room is usually 0. The y of a room is usually 0. The x of a view is usually 0. The y of a view is usually 0.

Distance is a kind of value. The distances are near, medium, far, and distant. A view has a distance. The distance of a view is usually far.

To decide which distance is the range of (poi - a view): 
	let a be x of poi minus x of location;
	let b be y of poi minus y of location;
	if a * b is 0, decide on far;
	if a < 0, let a be a * -1;
	if b < 0, let b be b * -1;
	if a > b, let c be b; otherwise let c be a;
	let d be a + b - c / 2;
	if d < 10, decide on near;
	if d < 25, decide on medium;
	if d < 50, decide on far;
	decide on distant.
	

Section - Time of Day

Procedural rule: substitute the fast time rule for the advance time rule.

The tide counter is a number that varies. The tide counter is 200.

The time factor is a number that varies. The time factor is 11.

This is the fast time rule:
	increase the turn count by 1;
	change the time of day to the time of day + time factor minutes;
	change the tide counter to the tide counter + time factor;
	if the tide counter is greater than 1100, change the tide counter to the tide counter minus 1100.



The interval is a kind of value. The intervals are dawn, sunrise, morning, midmorning, midday, afternoon, evening, sunset, twilight, night, moonrise, high tide, falling uptide, falling downtide, moonset, low tide, rising downtide, and rising uptide.

To decide which interval is current: if dawn then decide on dawn; if sunrise then decide on sunrise; if morning then decide on morning; if midmorning then decide on midmorning; if midday then decide on midday; if afternoon then decide on afternoon; if evening then decide on evening; if sunset then decide on sunset; if twilight then decide on twilight; if night then decide on night.

To decide whether sunup: if night or dawn or twilight, decide no; decide yes.

To decide whether sundown: if sunup, decide no; decide yes.

To decide whether tideout: if low tide or rising downtide or falling downtide, decide yes; decide no.

To decide whether tidein: if tideout then decide no; decide yes.

To decide whether moonrise: if the tide counter > 0 and the tide counter < 10 then decide yes; decide no.

To decide whether high tide: if the tide counter >= 10 and the tide counter < 183 then decide yes; decide no.

To decide whether falling uptide: if the tide counter >= 183 and the tide counter < 366 then decide yes; decide no.

To decide whether falling downtide: if the tide counter >= 366 and the tide counter < 549 then decide yes; decide no.

To decide whether moonset: if the tide counter >= 549 and the tide counter < 559 then decide yes; decide no.

To decide whether low tide: if the tide counter >= 559 and the tide counter < 732 then decide yes; decide no.

To decide whether rising downtide: if the tide counter >= 732 and the tide counter < 915 then decide yes; decide no.

To decide whether rising uptide: if the tide counter >= 915 and the tide counter <= 1100 then decide yes; decide no.

To decide whether dawn: if it is before 5:01 AM then decide yes; decide no.

To decide whether sunrise: if it is after 5:00 AM and it is before 5:06 AM then decide yes; decide no.

To decide whether morning: if it is after 5:05 AM and it is before 7:01 AM then decide yes; decide no.

To decide whether midmorning: if it is after 7:00 AM and it is before 10:31 AM then decide yes; decide no.

To decide whether midday: if it is after 10:30 AM and it is before 2:31 PM then decide yes; decide no.

To decide whether afternoon: if it is after 2:30 PM and it is before 5:31 PM then decide yes; decide no.

To decide whether evening: if it is after 5:30 PM and it is before 7:01 PM then decide yes; decide no.

To decide whether sunset: if it is after 7:00 PM and it is before 7:06 PM then decide yes; decide no.

To decide whether twilight: if it is after 7:05 PM and it is before 8:01 PM then decide yes; decide no.

To decide whether night: if it is after 8:00 PM then decide yes; decide no.

To decide whether day: if night or twilight or dawn, decide no; decide yes.

To decide whether moonup: if the moon is visible, decide yes; decide no. To decide whether moondown: if the moon is visible, decide no; decide yes.

To decide whether sunup: if sunrise or morning or midmorning or midday or afternoon or evening or sunset, decide yes; decide no. To decide whether sundown: if twilight or dawn or night, decide yes; decide no.

Section - Items

A prop is a kind of thing. A prop is usually fixed in place and undescribed. Instead of taking a prop, say "You'd rather not carry that around."

A setpiece is a kind of thing. A setpiece is usually fixed in place and undescribed. 

A set dressing is a kind of prop. After going: repeat with item running through set dressings in the former location begin; remove item from play; end repeat; continue the action.

Section - The Heavens

A heavenly body is a kind of backdrop.  Instead of doing something other than examining a heavenly body, say "Would that you could."

Every turn when the player is awake and the player is in Outside (this is the motions of the heavenly spheres rule):
	if sunup begin; move the sun to Outdoors; remove the stars from play; remove the galaxy from play; end if;
	if sundown begin; remove the sun from play; move the stars to Outdoors; move the galaxy to Outdoors; end if;
	if the tide counter > 550, remove the moon from play;
	if the tide counter < 550, move the moon to Outdoors.

The stars are a heavenly body. The description is "There must be millions of them, sparkling above you and lorded over by the great galaxy running through them all."

The great galaxy is a heavenly body. The description is "Stretching nearly from horizon to horizon, the galaxy is rich with a million tiny dots finer than dust grains, streaked through with every shade of orange-tinted silver you can imagine."

Phase is a kind of value. The phases are new, crescent, half, three quarter, and full.

The moon is a heavenly body.  The moon is in Outdoors. The moon has a phase. The description of the moon is "It's about twice as large as the one you're used to, and glows a ghostly pink, streaked through with shades of orange. Hanging [moon location], it's currently [long moon description]."

To say moon location: if tide counter < 50, say "just above the eastern horizon"; if tide counter >= 50 and tide counter < 140, say "low in the eastern sky"; if tide counter >= 140 and tide counter < 230, say "high in the eastern sky"; if tide counter >= 230 and tide counter < 320, say "directly overhead"; if tide counter >= 320 and tide counter < 410, say "high in the western sky"; if tide counter >= 410 and tide counter < 500, say "low in the western sky"; if tide counter >= 500, say "on the edge of the western horizon".

The sun is a heavenly body. The sun is in Outdoors. The description of the sun is "[if sunrise]The sun creeps over the ocean with yellow gold fire, lighting up a brilliant streak in the waves[end if][if morning]The morning sun beams brightly down on you, burning away the faint chill of night[end if][if midmorning]The sun is high in the eastern sky. It's beginning to get hot[end if][if midday]The sun is directly overhead, bright, and scorching[end if][if afternoon]High in the western sky, the sun is bright and hot[end if][if evening]Colors begin to deepen as the sun approaches the western horizon[end if][if sunset]The sunset over the waves is spectacular[end if]." Understand "sunrise" and "sunset" as the sun.

To calculate moon phase:
	let the_time be the hours part of time of day * 60;
	let the_time be the_time plus the minutes part of time of day;
	let offset-a be tide counter * 10 / 33;
	let offset-b be the_time * 10 / 40;
	let offset be offset-a minus offset-b;
	if offset > 180, change offset to offset - 360;
	if offset < -180, change offset to offset + 360;
	if offset < 0, change offset to offset * -1;
	if offset <= 30, now the phase of the moon is new;
	if offset > 30 and offset < 70, now the phase of the moon is crescent;
	if offset >= 70 and offset < 112, now the phase of the moon is half;
	if offset >= 112 and offset < 157, now the phase of the moon is three quarter;
	if offset >= 157, now the phase of the moon is full.
	
To say moon description: calculate moon phase; say "[if phase of moon is new]sliver of a[end if][if phase of moon is crescent]crescent[end if][if phase of moon is half]half[end if][if phase of moon is three quarter]three quarter[end if][if phase of moon is full]full[end if]".

To say long moon description: calculate moon phase; say "[if phase of moon is new]a barely visible splinter against the blaze of the sun[end if][if phase of moon is crescent]a rounded crescent, being chased by the sun[end if][if phase of moon is half]half full, the dark half faintly visible[end if][if phase of moon is three quarter]three quarters full[end if][if phase of moon is full]full and bright[end if]".

Section - Weather

[ This is very simple. Each afternoon there is a certain chance that there
  will be a storm. This lasts the whole afternoon (but only the afternoon)
  and is divided into three phases: gathering clouds, storm, dispersing clouds. ]

Weather status is a kind of value. The weather statuses are undecided, decided to rain, decided not to rain, gathering clouds, raining, and dispersing clouds. The weather state is a weather status that varies. The last weather state is a weather status that varies. The weather state is undecided. The last weather state is undecided.

Every turn when afternoon and weather state is undecided (this is the deciding on the weather rule):
	if a random chance of 1 in 1 succeeds, now the weather state is decided to rain;
	otherwise now the weather state is decided not to rain.
	
Every turn when the player is in Outdoors and the player is awake and the weather state is not undecided and the weather state is not decided not to rain (this is the rainstorm computations rule):
	if it is after 2:30 PM and it is before 3:31 PM begin;
		if weather state is not gathering clouds begin;
			now weather state is gathering clouds;
			say "The sky overhead is beginning to fill up with dark clouds.";
			move rain clouds to Outdoors;
		otherwise; add potential messages from the Table of Gathering Clouds, only one;
		end if;
	end if;
	if it is after 3:30 PM and it is before 4:31 PM begin;
		if weather state is not raining begin;
			[ this doesn't work if we've been waiting inside. ]
			now weather state is raining;
			move rain clouds to Outdoors; move lightning to Outdoors;
			say "With a crash of thunder, raindrops begin to fall. A moment later you are in a downpour.";
		otherwise; add potential messages from the Table of Rainstorms, only one;
		end if;
	end if;
	if it is after 4:30 PM and it is before 5:31 PM begin;
		if weather state is not dispersing clouds begin;
			now weather state is dispersing clouds;
			move rain clouds to Outdoors; move lightning to Outdoors;
			say "The rain peters out and the clouds begin to disperse.";
		otherwise; add potential messages from the Table of Dispersing Clouds, only one;
		end if;
	end if;
	if it is after 5:30 PM begin;
		remove rain clouds from play; remove lightning from play;
		now weather state is undecided;
		now last weather state is dispersing clouds; 
	end if.

Rain clouds are a view. The description is "[if weather state is gathering clouds]They are flying in rapidly from the east, black and ominous[end if][if weather state is raining]Buckets of warm rain pour down from the black thunderheads above[end if][if weather state is dispersing clouds]The clouds are quickly being carried off westward, revealing a reddish-orange evening sky[end if]." Understand "cloud" or "storm" as the rain clouds.

Lightning is a view. The description is "Only a purple blotch over your vision, now."

Every turn when night (this is the finishing up the weather business rule):
	now weather state is undecided;
	now last weather state is undecided.
	
To decide whether rained: if last weather state is dispersing clouds, decide yes; decide no.

To decide whether didnt rain: if rained or raining, decide no; decide yes.

To decide whether raining: if the weather state is raining, decide yes; decide no. To decide whether not raining: if raining, decide no; decide yes.

Table of Gathering Clouds
frequency	start time	end time	text	table		trigger	flag	
frequent	an interval	an interval	"Heavy rain clouds are beginning to gather overhead."

Table of Rainstorms
frequency	start time	end time	text	table		trigger	flag	
frequent	an interval	an interval	"Lightning flashes and thunder rumbles as the storm continues."

Table of Dispersing Clouds
frequency	start time	end time	text	table		trigger	flag	
frequent	an interval	an interval	"The rain clouds continue to slowly disperse."

Section - Sleeping

A person can be either asleep or awake. A person is usually awake. The player is awake.

[Instead of sleeping in the Jetty, say "What, on these sandpapery boards?"]

The player has a number called the sleep debt. The sleep debt of the player is 600.

Every turn when the player is awake (this is the sleep debt rule):
	increase the sleep debt of the player by time factor;
	if the sleep debt of the player > 1400, add potential messages from the Table of Sleepy Messages;
	if the sleep debt of the player > 2000, add potential messages from the Table of Really Sleepy Messages.

Table of Sleepy Messages
frequency	start time	end time	text	table		trigger	flag	
rare	--	--	"You stifle a yawn."
rare	--	--	"You rub your eyes... you're getting awful tired."
rare	--	--	"You're starting to feel pretty tired."

Table of Really Sleepy Messages
frequency	start time	end time	text	table		trigger	flag	
uncommon		--	--	"You blink away haze from your eyes blearily. You aren't sure how much longer you can stay awake."
uncommon		--	--	"You feel dead on your feet. You really need to get some sleep."
uncommon		--	--	"You are dead tired. Better find someplace to rest."

Check sleeping (this is the can't sleep if not tired enough rule):
	if the sleep debt of the player < 720, say "You aren't really feeling sleepy yet." instead.

A procedural rule: ignore the block sleeping rule.
	
Carry out sleeping:
	if the sleep debt of the player < 720, let sleeptime be a random number between 60 and 180;
	otherwise let sleeptime be the sleep debt of the player / 2;
	if sleeptime > 720 then change sleeptime to 660 plus a random number between 1 and 120;
	say "(sleeptime: [sleeptime])";
	say "Yawning, you kick off your shoes and settle in for a good rest.";
	now the player is asleep;
	let wakeup time be sleeptime minutes after the time of day;
	if wakeup time is after 1:00 AM and wakeup time is before 3:59 AM, change wakeup time to a random number between 1 and 60 minutes after 4:00 AM; 
	say "(wakeup time: [wakeup time])";
	if the time of day is after wakeup time begin;
		while the time of day is before time factor minutes before 3:59 AM repeatedly follow the turn sequence rules;
		follow the turn sequence rules;
	end if;
	while the time of day is before wakeup time repeatedly follow the turn sequence rules;
	change the sleep debt of the player to the sleep debt of the player - (sleeptime * 2);
	if the sleep debt of the player > 400, now the sleep debt of the player is a random number between 1 and 400;
	now the player is awake;
	say "Feeling refreshed and regenerated, you rise to your feet. (slept for [sleeptime] minutes; sleep debt now [sleep debt of the player]".

Section - Paying Attention

[This is going to be a big performance hit. We'll wait to active it until we're sure we need it.]

[Every thing has a number called attention. The attention of a thing is usually 0.

Every turn when the player is awake (this is the keeping track of attention rule):
	let x be 0;
	if we are examining or touching or taking or pushing or pulling begin;
		let x be 5;
		if the noun is not scenery and the noun is not a backdrop, now x is 10;
		if the noun is a person, now x is 30;
		now the attention of the noun is the attention of the noun plus (time factor * x);
	end if;
	repeat with item running through all visible things begin;
		let x be 1;
		if item is not scenery and item is not a backdrop, now x is 2;
		if item is a person, now x is 5;
		now the attention of item is the attention of item plus (time factor * x);
	end repeat.
	
After sleeping (this is the reduce the attention number of everything rule):
	repeat with item running through things begin;
		now the attention of item is the attention of item / 5;
	end repeat.

After 	printing the name of a visible thing (called the item): say "([attention of item])";

Definition: a thing is important if its attention is 200 or more.

Dreaming is an action applying to nothing. Understand "dream" as dreaming. To carry out dreaming: repeat with item running through important things begin; say "[the item] ([the attention of the item]) -- "; end repeat.]

Section - Random synonyms etc.

Understand the command "kick" as "attack".

Understand the command "wave" as something new.	
	

Section - Complex Messages

To say time of day ambiance: say "Wind gusts heavily through your hair".



To say light source: 
	if sunup begin; say "sun";
	otherwise;
		if moonup, say "moonlight";
		otherwise say "stars";
	end if.

To say approximate time: say "[if dawn]Dawn[end if][if sunrise]Sunrise[end if][if morning]Morning[end if][if midmorning]Midmorning[end if][if midday]Midday[end if][if afternoon]Afternoon[end if][if evening]Evening[end if][if sunset]Sunset[end if][if twilight]Twilight[end if][if night]Night[end if]".


Section - Room Descriptions

Describing is an action applying to one thing. [Instead of looking: say "[the name of the location]"; try describing the location. ][Report describing: say "No description!";]

Procedural rule: substitute the describing the room rule for the room description body text rule. 

This is the describing the room rule: try describing the location.

[After looking, say "[line break]".]

To process description table (tab - a table-name) with (r - a number):
	if r is 98, say ", ";
	if r is 99, say ". ";
	if r is at most 97 begin;
		choose row r in tab;
		say "[text entry]";
	end if.	
	
To do the room description dance with (t1 - a table-name) and (t2 - a table-name):
	repeat through t1 begin;
		if time entry is current begin;
			if there is a s1 entry, process description table t2 with s1 entry;
			if there is a s2 entry, process description table t2 with s2 entry;
			if there is a s3 entry, process description table t2 with s3 entry;
			if there is a s4 entry, process description table t2 with s4 entry;
			if there is a s5 entry, process description table t2 with s5 entry;
			if there is a s6 entry, process description table t2 with s6 entry;
			if there is a s7 entry, process description table t2 with s7 entry;
			if there is a s8 entry, process description table t2 with s8 entry;
			if there is a s9 entry, process description table t2 with s9 entry;
			if there is a s10 entry, process description table t2 with s10 entry;						
			say "[paragraph break]";
			stop;
		end if;
	end repeat.	


Section - Taking Shelter From

Taking shelter from is an action applying to one topic. Understand "take shelter [text]" or "hide under [text]" as taking shelter from.

Check taking shelter from (this is the can't take shelter when no reason rule): if weather state is not raining, say "There's nothing you need to take shelter from right now." instead.

Report taking shelter from:
	if the location contains a setpiece, say "You huddle in the leeward side of [the random setpiece in the location], managing to avoid most of the downpour.";
	otherwise say "You take shelter as best you can from the rain.".
	

Volume - Conversation System

[ NOTES:
	This conversation system is designed for situations in which there is never more than a single NPC in the location at any given time. 
]


[ The Table of Recognized Words stores a series of words the player might use to talk, along with the beats they are associated with, and an expiration date. As each beat is spoken, new words are added to this table dynamically. Each round, the fuse is shortened, and expired words are removed from the table. ]

Table of Recognized Words
topic		beatr		fuser
a topic	a beat	a number
with 25 blank rows

Part - Definitions

Chapter - Correcting Input

Instead of asking someone to try doing something, try correct conversing. Instead of asking anyone about anything, try correct conversing. Instead of telling anyone about anything, try correct conversing. Understand "talk to [text]" or "talk about [text]" or "ask about [text]" or "tell about [text]" as a mistake ("[correct conv]").

Correct conversing is an action out of world. Carry out correct conversing: say "[correct conv]". To say correct conv: say "To speak with people, try saying HELLO, and then using single keywords to direct the conversation. Type HINTING ON to view some (but not all) of the things you might speak about on any turn."



Chapter - Hello and Goodbye

A person can be idle or attentive. A person is usually idle.

Definition: a person is other if it is not the player. Definition: a person is conversing if it is other and attentive.

Understand "hello/hi/greet/greetings" as "[greeting word]". Understand "goodbye/bye/farewell" or "good bye" as "[farewell word]".

Greeting is an action applying to one visible thing. Understand "[greeting word] [someone]" or "say [greeting word] to [someone]" as greeting.

Check greeting (this is the can't greet someone you're talking to rule): if noun is attentive, say "You're already talking to [the noun]." instead. 

Carry out greeting: now the noun is attentive.

Report greeting: say "You greet [the noun]."

Vague hello is an action applying to nothing. Understand "[greeting word]" or "say [greeting word]" as vague hello. Check vague hello: if no other people are contained by the location, say "You can't see anyone here to greet." instead. Carry out vague hello: let conversee be a random other person in the location; try greeting conversee instead.

Saying farewell to is an action applying to one visible thing. Understand "[farewell word] [someone]" or "say [farewell word] to [someone]" as saying farewell to.

Check saying farewell to (this is the can't farewell someone you're not talking to rule): if noun is idle, say "You aren't talking to [the noun] right now." instead.

Carry out saying farewell to: now the noun is idle; now the boredom counter of the noun is 0.

Report saying farewell to: say "You say goodbye to [the noun]."

Vague farewell is an action applying to nothing. Understand "[farewell word]" or "say [farewell word]" as vague farewell. Check vague farewell: if no other attentive people are contained by the location, say "You aren't talking to anyone right now." instead. Carry out vague farewell: let conversee be a random attentive other person in the location; try saying farewell to conversee instead.

After going: now all attentive people are idle; continue the action.

Chapter - Yes, No, Maybe

Saying maybe is an action applying to nothing. Understand "maybe" or "shrug" as saying maybe. To carry out saying maybe: say "That was a rhetorical question."

Saying neither is an action applying to nothing. Understand "neither" or "none" as saying neither. To carry out saying neither: say "That was a rhetorical question."

[ Saying yes and saying no are defined by default in Inform 7.]

Chapter - Beats and Threads

A beat is a kind of thing. A beat has some text called the reaction. A beat has some text called the words line. A beat is either available or unavailable. A beat is usually available. A beat is either terminal or nonsequitous. A beat is usually terminal. A beat is either repeatable or unrepeatable. A beat is usually unrepeatable. Substantiality is a kind of value. The substantialities are ephemeral, semiphemeral, and substantial. A beat has a substantiality. A beat is usually substantial. [ This is the atom of a conversation: an individual point of discussion, made available to the player by defined keywords. A beat can be made unavailable if the option to discuss it has expired. A nonsequitous beat will jar the NPC if the subject is changed away from it. A repeatable beat can be said multiple times. An ephemeral beat does not change the records for last beat spoken; a semiphemeral beat does, but keeps the old word line. ]

The last beat is a beat that varies. The penultimate beat is a beat that varies. The next beat is a beat that varies. Silence is a beat. The last beat is silence. The next beat is silence. The penultimate beat is silence. [ Keeps track of the last thing said, and, sometimes, a queued response for the NPC to say. ]

A person has a beat called unavailable-beat. The unavailable-beat of a person is usually Silence. [ Sets what the NPC should do if the player tries to refer to a no-longer-relevant beat. ]

Suggesting relates various beats to one beat. The verb to suggest (he suggests, they suggest, he suggested, it is suggested) implies the suggesting relation. [ A throughline should be defined for every beat, which tells the NPC how to continue the conversation if the player is silent. ] 

Replacing relates various beats to various beats. The verb to replace (he replaces, they replace, he replaced, it is replaced) implies the replacing relation. [ An individual beat may only be seen once per game (unless it is repeatable). Replacing explains which beat should be used if the beat requested has already been said. If none is specified, the character will reply with a generic "not interested" message. ]

A thread is a kind of container. [ A thread is a group of related beats, all about the same general subject. They are tied together via the suggesting and replacing relations. ]

Adjoining relates threads to each other. The verb to adjoin (he adjoins, they adjoin, he adjoined, it is adjoined) implies the adjoining relation. [ Threads in a conversation can be connected to each other. This allows the NPC to know whether the conversation is naturally flowing or abruptly jumping to a new idea. ]

A procedural rule (this is the ignoring basic accessibility for beats rule): if the noun is a beat, ignore the basic accessibility rule. Rule for deciding the scope of a beat (called subject): if subject is available, decide yes; decide no. [Beats do not conform to the usual scope rules. ]

Part - Routines

Chapter - Conversation Actions

Section - Discussing

Discussing is an action with past participle discussed, applying to one thing. [ Discussing is the conversation verb in this system. ]

Check discussing: if a random other person in the location is idle begin; say "You aren't talking to anyone right now."; stop the action; end if.

Carry out discussing: 
	if next beat is noun, now next beat is silence;
	let subject be noun;
	if we have discussed subject and subject is unrepeatable begin;
		if a beat (called new subject) replaces subject, try discussing new subject instead;
		otherwise try exhausting subject instead;
	end if;
	if noun is substantial or semiphemeral begin; now penultimate beat is last beat; now last beat is subject; end if;
	say "[reaction of subject][paragraph break]";
	now discussed_this_turn is discussed_this_turn + 1.

Section - Exhausting

Exhausting is an action applying to one thing. [ Exhausting happens when the NPC has nothing else to say about a given topic. ]

Carry out exhausting: say "'I have nothing else to say about that,' [the random other person in the location] says." [ NPCs should replace this with a more personable message, preferable randomized. ]

After exhausting: try discussing a random beat suggested by last beat.

Section - Changing the Subject

Changing the subject is an action applying to one thing. Carry out changing the subject: now last beat is noun; try discussing noun. [ Changing the subject is triggered whenever the player discusses a nonsequitous beat that is not in an adjacent thread. Unless an NPC provides behavior for this verb, conversation carries on as normal. ]

Before discussing when the last beat is nonsequitous and a random thing (called Thing1) contains last beat and a random thing (called Thing2) contains noun and the noun is not contained by Thing1 and Thing1 does not adjoin Thing2 (this is the check for abrupt change of subject rule):
	try changing the subject noun instead.

Section - Pissing Off

Pissing off is an action applying to one thing. Before pissing off: try silently saying farewell to noun. [ An NPC is pissed off when they are asked about the same thing repeatedly, or asked about multiple unavailable things in a row. ]

Instead of exhausting for more than the second time: let subject be a random other person in the location; try pissing off subject instead.

Section - Getting Bored

Getting bored is an action applying to one thing. Before getting bored: try silently saying farewell to noun. [ An NPC gets bored if the player has not spoken for several turns. ]

A person has a number called the boredom counter. The boredom counter of a person is usually 0.

Section - Not Understanding

[ This is not a verb, as we always cause the conversation to fail at the parser level, not the NPC level. This prevents NPCs from professing ignorance over things the player expects them to know about. ]

Rule for printing a parser error when parser error is didn't understand and a random other person in the location is attentive: say "Sorry, that's not something I know how to ask [random other person in the location] about. Try using a different word." instead.



Chapter - Single Word Conversation

Discussed_this_turn is a number that varies. Discussed_this_turn is 0. [ This is used to ensure the NPC doesn't talk over himself. ]
	
After reading a command when a random other person in the location is attentive:
	let joe be a random other attentive person in the location;
	let foundany be 0;
	sort the Table of Recognized Words in fuser order;
	repeat through the Table of Recognized Words begin;
		if the player's command matches topic entry begin;
			if beatr entry is available begin;
				try discussing beatr entry;
				follow the turn sequence rules;
				rule succeeds;
			otherwise;
				now foundany is 1;
				blank out the whole row;
			end if;
		end if;
	end repeat;
	if foundany is 1, try discussing unavailable-beat of joe;
	continue the action.
		
Every turn when discussed_this_turn is 0 and an attentive person is visible and the last beat suggests a beat (called new subject) (this is the checking if the NPC has anything else to say rule):
	now new subject is available;
	try discussing new subject.


Chapter - Bookkeeping

To update the word table:
	let N be the number of rows in the Table of Recognized Words;
	sort the Table of Recognized Words in fuser order;
	choose row N in the Table of Recognized Words;
	let M be 0;
	while there is a fuser entry begin;
		change fuser entry to fuser entry - 1;
		if fuser entry is at most 0 begin;
			blank out the whole row;
		end if;
		increase M by 1;
		choose row N - M in the Table of Recognized Words;
	end while.

The last every turn rule:
	if an attentive other person (called subject) is visible begin;
		if we are discussing begin;
			now the boredom counter of a random other person in the location is 0;
		otherwise;
			if the next beat is silence begin;
				increase the boredom counter of subject by 	1;
			otherwise;
				if discussed_this_turn is 0, try discussing the next beat;
			end if;
		end if;
	[	if the boredom counter of subject > 2 begin;
			try getting bored subject;
		end if; ]
	end if;
	now discussed_this_turn is 0;
	update the word table.



Volume Three - The Game

Outdoors is a region. Beachfront is in Outdoors. Tiderooms is in Outdoors. North Island is in Outdoors.

Book One - Lacuna

Part - Progue

Posture is a kind of value. The postures are pacing, standing, sitting, reclining. A person has a posture. A person is usually standing.

Mood is a kind of value. The moods are agitated, calm, sad, excited. A person has a mood. A person is usually calm.

A person is either asleep or awake. A person is usually awake.

Progue is a man in Outside Hut. Progue is asleep.  Understand "old" or "man" as Progue. "[if Progue is asleep]Sitting cross-legged on a rock is an old man in ragged, faded clothes, his eyes closed.[otherwise]The old man stands before you, watching you excitedly.[end if]". 

Instead of greeting an asleep Progue, say "The old man does not seem to hear you."



To wd x (newword - a topic) y (newbeat - a beat) z (len - a number):
	if the number of blank rows in Table of Recognized Words is 0 begin;
		sort the Table of Recognized Words in fuser order;
		choose row 1 in the Table of Recognized Words;
		blank out the whole row;
	end if;
	choose a blank row in Table of Recognized Words;
	change topic entry to newword;
	change beatr entry to newbeat;
	change fuser entry to len.

p_island is a beat. p_wayfarer is a beat. p_thecall is a beat. p_painter is a beat. p_notpainter is a beat. 

Instead of waking, pushing, or attacking an asleep Progue: now Progue is awake; now Progue is attentive; now the unavailable-beat of Progue is p_unavailable; wd x "island" y p_island z 99; try discussing p_wakesup.

Carry out exhausting when Progue is in the location: say "[one of]'Oh, let's not talk about that any more,' Progue says.[or]'I haven't much else to say about that, Progue says lightly.[or]'Oh, but we've been over all that already,' Progue says with a sigh.[or]'Mmm,' Progue says, 'it's not something I care to discuss any more, to be perfectly honest.[or]'Enough about that,' Progue says, pacing nervously, 'or we could be here all day!' He lets out a shrill little giggle.[cycling]"; stop the action.

Before changing the subject when Progue is in the location: 
	let x be a random number from 1 to 2;
	if x is 1, say "'We could always talk about that instead, I suppose,' Progue says, waving a hand dismissively. '[run paragraph on]";
	if x is 2, say "'Back to that, then,' he sighs. 'Well. [run paragraph on]";
	continue the action.





	
Beginnings is a thread carried by Progue. 

ProgueStory is a thread carried by Progue. ProgueStory adjoins Beginnings.

LacunaStory is a thread carried by Progue. LacunaStory adjoins Beginnings.

[ OK... all the stock behavior. First is talking about a known topic when it's not available. ]

p_unavailable is a repeatable ephemeral beat with reaction "[one of]'Don't change the subject,' the old man snaps.[or]'We weren't talking about that,' the old man responds testily, crossing his arms. 'I'm not senile yet.'[cycling]". 

[ Next is if the player doesn't answer a question. Any question should suggest this beat. ]

p_noans is a repeatable semiphemeral beat in Beginnings with reaction "[one of]The old man crosses his arms. 'Well?' he barks, annoyance creeping into his voice. 'Are you mute? Dumb? By choice or chance? I've had enough one-sided conversations for one lifetime. Say something!'[or]The old man taps his foot impatiently. 'Reticence, reticence,' he mutters, 'is not a virtue in conversation. Your answer, please!'[or]The old man folds his arms and sets a grim, steely gaze on you, obviously still waiting for your answer.[stopping]". p_noans suggests p_angryending. After discussing p_noans: wd x "something/answer" y p_smartass z 2.

p_smartass is an ephemeral beat with reaction "'Cute,' the old man says, 'cheeky. Smarmy even. Ordinarily I'd be amused, but I'm still waiting for your answer.'".

p_avoidingtheq is a repeatable beat in Beginnings with reaction "'Don't try to change the subject,' the old man says, 'I'm not so easily distracted. Your answer, please.'". p_avoidingtheq suggests p_angryending.

[ Used if the old man is fed up with player noncooperation. ]

p_angryending is a beat in Beginnings with reaction "The old man makes an indignant noise in his throat. 'Good riddance to you then,' he says with a dismissive wave of the hand, and marches off down the beach." After discussing p_angryending, remove Progue from play.

p_neutralending is a beat in Beginnings with reaction "Progue regards you for a moment, then clears his throat. 'Well, I'll be around,' he says, 'ha! Not going anywhere. Find me if you need me.' And with that, he sets off across the sand and vanishes." After discussing p_neutralending, remove Progue from play.

[ For various colorful words that aren't actually important. ]

p_colloquialisms is an available ephemeral beat with reaction "[one of]'Just an expression,' Progue says. 'Picked it up on some other world, years and years ago.' [or]'You'll have to excuse me,' Progue says, 'I know hundreds of colloquialisms, usually contradictory. Something of a linguistic chameleon, I suppose.' He chuckles.' [cycling]".

[ Saying yes, no, maybe, neither at inappropriate times. ]

Instead of saying yes when Progue is visible, say "'Yes? Yes?' The old man furrows his brows. 'Yes what? Did I ask a question with a yes or no answer? I don't recall doing so. I may have done. Perhaps. I've forgotten it, though. Let's change the subject, shall we?'".

[ Phew! OK, now on to the actual conversation. ]

p_wakesup is an available beat in Beginnings with reaction "You put a hand on the old man's bony shoulder. As you do, his eyes fly open and, seeing you, he leaps to his feet in astonishment.

'Wh--- wh---' he gasps, seemingly unable to get the words out. Finally he sputters 'Are you real?'" and words line "real, yes, no, maybe". After discussing p_wakesup: wd x "real" y p_real z 10; wd x "where/island/here/beach/place" y p_whereami z 15. p_wakesup suggests p_unsure. 


Instead of saying no or saying maybe when Progue is visible and p_reallyreal is available and we have not discussed p_ghost, try discussing p_ghost. Instead of saying yes when Progue is visible and p_reallyreal is available, try discussing p_reallyreal.

p_real is a beat in Beginnings with reaction "'Real, corporeal. Made of meat, eh?' He squints, and adds 'Not bad dreams. Not nightmares,' in a low mutter. After a pause he pokes you in the chest. 'Well? What do you say?'" and words line "real, dreams, yes, no, maybe". After discussing p_real: wd x "corporeal" y p_corporeal z 5; wd x "dreams" y p_nightmares z 5. p_real suggests p_mustbereal. p_corporeal replaces p_real. 

p_nightmares is a beat in Beginnings with reaction "'Think it's funny, do you?' the old man cries, face flushing. 'So hard to believe, is it, that a man alone for twenty years stops to ask a sudden visitor if he's really there?' He stops, then shakes his head. 'Look, please, just answer the question. Are you real, yes or no?'" and words line "funny, dreams, island, yes, no, maybe, shrug". After discussing p_nightmares: wd x "funny/visitor" y p_mustbereal z 2. p_nightmares suggests p_mustbereal. p_unsure replaces p_nightmares.

p_corporeal is a ephemeral beat in Beginnings with reaction "'Yes, yes,' he says in annoyance, waving a hand as if swatting a fly, 'flesh, matter, stuff. Let's not play semantics here. Answer the question, yes or no?'". p_mustbereal replaces p_corporeal. 

p_mustbereal is a beat in Beginnings with reaction "'Must be real,' the old man mutters, seemingly to himself, 'far too [far too what] to be a hallucination.' He takes a step back and studies you critically. ". After discussing p_mustbereal, try discussing p_reallyreal.

To say far too what: 
	if we have discussed p_corporeal begin; say "annoying";
	otherwise if we have discussed p_ghost; say "confused";
	otherwise if we have discussed p_nightmares; say "rude";
	otherwise; say "boring";
	end if.

p_unsure is an ephemeral beat in Beginnings with reaction "The old man regards you warily. He reaches out a bony hand and gives you a sharp poke in the chest, then leaps back, squinting his eyes suspiciously.". p_unsure suggests p_mustbereal. p_mustbereal replaces p_unsure.

p_ghost is a beat in Beginnings with reaction "The old man's eyes narrow. 'Deceptive spirit,' he says, giving you a[if we have discussed p_unsure]nother[end if] sudden poke in the chest. 'I can tell you're as real as I; don't tell me lies.' A thought seems to occur to him. 'But if you're lying about not being real, perhaps you're telling the truth about not being unreal. Well? Are you?' he snaps. " and words line "spirit, yes, no, maybe, shrug". p_ghost suggests p_mustbereal. After discussing p_ghost: wd x "unreal/spirit/spirits" y p_nightmares z 5. 

Instead of saying yes or saying no or saying maybe when Progue is visible and last beat is p_ghost, try discussing p_mustbereal.

p_whereami is an ephemeral beat with reaction "'Oh, this is a real place, I assure you,' says the old man, 'or else I've been having an extraordinarily long and dull dream, but I rather think otherwise. But answer my question, please!'". 

p_reallyreal is a beat in Beginnings with reaction "The curious old man blinks in astonishment. 'Bound me and slay me,' he says, gaping, 'well then, if you're real, and I--' An expression of horror flashes across his face; he quickly pinches himself, stomps his foot a few times, screws up his face in concentration, and finally seems to feel reassured-- 'If you're real, and I'm real, and we both are here, then... then how did you get here?' he finishes, wide-eyed." and words line "bound, wayfaring, painting, shrug". p_reallyreal suggests p_noans. After discussing p_reallyreal: wd x "bound/slay" y p_colloquialisms z 3; wd x "wayfared/wayfare/wayfaring" y p_wayfarer z 10; wd x "paint/painted/painting" y p_painterdirect z 10; now p_mustbereal is unavailable; now p_real is unavailable; now p_ghost is unavailable; now p_corporeal is unavailable; now p_reallyreal is unavailable. Instead of saying maybe when last beat is p_reallyreal, try discussing p_nottelling.

p_nottelling is a beat in Beginnings with reaction "'Hmph. Be mysterious, then,' the old man says, eyeing you carefully, 'but I have enough of an idea myself. Got here the same way I did, I expect. Must have been the Call. Ha! After all these years. Ridiculous.'

He spits. 'What are you then?' he asks abruptly. 'Painter? Potter? Writer? Hmm?'" and words line "way, call, painter, potter, writer, neither, shrug". After discussing p_nottelling: wd x "call/same/way" y p_thecall z 5; wd x "painter" y p_painter z 10; wd x "potter/writer" y p_notpainter z 10. p_nottelling suggests p_noans. Instead of saying neither or saying maybe when last beat is p_nottelling, try discussing p_notpainter.

p_painterdirect is a beat in Beginnings with reaction "For a moment, the old man simply blinks at you in astonishment. Then he throws back his head and laughs uproariously.

'Of course,' he finally gasps, still heaving, 'of course! The Call! Yes, after all these years, and why not? Still, I'm astonished. Amazed. Flabbergasted, even. What did you call it? Wayfaring? Yes, that sums it nicely, I suppose. Wayfaring. My sands and stars.' He seems to lose focus for a moment, trailing off and staring into the distance." and words line "call, astonished, wayfaring, sands". p_painterdirect suggests p_introduction. After discussing p_painterdirect: now p_painter is unavailable; now p_painterdirect is unavailable; now p_wayfarer is unavailable; wd x "astonished/amazed/flabbergasted/amazing" y p_astonished z 2; wd x "sand/sands/star/stars" y p_colloquialisms z 2; wd x "call" y p_thecall z 5; wd x "wayfaring/wayfare/wayfarer" y p_wayfarer2 z 99.

p_thecall is an ephemeral beat in Beginnings with reaction "'Trust me, I'm as surprised as you,' he says sourly. 'I had no idea it still worked. It hasn't any right to, after everything that[if we have discussed p_painterdirect]'s happened...[otherwise]... but come now, answer the question. What's your art?[end if]'". After discussing p_thecall: wd x "art/craft" y p_art z 3; wd x "happened/everything" y p_family z 2. p_thecall suggests p_noans. p_laterlater replaces p_thecall. 

p_art is an ephemeral beat in Beginnings with reaction "'Yes, yes, or craft if you like,' the old man says impatiently. 'Some draw, some write, others do whatever it is they do. I ask again: what is your art?'". p_art suggests p_noans.

p_wayfarer is a beat in Beginnings with reaction "For a moment, the old man simply blinks at you in astonishment. Then he throws back his head and laughs uproariously.

'Of course,' he finally gasps, still heaving, 'of course! The Call! Yes, after all these years, and why not? Still, I'm astonished. Amazed. Flabbergasted, even. What did you call it? Wayfaring? Yes, that sums it nicely, I suppose. Wayfaring. My sands and stars. What are you, then... painter? Potter? Writer?' He looks at you expectantly." and words line "call, astonished, sands, painter, potter, writer, neither".  p_wayfarer suggests p_noans. Instead of saying neither when last beat is p_wayfarer, try discussing p_notpainter. After discussing p_wayfarer: wd x "painter/paint" y p_painter z 5; wd x "potter/writer/sculptor" y p_notpainter z 5; wd x "astonished/amazed/flabbergasted/amazing" y p_astonished z 2; wd x "sand/sands/star/stars" y p_colloquialisms z 2; wd x "call" y p_thecall z 5; wd x "wayfaring/wayfare/wayfarer" y p_wayfarer2 z 99. p_wayfarer2 replaces p_wayfarer.

p_wayfarer2 is a beat in Beginnings with reaction "'Yes,' he says with a faint smile, 'I, too, am one of those so gifted. Was. I never knew a name for it, though. Wayfaring; it's a good one.' He mouths the word carefully, as if trying out, then shrugs. 'All academic now, I suppose,' he says morosely. [if we have discussed p_wayfarer]'But answer my question: which are you, painter, scuptor, what?' [end if] " and words line "was, academic, painter, sculptor, neither". p_wayfarer2 suggests p_introduction. After discussing p_wayfarer2: wd x "was/academic/gifted" y p_family z 3.

p_astonished is an ephemeral beat in Beginnings with reaction "The old man waves his hand dismissively. 'Let's just say I didn't think I still had it in me. Amazing. But tell me, do, what is your art?'". 

p_laterlater is a beat in Beginnings with reaction "'Yes yes, later, later,' he says, almost pleading. 'But aren't you going to answer my question?'" and words line "painter, potter, writer, no". Instead of saying no when last beat is p_laterlater, try discussing p_angryending. p_laterlater suggests p_angryending. 

p_painter is a beat in Beginnings with reaction "He is nodding almost before you can respond. 'Yes, I thought as much,' he says. 'Or something in the eyes thought it for me. I sculpt, myself, but painting is in the family.' A pained look crosses his face, and he trails off." and words line "eyes, sculpt, painting". p_painter suggests p_introduction. After discussing p_painter: wd x "family/painting/sculpt/pained/crosses" y p_family z 2; wd x "eye/eyes/something/thought" y p_eyes z 2; now p_notpainter is unavailable. 

p_notpainter is a beat in Beginnings with reaction "'Is it so?' the old man says curiously. 'Strange. I thought you might be a painter. Something in the eyes. I sculpt myself, or rather, once I did. Once I did. Yes.' He seems to lose focus for a moment, trailing off and staring into the distance." and words line "painter, eyes, sculpt, once". p_notpainter suggests p_introduction. After discussing p_notpainter: wd x "something/eyes/thought" y p_eyes z 2; wd x "sculpt/once/did" y p_family z 2; wd x "painter" y p_introduction z 2.

p_family is a beat in Beginnings with reaction "'It's been so long,' the old man mutters, still gazing towards the horizon, 'so very very long...' Then he seems to shake something off and turns to face you again.". After discussing p_family, try discussing p_introduction.

p_eyes is a beat in Beginnings with reaction "'The eyes, the eyes, and never the hands, to tell the nature true,' he says singsong, as if reciting, still staring into the distance. Then he seems to shake something off and turn towards you with a smile.". After discussing p_eyes, try discussing p_introduction.

p_introduction is a beat in Beginnings with reaction "'Goodness, how thoughtless, how rude,' he says with a start, 'introductions! They haven't happened. I have always been called Progue,' he says formally, pronouncing it as a single syllable with the 'r' almost rolled, 'and by now it's far too late to start protesting. And you?'

You make your introductions and Progue shakes your hand earnestly. 'How strange,' he marvels, 'no visitors for so long, and then I both meet and am introduced to one on the same day!'" and words line "progue, strange, visitors, questions". p_introduction suggests p_novisitors. p_moreaboutProgue replaces p_introduction. After discussing p_introduction: wd x "visitors/strange" y p_novisitors z 5; wd x "progue" y p_moreaboutProgue z 99; wd x "question/questions/why/who/where/what/how" y p_possibleqs z 99.

p_novisitors is a beat in Beginnings with reaction "'I don't get visitors much,' he goes on. A shrill little laugh. 'At all, I mean, at all. It's hard to tell what with it always being summer, but by guesswork I'd say I've been alone on this island a decade now. Perhaps two. No point in counting really, you see? No, of course you don't.' He rubs his hands nervously against each other." and words line "summer, alone, decade". After discussing p_novisitors: wd x "summer/island" y p_tourist z 99; wd x "decade/alone/guesswork/point/counting" y p_alone z 3. p_moreaboutProgue replaces p_novisitors. p_novisitors suggests p_transtoposq. 

p_alone is a beat in Beginnings with reaction "'One gets used to it, after a while,' says Progue musingly, seemingly unsure if he's trying to convince you or himself. 'There are times I've wanted to leave more than anything. If only I could...' he trails off." and words line "leave, could". After discussing p_alone: wd x "wanted/leave/more/anything/could" y p_toopersonal z 3. p_alone suggests p_transtoposq.

[p_cantleave is a beat in Beginnings with reaction "'Ah,' Progue says sadly. 'It's embarrassing, truthfully. I can no longer sculpt, you see. That is, I can, but they're just sculptures now, nothing more. You understand, I suppose.'

He bites his lip. 'Hence,' he says finally, quietly, 'exile of a sort. Though a pretty place for it.'" and words line "sculpt, sculptures, artist, exile, pretty, place". After discussing p_cantleave: wd x "pretty/place" y p_island z 5; wd x "sculpt/sculptures/understand" y p_justsculptures z 2. p_cantleave suggests p_transtoposq. 

p_justsculptures is a beat in Beginnings with reaction "'Hmph,' he says, making a gesture as if of dismissal, but failing to hide an obvious pain, 'they're good ones, I suppose. But even that doesn't matter. What's to separate the work of a master from an ugly lump of rock when there's none but the artist to see them, eh?'". After discussing p_justsculptures, try discussing p_transtoposq.]

p_toopersonal is a beat in Beginnings with reaction "A look of pain momentarily twists the old man's face, then he forces a smile and turns to you, beaming a little too brightly, apparently determined not to answer your question." After discussing p_toopersonal, try discussing p_possibleqs.

p_transtoposq is a beat in Beginnings with reaction "The old man seems to physically shake himself out of some momentary funk, and turns to face you with a smile that's a little too bright." After discussing p_transtoposq, try discussing p_possibleqs.

p_possibleqs is a beat in Beginnings with reaction "'Questions!' he shouts. 'Why, you must have thousands. About this crazed fool you see before you, none the least. Let's see, what else? Oh! About this island, I'm sure. And presumably why... why...' he trails off. Another forced smile. 'Oh! All about my little cabin up the rise there. Well, what would you like to know?' He waits expectantly." and words line "questions, progue, island, why, call, cabin". p_qs2 replaces p_possibleqs. p_possibleqs suggests p_notinterested. After discussing p_possibleqs: wd x "questions/thousands" y p_questions z 2; wd x "question/questions" y p_qs2 z 99; wd x "crazed/fool/progue" y p_moreaboutProgue z 99; wd x "island/lacuna" y p_island z 99; wd x "why/call/called" y p_why z 8; wd x "cabin/shack/house" y p_shack z 99; now p_whereami is unavailable.

p_shack is a beat in Beginnings with reaction "'I hardly ever sleep up there, anymore,' Progue says, waving a hand in the direction of the shack. 'It's looking old, now, isn't it? Served its purpose, I suppose. Feels... used up, somehow. Feel free to make use of it, if you wish.'". p_shack suggests p_qs2. 

p_why is a beat in Beginnings with reaction "'Why what?' the old man snaps, annoyed. 'Why did I Call you here, then? Is that it? Well, I should think it's perfectly obvious.' He begins furiously pacing back and forth." and words line "call, yes, no, questions". p_why2 replaces p_why. p_why suggests p_qs2. Instead of saying yes when last beat is p_why, try discussing p_whyyes. Instead of saying no when last beat is p_why, try discussing p_why2.

p_whyyes is a beat in Beginnings with reaction "'Ah!' he says, seemingly relieved. 'Excellent, then. We'll just consider that subject closed.'". After discussing p_whyyes: try discussing p_qs2.

p_why2 is a beat in Beginnings with reaction "'I don't know, I don't know, all right?' the old man shouts, running his hands through his shock of white hair. 'I didn't even realize I did it till I saw you standing there. Oh, maybe some part of me realized, somewhere between dreams and waking life. The Call's like that, you know.'

He stops and sighs. 'But really, I don't know why you're here,' he says, a little more calmly, 'there's nothing I need; no one can help me. There's been a mistake, you see. All I can say is I'm terribly sorry for any inconvenience, and feel free to scour the island for the materials you'll need to paint your way home again.'

He takes a deep breath. 'Now that's out of the way,' he says, 'any other questions?'" and words line "progue, island, call, cabin". After discussing p_why2: wd x "help/mistake/call/nothing/need" y p_crossedtheline z 4. p_why2 suggests p_notinterested.

p_sadness2 is a beat in Beginnings with reaction "'Don't press the point,' Progue says, lips a thin line, 'I prefer no friends to rude friends.'" and words line "point, sculpture, arrival, girls, years". p_angryending replaces p_sadness2. p_sadness2 suggests p_lstory2.

p_questions is a beat in Beginnings with reaction "'An inquisitive mind is such a healthy thing to have!' Progue says, a delighted expression brightening his face. 'Oh, it's been so long since I had someone animate to talk to. With the crabs, you know it's not the same. Oh! Questions! How I've missed them!' He spontaneously seizes your hand and begins to shake it vigorously." and words line "animate, crabs, progue, island, why, cabin".

p_island is a nonsequitous beat in Beginnings with reaction "'Ah yes,' Progue says, turning and presenting the beach with a broad gesture of his hand, 'welcome to Lacuna. That's what I called it, you know, after I first came here. Ha! Ancient history. But this island is my home now, and it's quite comfortable.' He seems to be warming to his subject." and words line "lacuna, came, history, island, comfortable". p_tourist replaces p_island. p_island suggests p_tourist. After discussing p_island: wd x "lacuna/called" y p_LacunaWord z 10; wd x "after/first/came/ancient/history" y p_moreaboutprogue z 4; wd x "island/here/home/comfortable" y p_tourist z 5.

p_tourist is a beat in Beginnings with reaction "'Pleasant year round,' Progue says with a hint of pride, 'never too hot or cold. Rains never last long and never get too severe; no dangerous animals; plentiful food of all kinds. It's really not too bad, at least on this side.'" and words line "pleasant, rains, animals, food, side". After discussing p_tourist: wd x "pleasant/hot/cold" y p_tourist2 z 5; wd x "rain/rains/severe" y p_rain z 10; wd x "dangerous/animals/animal" y p_animals z 10; wd x "plentiful/food" y p_food z 10; wd x "side/this" y p_side z 5. p_tourist suggests p_tourist2. 

p_tourist2 is an ephemeral beat in Beginnings with reaction "'Yes, I'm quite happy here,' Progue muses, although he seems unsure whether he's trying to convince you or himself. 'The tide comes in and out, the moon and sun rise and set... yes. It's easy to forget.' He sighs, staring off towards the horizon, seemingly almost unaware you are still here."

 p_LacunaWord is an beat in Beginnings with reaction "'Lacuna, yes,' Progue says. 'It's an old word. Don't know it? You could look it up, if there were a dictionary here, which there isn't, I'll save you the trouble of looking. To any event it's beside the point. Now it means this place, to me.'" and words line "lacuna, dictionary, place, questions". After discussing p_LacunaWord: wd x "lacuna/dictionary/definition" y p_LacunaWord2 z 5. p_LacunaWord suggests p_tourist2. [ TODO: dictionary]

p_LacunaWord2 is a beat in Beginnings with reaction "Progue looks annoyed. 'Oh very well,' he says, 'lacuna means the missing bit, more or less, and there is something missing here, can't you feel it?' He hugs himself, a wistful, almost haunted look coming into his eyes. 'There was something missing when we first came here, wasn't there? And even more missing now. Lacunae, lacunae everywhere...'" and words line "missing, feel, first, more, lacunae, questions". After discussing p_LacunaWord2: wd x "missing/feel/first/something/even/more/lacunae/lacuna" y p_crossedtheline z 4. p_LacunaWord2 suggests p_pasthint.

p_crossedtheline is a beat in Beginnings with reaction "Your words seem to break some spell, and abruptly Progue's face hardens and his eyes snap to yours in annoyance. 'Yes, well, what's past is past,' he says, ".

p_pasthint is a beat in Beginnings with reaction "Progue's eyes redden as he continues staring out to sea. 'Little birds,' he whispers, 'where have you flown? Oh, my darling little girls...'

Abruptly, he seems to become aware of you again. Self-conciously drying his eyes, he says 'I'm sorry. What were we talking about? ".

p_rain is an ephemeral beat in Beginnings with reaction "'Tends to monsoon a little most afternoons,' Progue says, 'but it's warm rain and over practically as soon as it begins. Come to love it, myself.'". p_rain suggests p_possibleqs. 

p_food is a beat in Beginnings with reaction "'Fond of crab?' Progue asks. 'They're delicious. The little rascals are quick, but it's easy enough to outsmart them. There's also plenty of fish, bavafruit-- sweet red mushy stuff-- berries off to the south, some bird when I can get it.' He pats his stomach. 'Never gone hungry, for truth.'" and words line "crab, outsmart, fish, bavafruit, berries, bird, hungry". p_food suggests p_possibleqs. After discussing p_food: wd x "crab/delicious/rascals/outsmart/easy" y p_crabs z 10; wd x "fish/plenty" y p_fish z 10; wd x "bavafruit/sweet/red/mushy/stuff" y p_fruit z 10; wd x "berries/berry" y p_berries z 10; wd x "bird" y p_bird z 10; wd x "hungry" y p_hungry z 10; wd x "truth" y p_colloquialisms z 6.

p_crabs is a beat. p_fish is a beat. p_fruit is a beat. p_berries is a beat. p_bird is a beat. p_hungry is a beat.

p_animals is a beat in Beginnings with reaction "'No dangerous animals,' Progue says again, his smile fading a little, 'but that's not to call this island Lacuna entirely without danger.' He pauses. 'It's part of why I Called you here,' he finally adds." and words line "lacuna, danger, why, called". p_animals suggests p_possibleqs. 

p_side is a beat in Beginnings with reaction "Progue scowls. 'I like it down here, what's wrong with that?' he says. 'I never go up the path any more. Too... noisy.'" and words line "like, never, noisy". p_side suggests p_possibleqs. After discussing p_side: wd x "noisy/path" y p_noisy z 3.

p_noisy is a beat in Beginnings with reaction "'But enough about that!' Progue says with a broad grin that seems to indicate the subject is closed.". After discussing p_noisy, try discussing p_possibleqs. p_noisy2 replaces p_noisy.

p_noisy2 is a beat in Beginnings with reaction "'There are things here you must discover for yourself,' Progue says darkly. 'Please waste no more breath on asking me about them.'" and words line "things, discover". p_angryending replaces p_noisy2.


p_nomoreisland is an available beat in Beginnings with reaction "'I'd bore you to tears if I told you any more,' Progue says, patting your arm. 'No, the rest you must learn for yourself, as I did, exploring this place and uncovering its mysteries.'" and words line "learn, exploring, mysteries". p_nomoreisland suggests p_reasonforcall.

p_notinterested is a nonsequitous repeatable beat in Beginnings with reaction "'What am I saying?' the old man cries, clapping his hand to his forehead dramatically. 'Of course you aren't interested. Gracious, you've just arrived. You must be famished! And tired. Are you tired? Please, feel free to drop to the ground and sleep right here on the dunes. They're quite relaxing.' He bites his lip and takes a few steps back, watching you nervously." and words line "famished, tired, sleep, questions". After discussing p_notinterested: wd x "famished" y p_food z 5; wd x "tired/sleep" y p_shack z 5. p_notinterested suggests p_neuralending. p_neutralending replaces p_notinterested.

p_qs2 is a repeatable beat in Beginnings with reaction "[one of]'More questions?' Progue asks.[or]'Anything else I can tell you about?' Progue says.[or]'What else?' Progue says.[cycling]" and words line "questions, progue, island, why, call, cabin". p_qs2 suggests p_happyending. Instead of saying no when last beat is p_qs2, try discussing p_happyending.

p_happyending is a repeatable beat with reaction "'I shall leave you to explore, then,' Progue says, pumping your hand again while simultaneously bowing. 'Please, if you would like to talk again, do find me, do!' After another long bow, he disengages and trudges off up the dune, glancing back every few feet with another grin and a wave.". After discussing p_happyending: remove Progue from play.

p_moreaboutProgue is a beat in Beginnings with reaction "'Me?' he shrugs. 'What is there to tell?' He ponders for a moment. 'Well, rather a lot, I suppose. Ha!' He begins to pace back and forth along the beach, rubbing his hands nervously. 'Well, the short version is, I'm a wanderer of worlds, like yourself, and my wanderings have left me here. 
'Don't ask again, I warn you, or you might never hear the end.'" and words line "progue, lot". p_evenmoreaboutProgue replaces p_moreaboutProgue. p_moreaboutProgue suggests p_questions.

p_evenmoreaboutProgue is a nonsequitous beat in ProgueStory with reaction "'Ah, inquisitives,' Progue says with a faint smile, 'a singular breed. Who was it that called the past [apostrophe]a lockéd chest, window'd round but ne'er a key that fit her?[apostrophe]' He runs a hand through thinning hair. 'Ask me again, sometime,' he finally says, 'I'm not in the mood to go dredging through memories.'" and words line "past, change". p_evenmoreaboutProgue suggests p_Proguepast. p_Proguepast replaces p_evenmoreaboutProgue.


Part - Distant Scenery

The mountain is a view with x 90 and y 50. [Fix!] The mountain is visible from Beachfront.

The description of the mountain is "Dominating [if dir]the northeastern[otherwise]one[end if] corner of the island, the mountain is steep and tall, seemingly unclimbable. The rocky sides [if range of mountain is near]seem to be composed of sharp volcanic rock[otherwise]are black and smooth[end if].[if the range of mountain is near or medium] Perched near the mountain's summit is a round, domed building that looks like an observatory.[end if]".

To say a sentence about the mountain:
	if we have not examined the mountain, say "A large, craggy mountain looms up into the clouds in the [range of mountain] distance";
	otherwise say "The mountain, at a [range of mountain] range, is jauntily attired [if evening or sunset]in the fiey glow of the fading sun[end if][if sunrise]in shadows as the sun rises behind it[end if][if moonup]in a pillowy glow of moonlight[end if]".
	
To say a phrase about the mountain:
	if raining begin;
		say "but the rest of the island is shrouded in mist";
	otherwise if night; say "and [if we have examined the mountain]the great dark shape of the mountain[otherwise]a great dark shape[end if]looms over the island"; 
	otherwise; say "[one of]while the [if dir]northeast [end if]mountain rises triumphantly over the landscape[or]and, like a titan, the mountain on the [if dir]northeast corner [otherwise]far end[end if] lords over the island[or]while the mountain continues its rocky vigil [if dir]to the northeast[otherwise]at the island's far end[end if][location random][if rained], head shrouded in clouds[end if][if sunrise or morning], its peak catching the morning light[end if][if sunset or twilight], the top of its peak glowing a dull red[end if]";
	end if.

Part - Classes

Section - Plaques

A plaque is a kind of prop. Understand "wood" or "wooden" as a plaque. A plaque is always undescribed.

The description of a plaque is usually "No larger than a small book, the plaque is firmly affixed [if location is Center Low Tide]to a flat boulder rising just above the sand[end if][if location is Tidepools]at the bottom of a shallow tidepool, inches below the surface[end if][if location is Treehouse]to the trunk of the tree[end if][if location is Sloping Meadow]to a large grey boulder[end if][if location is Rim of Volcano]to a swell of black volcanic rock at the volcano's edge[end if]. Elegantly carved into the aging wood is [plaque symbol]."

To say plaque symbol:
	if location is Center Low Tide begin;
		if we have examined the rayfish, say "a rayfish";
		otherwise say "some sort of manta ray creature";
	otherwise if location is Tidepools; say "a crashing wave";
	otherwise if location is Treehouse; say "another withered tree with holes through its branches, much like the one you're standing in";
	otherwise if location is Sloping Meadow; say "a dragonfly";
	otherwise if location is Rim of Volcano;
		if we have examined the galaxy, say "the night sky's massive galactic disc";
		otherwise say "a disc with a bulge in its center, made up of tiny points... a galaxy, perhaps";
	end if.

Before taking a plaque, say "The plaque is firmly attached; it doesn't budge when you tug on it." instead.


Part - The Beach

Chapter - Definitions

Beachfront is a region. The ambiance table of Beachfront is Table of Beachfront Ambiance.

Tiderooms is a region. 

South Beach is south of Outside Hut, northwest of Fork, northeast of Among the Boulders, east of South Low Tide, and southeast of Center Low Tide. Among the Boulders is south of South Low Tide and northeast of Tidepools. Center Low Tide is west of Outside Hut, south of North Low Tide, north of South Low Tide, and southwest of North Beach. Outside Hut is west of a room called Hut. Outside Hut is south of North Beach. Hut is west of Back Room. North Beach is east of North Low Tide. South Beach is down from Fork.

Instead of listening when in Beachfront, say "You hear [if night]only [end if]the [if tideout]far-off [end if][if high tide]crashing [end if]sounds of the surf[if day] and the cawing of seagulls[end if]."

Chapter - Views and Backdrops

The nearby beach is a backdrop. The nearby beach is in Beachfront. Understand "sand" as the beach.

Instead of examining the nearby beach:
	say "Startlingly white, the sandy beach stretches around the edge of the lagoon in an unbroken crescent. At ";
	if dir begin; say "its southern end, boulders give way to a rocky spur, while a black rocky spur runs from the volcano all the way down to the beach's northern end";
	otherwise; let dis1 be the number of moves from the location to Among the Boulders; let dis2 be the number of moves from the location to Rise; say "the [if dis1 > dis2]far[otherwise]nearer[end if] end, boulders give way to a rocky spur, while a hardened black lava flow runs from the volcano all the way down to the [if dis1 > dis2]nearer[otherwise]far[end if] end of the beach";
	end if;
	say ".".

Instead of taking or touching the beach:
	if rained or raining, say "You scoop up a handful of the wet, almost muddy sand, feeling it ooze in gritty trickles through your fingers."; otherwise say "You let a handful of the [if night or dawn or sunrise or morning]cool[end if][if midmorning or midday or twilight]warm[end if][if afternoon or evening or sunset]scorching hot[end if] sand run through your fingers. So fine they feel almost soft, the grains [if midday or afternoon or evening or sunset]sparkle in the bright sun as they [end if]fall in a thin line back to the beach."

To say a sentence about the nearby beach: 
[	let z be a random number from 1 to 3;
	if z is 1, say "A white sand beach [if sunup]glistens[otherwise]arcs in a graceful curve[end if] in the [if sunset or evening]setting sun[end if][if dawn or twilight]faint glow of the sky[end if][if night and moonup]moonlight[end if][if night and moondown]starlight[end if][if morning or midmorning or midday or afternoon]sunlight[end if]";]
	if night begin; say "[one of]The undulating white sand beach [if moonup]is silver in the moonlight, which sparkles faintly on the [otherwise]is dim and indistinct under the stars, the border between ground and sky defined by the sound of the [end if][if tideout]distant waves[end if][if rising uptide or falling uptide]waves, a stone's throw away[end if][if high tide]runners of foamy surf reaching almost to your feet[end if][or][if falling uptide or falling downtide]Damp sand glistens[end if][if high tide]Foamy breakers lap the shore[end if][if low tide or rising downtide or rising uptide]Smooth stretches of sand spread out[end if] [if moonup]ghostly white [end if]before you, [if location is South Beach]dotted with myriad tiny shells and pieces of wood[otherwise]unbroken save for your own footsteps[end if][location random]"; stop; end if;
	if twilight or dawn begin; say "The stillness of the great crescent beach is magical in the half-light; the whole expanse curving out before you quietly breathtaking"; stop; end if;
	say "[one of]Sand curves in a great white crescent around the lagoon[or]Pristine white sand [if midday]almost blinds you as it [end if]stretches in a great arc around the lagoon[location random]".

The surf is a view. The surf is visible from Outdoors. Understand "wave" or "waves" or "water" or "sea" or "ocean" or "tide" as the surf. The description is "[if high tide]The waves are very near your feet. Glancing at the debris, it looks as if the surf is near the high tide mark.[end if][if falling uptide]The tide seems to be ebbing out, but the waves are still relatively close.[end if][if falling downtide]The tide is a good distance away, and seems to be ebbing even farther out.[end if][if low tide]The waves are a long way down the beach, breaking languidly against the surf.[end if][if rising downtide]The waves are a good distance away, but the tide seems to be flowing back in.[end if][if rising uptide]The surf is relatively close, each wave seeming to crash a little closer.[end if]".

Instead of touching the surf, say "The water is warm, and feels fresh and alive as it swirls over your hand."

The lagoon is a view. The lagoon is visible from Outdoors. To say a sentence about the lagoon:
	if night begin;
		say "[if we have examined the rayfish]The faint blue glows of the rayfish are dimly visible out in the lagoon[otherwise]Pale blue lights weave and bob through the waters of the lagoon[end if]";
		stop;	end if; 
	if afternoon or midday or midmorning begin;
		say "[if tidein]The surf stretches to[otherwise]The surf pounds faintly beneath[end if] the western horizon, [if rain clouds are in location]under a grey sky streaked with fast moving clouds[end if][if raining] dumping buckets of rain[end if]";
		if rain clouds are not in location, say "[one of]where it meets a vast, unclouded sky, so deep a blue your eyes hurt[or]the lagoon practically glowing as it warms in the sparkling sunlight[location random]";
	stop;	end if;
	if evening begin;
		if rained begin;
			say "Thunderheads receeding westward are lit up like giant floating barges by the sinking sun's rays, which are reflected by the water and the wet, sparkling sand";
		otherwise;
			 say "Reflected sunlight shimmers off the [if tideout]distant [end if]tide, pointing a straight line towards the sinking sun";
		end if;
		stop;	end if; 
	if sunset begin;
		say "A fantastic tropical sunset dominates the sky, the [if tideout]distant [end if]waves westward shimmering magically under deep purples, oranges, and the brilliant yellow gleam of the setting sun";
		stop;	end if;
	if twilight begin;
		say "The sky and the colors of the lagoon are slowly fading in the dimming light";
		stop; end if;
	if dawn or sunrise or morning begin;
		say "[one of]Distant clouds glow yellow-pink over the ocean to the west as the rising sun's rays intersect them, but [if dawn]the land[otherwise]most of the beach[end if] is still in shadow[or]The lagoon stretches before you, blue and beautiful, slowly richening in color as the sky brightens above[location random]";
		stop;	end if.


Chapter - Ambiance

Table of Beachfront Ambiance
frequency	start time	end time	text	table		trigger	flag
frequent	high tide	--	--	Table of High Tide Ambiance	a thing	a number
common	rising uptide	--	--	Table of Tide Ambiance
common	falling uptide	--	--	Table of Tide Ambiance
uncommon		--	--	"[one of]A gust of wind blows sand in whirls and eddies along the beach[or]A sudden breeze springs up, send sand spiraling along the beach[if the location contains a setpiece] and drifting against [the random setpiece in the location][end if][at random]."
common	dawn		twilight	--	Table of Seagull Ambiance
uncommon		dawn		midmorning	--	Table of Crab Ambiance
common	evening	twilight	--	Table of Crab Ambiance
uberrare	dawn		midmorning	"Far out in the lagoon, a great blue-gray mass heaves above the surface-- a whale! With a spurt of air and mist, the creature glides gracefully back beneath the surface."	--	whale
common	night		--	"[one of]Out in the lagoon, [if we have examined the rayfish]strange pale blue lights[otherwise]the glowing blue rayfish[end if] bob and weave under the water[or][if we have examined the rayfish]Dozens of ghostly blue lights[otherwise]The glowing blue lights of the rayfish[end if] circle slowing under the waters of the lagoon.[at random]"
rare	--	--	"A steady wind blows the smell of the ocean across the beach."

Table of High Tide Ambiance
frequency		text	table		trigger	flag
common	"A wave slowly breaks up the shallow lagoon, sending an undulating line of foamy water almost to your feet."
common	"Another wave breaks on the beach."
rare	"The loud sound of rushing surf gives you just enough time to dance away as a larger than usual wave surges up the beach."
rare	"[if night]Something black and shapeless[otherwise]A large clump of seaweed[end if] gyrates at the edge of the tide."
uncommon		"Two waves roll up in quick succession, as if the second is overtaking the first."
uncommon		"The sound of the surf surges around you as another wave breaks."

Table of Tide Ambiance
frequency		text	table		trigger	flag
uncommon		"[one of]Some distance away[or]Farther down the beach[or]At the water's edge a stone's throw away[at random], [one of]a wave rolls in and breaks against the shore.[or]surf crashes against the sand.[or]the steady surge and ebb of surf continues.[or]a wave rolls gently in. [if day]You watch the breakpoint as it travels around the lagoon.[end if][or]the surf beats against the sandy shore.[at random]"
rare		"[one of]A large wave rolls in across the lagoon and crashes spectacularly against the beach, the breakers surging to near where you're standing[or]A big wave crashes to shore down at the edge of the beach[at random]."

A small crustacean carapace is set dressing. A whale is set dressing. The description of the whale is "The majestic creature has already vanished beneath the water's surface, leaving only a roiling mass of bubbles behind."

Seaweed is a backdrop in Beachfront. Understand "weed" or "black" or "shapeless" as seaweed. The description is "It's a long clump of seaweed. Green nodules full of air are spaced along its long, along with graceful filiments and tendrils of leaves."

Chapter - Animals

A crab is an undescribed animal. The description is "About the size of your hand, this curious creature scuttles sideways along the sand quite nimbly, holding pincers above him and darting eyes on long stalks every way it can." Instead of taking or touching a crab: say "[one of]You reach out your hand for one of the creatures, but it dashes away in a panic before you can grab it, tiny legs pumping furiously[or]You reach down to grab it, but in a snap it nips you with a pincer and darts away. Ow! It's only a tiny cut, but the crab made its point[or]You sidle cautiously towards the crab, then reach down in a flash. You got him! He snaps pincers and waves his legs fiercely as you study his fine caparace and detailed underbelly. Finally, you set him back down. He snaps once more, indignantly, before beating a hasty retreat down the beach[at random]."; remove the crab from play. Instead of attacking a crab: say "You aim a kick at one of the little creatures, but it scuttles out of the way with better reflexes than you gave it credit for, and quickly hurries out of sight."; remove the crab from play.

The rayfish is an undescribed animal in North Beach.

A giant sea turtle is an animal. The description of the turtle is "[if location is Beachfront]Its great rounded shell is mottled brownish-black, and it pulls itself along with powerful front flippers. Shrewd eyes gaze out at the world from a leathery face[otherwise]The turtle manages to seem both graceful and ridiculous as it paddles through the water, just under the surface[end if].". 

Turtle Encounter is a scene. Turtle Encounter begins when the giant sea turtle is in the location. When Turtle Encounter begins, say "A giant sea turtle lumbers around the rounded edge of a boulder and swishes through the sand, taking no notice of you at all." Turtle Encounter ends when the turtle is not in the location. When Turtle Encounter ends, remove turtle from play.

A seagull is an undescribed animal. The description is "These seem larger and more streamlined than the usual kind, and their long yellow beaks are tipped with a cerulean blue rather than red. But their cries sound just as you'd expect." Understand "gull" or "bird" as the seagull. Instead of doing anything other than examining or describing to the seagull: say "The bird squawks angrily at you and takes to the air, flapping up in a broad circle to join its fellows."; remove the seagull from play.

The cluster of gulls is a backdrop in Beachfront. The description is "Flocks of seagulls and other birds make wide circles around the lagoon, occasionally diving down to snatch something from the warm blue water." Understand "seagulls" as the cluster of gulls.
	
Table of Crab Ambiance
frequency	text	table	trigger	flag
uncommon		"A small red crab picks its way carefully through the sand."	--	crab
uncommon		"[if tidein]A small crustacean carapace washes up to the beach[otherwise]A small crab picks at an abandoned carapace filling with sand, before losing interest and continuing along his way[end if]."	--	carapace
uncommon		"A tiny red crab freezes motionless as you approach."	--	crab
uncommon		"[if tidein]A wave tumbles a small red crab end over end. It lies struggling upside down for a moment before righting itself and hurrying up the beach indignantly[otherwise]A little reddish-black crab digs at something in the sand with its front pincers[end if]."	--	crab

Table of Seagull Ambiance
frequency	text	table	trigger	flag
uncommon		"A gull picks at its feathers with its beak before letting out a loud call."	--	seagull
uncommon		"A gull walks carefully along the sand, occasionally poking at something with its blue-tipped beak."	--	seagull
rare	"Two gulls flap wings and caw fiercely at each other for a moment over a piece of rotting fish, before one snatches it and takes to the air."	--	seagull
		
Table of Seagull Air Ambiance
frequency	text	table	trigger	flag
common	"Gulls cry as they circle overhead, before heading back out to sea."
uncommon		"A lone gull drifts lazily by overhead, almost seeming to hover in place as he rides an updraft."
common	"A distant flock of gulls cry racously as they wing their way along the edge of the coast."
rare		"A gull swoops by your head, momentarily startling you out of your wits."


Chapter - Rooms

Section - South Beach

South Beach is a room in Beachfront with x 38 and y 40. The printed name of South Beach is "[if dir]South Beach[otherwise]Beach, Near the Path[end if]". Instead of describing when the noun is South Beach:
	say "[A sentence about the nearby beach]. [A sentence about the lagoon]. [exits]."
	
The exits text of South Beach is "The beach [if dir]curves around to the north[otherwise]continues around the lagoon[end if], while [if dir]southwest is[otherwise]closer at hand lies[end if] rockier terrain. A faint path climbs [if dir]southeast[otherwise]up[end if] into [if day]dense vegetation[otherwise]shadows[end if]". Understand "beach" or "more" or "continues" or "around" as Outside Hut. Understand "closer" or "rockier" or "rocky" or "terrain" as Among the Boulders. Understand "faint" or "path" or "dense" or "vegetation" or "shadows" as Fork. The exits line of South Beach is "more beach, rocky terrain, faint path, ocean".

Some beach debris is a prop in South Beach. Understand "shell" or "seashell" or "seashells" or "pieces of wood" or "wood" or "tiny" or "shells" or "detritus" or "flecks" or "seaweed" as the debris. Instead of doing anything to the debris, say "None of it appears particularly valuable."

Report going southwest from South Beach: say "You amble across the sand into rockier terrain." Report going north from South Beach: say "You follow the sweeping curve of the beach about halfway around its edge." Report going southeast from South Beach: say "You walk back up the path and reenter the shade of the forest."

Section - Outside Hut
	
Outside Hut is a room in Beachfront with x 40 and y 53. The printed name of Outside Hut is "Beach, Near the Shack". Instead of describing when the noun is Outside Hut:
	say "The sandy beach slopes up here to meet a small wooden house, built up against a rocky volcanic ridge that sweeps up [if dir]to the southeast [end if]towards the volcano. [exits]."
	
The exits text of Outside Hut is "The beach stretches away [if dir]to the north and south[otherwise]towards a cluster of boulders or a rocky butte[end if], the lagoon [if dir]lies to the west[otherwise]beckons, tantalizing[end if], and the shack is up a short rise[if dir] to the east[end if]". Understand "cluster" or "boulders" as South Beach. Understand "rocky" or "rise" as North Beach. Understand "lagoon" as Center Low Tide. Understand "shack" or "short" or "butte" or "house" as Hut. The exits line of Outside Hut is "boulder cluster, rocky rise, lagoon, shack".

Report going north from Outside Hut: say "You amble along the soft white sand of the beach, working your way [if dir]north [end if]around the edge of the bay." Report going east from Outside Hut: say "You clamber up the slipping sand past seaweed and shells at the high-water mark, then onto sturdier ground, before finally arriving at the building[if Hut is unvisited]. Peering in the door cautiously, you step inside[otherwise] and stepping inside[end if][if raining], grateful to be out of the rain[end if]." Report going south from Outside Hut: say "You walk around the edge of the beach towards some rockier terrain[if dir] near its southern end[end if]."

Section - North Beach

North Beach is a room in Beachfront with x 38 and y 59. The printed name of North Beach is "[if dir]North Beach[otherwise]Beach, Near the Rise[end if]". Instead of describing when the noun is North Beach:
	if raining, say "Rain patters noisily on a huge piece of driftwood which seems to mark";
	otherwise say "A huge piece of moss-covered driftwood[if rained], dark and dripping with moisture,[end if] seems to guard";
	say " [if tidein]the narrow strip of sand here at the end of the beach, between the waves and[otherwise]the end of the beach, dominated by[end if] a rocky slope that juts out into the water. [A sentence about the lagoon]. [if dir]To the east[otherwise]Opposite the lagoon[end if], ";
	if night, say "the sky is blotted out by rocky cliffs.";
	otherwise say "the beach ends abruptly at a much steeper slope so dense with vegetation as to be complete impassable; a more promising route heads up the rise [if dir]to the northwest[otherwise]nearby[end if].".
	
The exits text of North Beach is "A path through the rock slope heads up[if dir] to the northwest[end if]. You can also walk [if dir]south[otherwise]back[end if] along the beach towards the wooden shack[if tideout], or head [end if][if tideout and dir]west [end if][if tideout]down the beach towards the water[end if]". Understand "rocky" or "slope" as Rise. Understand "cliff" or "cliffs" as FakeRoomCliffs.

FakeRoomCliffs is east of North Beach. Instead of going to FakeRoomCliffs, say "The cliffs in that direction are impassable."

A huge piece of moss covered driftwood is a setpiece in North Beach.

Report going northwest from North Beach: say "You clamber easily over some boulders up onto a rocky spur of land, leaving the beach behind." Report going south from North Beach: say "You follow the gentle curve of the white sand beach around till you near its center."

Section - Among the Boulders

Among the Boulders is a room in Beachfront with x 24 and y 35. 

Instead of describing when the noun is Among the Boulders:
	do the room description dance with Table of Among the Boulders Structure and Table of Among the Boulders Description.

Table of Among the Boulders Structure
time	s1	s2	s3	s4	s5	s6	s7	s8
dawn		1	98	3	4	99	5	a number	a number
sunrise	6	98	3	99	5
morning	6	98	7	99	5
midmorning	1	98	3	99	5
midday	1	98	3	99	5
afternoon	2	99	5
evening	2	99	5
sunset	2	99	5
twilight	1	98	3	4	99	5
night		8	99	9

Table of Among the Boulders Description
row	text
1	"Large mottled boulders rise up from the sand"
2	"Great gray boulders rise from the sand, [if raining]rain smoothly pattering on and slipping off their egg-shaped tops[end if][if rained]warm and wet in the sinking sun and smelling of rock[end if][if didnt rain]their rouned edges catching the light of the falling sun[end if]"
3	"rubbed smooth by eons of tides and wind"
4	" and further rounded by the shadowless [if dawn]dawn light[otherwise]twilight[end if]"
5	"They tower over a multitude of [if dawn or twilight]shadowy[otherwise]sandy[end if] paths heading [if dir]southwest[otherwise]out to a rocky point[end if][if evening] and send long fingers of shadow across the rippling beach stretching[otherwise], while the beach becomes more open to the[end if] [if dir]northeast[otherwise]back towards the path[end if]. [if tidein]The tide crashes against low smooth stones[otherwise]A bank of slippery stones stretches[end if] [if dir]to the north[otherwise]in the direction of the ocean[end if]."
6	"Pink morning light kisses the tops of the great mottled boulders here"
7	"casting a jumble of confused shadows over the sandy paths wandering [if dir]southwest[otherwise]towards a rocky point[end if]"
8	"A confusion of boulders rises from the sand here, great black egg-shapes blotting out the stars on all sides"
9	"[if dir]The dark beach becomes more open to the northeast, while to the southwest is a rocky point[otherwise]The land narrows towards a rocky point, or widens back in the direction of the beach[end if]."

Understand "sandy" or "paths" or "rocky" or "point" or "narrows" as Tidepools. Understand "path" or "widens" or "beach" as South Beach. Understand "bank" or "slippery" or "stones" or "ocean" as South Low Tide. The exits line of Among the Boulders is "beach, rocky point, ocean".

The ambiance table of Among the Boulders is the Table of Among the Boulders Ambiance.

Table of Among the Boulders Ambiance
frequency	start time	end time	text	table		trigger	flag
rare	dawn		sunset	--	--	turtle
uncommon		dawn		twilight	"A crab wends its way between the boulders, either lost or unusually adventurous."	--	crab
rare	dawn		twilight	"A gull flutters in from sea and perches on the exact top of a large, rounded boulder looming above you."	--	seagull


Report going southwest from Among the Boulders: say "You weave through the boulder stand, clambering over a few here and there, and pick your way carefully out onto a wet, rocky point." Report going north from Among the Boulders:  say "[if tidein]You wade out into the warm water, stepping carefully until the rocky ground gives way to smooth, fine sand[otherwise]You clamber carefully across rocks slick with water and seaweed before reaching the warm fringe of the tide[end if]." Report going northeast from Among the Boulders: say "You leave the boulders behind and walk back along the smooth white sand of the beach."



Section - Tidepools

Tidepools is a room with x 18 and y 29. 

Instead of describing when the noun is Tidepools:
	do the room description dance with Table of Tidepools Structure and Table of Tidepools Description.

Table of Tidepools Structure
time			s1	s2	s3	s4	s5	s6	s7	s8	s9	s10
dawn		3	4	2	99	5	6	99	7	11	a number
sunrise		3	4	2	99	5	6	99	7	11
morning		1	4	2	99	5	6	99	7	11
midmorning	1	4	2	99	5	8	99	7	11
midday		1	4	2	99	5	8	99	7	11
afternoon		1	4	2	99	5	8	99	7	11
evening		9	4	2	99	5	8	99	7	11
sunset		9	4	2	99	5	6	99	7	11
twilight		10	4	2	99	5	6	99	7	11
night			1	4	2	99	7

Table of Tidepools Description
row	text
1	"A rocky point ends here with a series of "
2	"[if tidein]battered and churned constantly by the surf[end if][if tidein and raining] and rain[end if][if tideout and raining]broken into dancing mirrors by the constant rain[end if][if tideout and not raining]smooth mirrors of the [light source] above[end if]"
3	"Morning sunlight just touches this rocky point, strewn with "
4	"tidepools, "
5	"From here the whole lagoon stretches out before you, "
6	"[a phrase about the mountain]"
7	"[exits]."
8	"dominated by the mountain and volcano looming from either end of the island"
9	"The sinking sun sets over this cluster of "
10	"Under the fading light are strewn "
11	 "[paragraph break]Affixed to the bottom of one of the tidepools[if tidein], barely visible beneath the churning surf, [end if] is [a or another for plaque] small wooden plaque."


The exits text of Tidepools is "Dry land snakes [if dir]northeast [end if]back towards the cluster of rounded boulders". The exits line of Tidepools is "boulder cluster".

				
Report going northeast from Tidepools: say "You step carefully[if tidein] through the crashing surf[end if] back towards the beach until you find yourself amidst the boulders once again."

The wave plaque is a plaque in Tidepools.

Definition: something is plaquelike if it is a plaque.

To say a or another for plaque: say "[if we have examined something plaquelike]another[otherwise]a[end if]". [FIX]

The ambiance table of Tidepools is the Table of Tidepools Ambiance.

Table of Tidepools Ambiance
frequency	start time	end time	text	table		trigger	flag
frequent	high tide	--		"[one of]With a crash, a wave breaks against the jagged rocks of the point, spraying you with surf and sending foam swirling around your ankles[or]A wave breaks against the rocks, sending a surge of seawater past your feet[or]A wave smashing against the rocky point, sending a wall of spray flying into the air and half drenching you[or]A wall of water crashes into the rocky point, sending foamy waves surging and crashing through the tidepools[at random]."
common	falling uptide	rising uptide	--	Table of Tide Ambiance
common	sunrise	twilight	--	Table of Seagull Ambiance


Section - Tiderooms

South Low Tide is a room in Tiderooms. Instead of describing when the noun is South Low Tide:
	say "[A sentence about the ocean swells]. [A sentence about the lagoon]. [exits]."
	
Center Low Tide is a room in Tiderooms. Instead of describing when the noun is Center Low Tide:
	say "[A sentence about the ocean swells]. [A sentence about the lagoon]. [exits].[if low tide][paragraph break]Affixed to a boulder jutting from the sand is [a or another for plaque] small plaque.[end if][if rising downtide or falling downtide][line break]Water swirls around an almost-submerged boulder, bearing [a or another for plaque] small plaque.[end if]".

North Low Tide is a room in Tiderooms. Instead of describing when the noun is North Low Tide:
	say "[A sentence about the ocean swells]. [A sentence about the lagoon]. [exits]."

The exits text of South Low Tide is "The lagoon arcs gently around to [if dir]north; to the south are a cluster of round-topped boulders[otherwise]towards its center; closer at hand you see a cluster of round-topped boulders[end if]. [lagoon exit finish]". Understand "lagoon" or "arc" or "arcs" as Center Low Tide. Understand "round" or "round-topped" or "topped" as Among the Boulders. Understand "beach" or "more" or "other" as South Beach. The exits line of South Low Tide is "lagoon, boulders, beach". 

The exits text of Center Low Tide is "The lagoon surrounds you, continuing [if dir]north and south[otherwise]towards distant boulders or a far-off cliff[end if]. [lagoon exit finish], capped by the distant wooden shack". The exits line of Center Low Tide is "distant boulders, rise, beach". Understand "distant" or "boulder" or "boulders" as South Low Tide. Understand "beach" or "shack" as Outside Hut. Understand "far" or "off" or "far-off" or "cliff" as North Low Tide.

The exits text of North Low Tide is "The lagoon curves to[if dir] the south, while a rocky butte rises out of the water to the north[otherwise]wards its center, but ends near near a rocky butte[end if]. [lagoon exit finish]". The exits line of North Low Tide is "lagoon, beach". Understand "lagoon" as Center Low Tide. Understand "beach" as North Beach.

To say lagoon exit finish: say "[if low tide]The tide breaks to[end if][if rising downtide or falling downtide]The tide washes in from[end if][if rising uptide or falling uptide or high tide]The ocean stretches further to[end if] [if dir]the west[otherwise]one side[end if], while to the [if dir]east[otherwise]other[end if] is [if rising uptide or falling uptide or high tide]the[otherwise]more[end if] beach". 


The rayfish plaque is a plaque in Center Low Tide.

To say a sentence about the ocean swells:
	if tidein begin;
		if raining, say "Rain falls down on you from above, waves surge around your waist from below, and thousands of tiny raindrop splashes on all sides ensure you are thoroughly soaked. At least it's all warm water";
		otherwise say "Warm seawater [if evening or sunset]sparkles brilliantly and [end if][if twilight]still glows under the failing light and [end if]surges about your waist as you wade through the [if night]blackened [end if]lagoon, the sand like wet velvet under your feet";
	otherwise;
		if raining, say "The soft drumming of rain on wet sand fills your ears. Curtains of rainwater wash down the saturated beach, the line between sea and land turned into one between salt water and fresh";
		otherwise say "[if rising downtide or falling downtide][one of]The warm surf feels good as it swirls around your ankles, first tugging in one direction, then another[or]The warm tide crashes over your feet, here where it meets the land[location random][otherwise][one of]Wet sand marks the edge of the beach, only the most energetic breakers nipping at your toes[or]The sand is smooth and damp here near the low-tide mark, sprinkled with a profusion of shells, small stones, and clumps of seaweed[location random][end if]";
	end if.

Report going from Tiderooms to Beachfront: say "[if tidein]You slosh your way towards the shore, push past the breakpoint where the gentle swells break into knee-high waves, and finally clamber up onto the sand[otherwise]You hike up the drying beach, leaving the soft crash of the surf far behind[end if].".

Report going from Beachfront to Tiderooms: say "[if tidein]You wade out into the surf. The lagoon is shallow enough that you walk quite far before the water climbs past your knees[otherwise]You amble down the white sand beach towards the distant tide line[end if].".

Report going from Tiderooms to Tiderooms: say "[if tidein]You wade your way through the clear lagoon waters, parallel to the shoreline[otherwise]You follow the edge of the surf around the gentle curve of the beach[end if].".

Instead of going north in North Low Tide: say "The rocks in that direction are too sharp."

Instead of going west in Tiderooms: try vague swimming.

Instead of vague swimming when location is in Tiderooms or Beachfront:
	if raining, say "Aren't you wet enough already?";
	otherwise say "You[if location is Tiderooms and tidein] [otherwise] wade out into the surf and [end if]dive forward. [if night]The glowing mantas beneath you and the great galaxy above make this seem like a dream, but it feels real when your muscles begin to complain[otherwise][one of]Paralelling the shore, you do a few strokes under the [light source][or]Eagerly, you swim out a bit and then back in, enjoying the scenery[location random]. [one of]It feels good to stretch your muscles a bit, and the water is warm and refreshing[or]The exercise does you some good, and the conditions are nearly perfect[location random][end if]. After a few laps you [if location is Tiderooms and tidein]stand back up[otherwise]wade back onto shore[end if][if day], the tropical heat quickly baking you dry[end if].".

The ambiance table of Tiderooms is the Table of Tiderooms Ambiance.

Table of Tiderooms Ambiance
frequency	start time	end time	text	table		trigger	flag
common		rising uptide	falling uptide	"A clump of seaweed drifts by, bobbing gently in the surf."
common		night		--		--	Table of Manta Ray Ambiance
common		rising uptide	falling uptide	--	Table of Fish Ambiance
uncommon		rising uptide	falling uptide	"A big swell surges by, momentarily wetting you to your chest."
rare		rising uptide	falling uptide	--	Table of Sea Turtle Ambiance

Table of Fish Ambiance
frequency	text	table		trigger	flag
common		"A school of reddish-silver fish dart past your knees."
common		"A silvery fish shoots by at high speed like some undersea arrow."
uncommon	"A yellow puffer fish drifts by, tiny fins straining against its bulky mass and the swirling waters of the lagoon."
uncommon	"A large red fish darts in from nowhere to snap up a tiny silver fish, as the others in its school scatter in all directions."
uncommon	"A long skinny fish, its scales a flourescent green sheen in the [light source], circles playfully around you a few times before darting off."

Table of Sea Turtle Ambiance
frequency	text	table		trigger	flag
common		"A sea turtle swims past you, surprisingly graceful, its scaled legs kicking and shell bobbing along, just touching the surface."

Table of Manta Ray Ambiance
frequency	text	table		trigger	flag
common		"A huge glowing manta ray swims past you like a great blue ghost."
common		"The blue glowing mantas seem to dance through the water around you."
uncommon	"A glowing blue manta glides effortlessly past your feet, momentarily brushing them with silken-smooth wings."



Section - Hut

The printed name of Hut is "Inside the Shack". Instead of describing when the noun is Hut:
	say "Sand drifts around the open doorjam, spilling out in tiny dunes across the wooden floorboards[if Back Room has been visited] disturbed only by your footsteps[otherwise], undisturbed[end if]. [if we have greeted Progue]If Progue lives here, he must not enter often. [end if]The room ";
	if raining, say "is gloomy and indistinct, seeming somehow to share some intangible qualities with the storm raging outside";
	otherwise say "[if sunset or evening]is lit up as the setting sun shines in through the doorway[end if][if afternoon or midday or midmorning or morning]is bright with the scattered light of the white beach, brilliant once your eyes have adjusted to the interior[end if][if sunup], but something about it seems desolate and indistinct, nonetheless[end if][if sundown]seems ghostly in the gloom, like a place long deserted[end if]";
	say ". A rotting hammock and a small wooden table seem to be the only adornments.

An open doorway leads into a smaller room at the back of the house.".

The exits text of Hut is "Doorways lead back out to the beach, or farther in to a smaller room at the back of the house." The exits line of Hut is "back room, beach". Understand "beach" as Outside Hut. Understand "smaller" or "doorway" as Back Room. Report going west from Hut: say "You step back outside into [if raining]the rain[end if][if not raining and sunup]the sunlight[end if][if not raining and sundown]the night[end if], walking down the beach in the direction of the surf." Report going east from Hut: say "You duck through the small doorway into a smaller room."

Hutsand is a prop in Hut. Understand "sand" or "drifts" or "tiny" or "dunes" as hutsand. The description is "The sand is piled a few inches high near the door, arcing down to mere grains near the center of the room. It seems undisturbed, although how long it would take the beach winds to smooth out any footsteps you do not know."

A rotting hammock is a setpiece in Hut. The description is "Expertly weaved from some variety of thick vegetable fiber, the hammock must once have been a thing of beauty. Now, the tiny strands are brown and rotting, frayed near the stress points." Instead of entering the hammock, say "It doesn't look as if it would support your weight." Instead of taking the hammock, say "It looks as if it would fall apart in your hands."

A small wooden table is an undescribed supporter in Hut. The description is "Bending down to examine this small table, you are taken aback by the level of detail that went into its construction. It seems be made of a number of rounded wooden pieces that fit together seamlessly, with no nails or other force to hold them together. The edges of the smoothingly curved legs are covered with intricate carvings, and a delicate pattern is inlaid into the table's top.

[if we have examined the sketchbook]On the table is the oversized sketchbook[otherwise]Resting askew atop the table, as if thrown aside carelessly, is an oversized sketchbook, its cover badly weathered[end if]."

Instead of taking the table, say "You could probably move it easily, but something about the barren quietude of the room dissuades you from disturbing it."

The intricate carvings are part of the table. The description is "The carvings are impossibly tiny, and as you peer closer, seem to be all part of one immense, tropical seam. Splashing dolphins segue seamlessly into beaches littered with shells, tall, graceful palm trees, laughing children, and fanciful animals. You could study these carvings for hours without taking in all the detail. After a while you pull back, impressed." Instead of touching the carvings, say "The relief is only as deep as a fingernail, but seems to lend the carvings a remarkable sense of depth and dimension. You run your finger along the aging wood, feeling the texture of the grain and the artist's tool." 

Progue's sketchbook is a described prop on the table. The description is "You examine the sketchbook carefully. Its thick cover is covered in inkblots, dirt, and water damage, but as you open it you see the inside seems largely undamaged.[line break][current sketchbook page][paragraph break]It looks like you could see other drawings if you turned the page.". Understand "page" or "notebook" or "drawing" or "book" or "sketch" as the sketchbook.

The sketchbook has a number called current page. The current page of the sketchbook is 1. To say current sketchbook page: let n be the current page of sketchbook; choose row n in the Table of Progue's Sketchbook; say "[desc entry]".

Instead of turning the sketchbook:
	increase the current page of sketchbook by 1;
	if current page of sketchbook is greater than the number of rows in Table of Progue's Sketchbook begin; 
		now the current page of sketchbook is 1;
		say "You seem to have reached the end of the sketchbook. Your close it again.";
	otherwise;
		say "You turn the page to study the next drawing.[line break][current sketchbook page][if the current page of sketchbook is at most the number of rows in Table of Progue's Sketchbook][paragraph break]It looks like you could see other drawings if you turned the page.[end if]";
	end if.

Table of Progue's Sketchbook
desc
"The first drawing is a portrait study of two girls, maybe about nine or ten. The artist's skill is remarkable: the faces seem so lifelike that you instantly feel you know the subjects. Their long straight black hair frames faces that, while retaining some of the whimsy of childhood, have already seen sadness and begun to age. The girls, who at first you take for twins, do in fact have subtle differences of appearance-- the one with a slightly broader chin, the other with a tiny mole here, a divet in the ear there-- but the expression each wears is nearly identical. Though they are not looking at each other, you can sense the bond between them, forged in loss and strengthened by the constant companionship of the other. It is a remarkable sketch."
"This next sketch is a landscape. You recognize at once the beach outside, and the half-constructed hut against the tumble of volcanic rock. The two girls are playing in the sand, one of them on hands and knees studying a fleeing crab intently, the other concentrating intently as she constructs a sand castle. Behind them, a tall masculiine figure labours to chop branches of a tree trunk lying in the sand. The figure is drawn curiously, however; while the beach scene and the girls are sharp and finely detailed, the main is fuzzy and dark, indistinct, drawn with heavy, crude lines. His presence, though only a small part of the scene, seems to somehow throw the rest of the sketch into a sadder, more somber mood."

Progue is a person.


Section - Back Room

The printed name of Back Room is "Shack, Back Room". Instead of describing when noun is Back Room:
	if night or dawn or twilight or raining, say "Hardly any light at all filters into this windowless back room. Shapes are jumbled and indistinct.";
	otherwise say "Only a dim light filters into this windowless back room. As you study the back wall, you see it is actually the smoothed face of the lava flow. A wide crack in the mirror-smooth black stone [if lava tunnel door is closed]is blocked by cobblestones and a thick wooden door, inlaid with an elaborate map and row of symbols[otherwise]leads through the open doorway into darkness[end if].

Other than the door and some splintered wood in a corner, the only exit is back to the front room."

The exits text of Back Room is "The open doorway back to the front room and in the imposing wooden door [if lava tunnel door is open]leading into the fissure [end if]are the only two exits."

The lava wall is a setpiece in Back Room. The description is "The lava flow is nearly vertical here, and sharp edges have been smoothed and polished away to make a gently rippling, deep black surface." Instead of touching the lava wall, say "Smooth and glasslike, although quite hard." Instead of pushing the lava wall, say "It gives not at all."

The lava tunnel door is east of Back Room and west of Fissure. The lava tunnel door is a closed locked undescribed door. The description is "Only just your height but wider than a normal door, the wooden surface of this portal has been planed smooth, bringing out the complex grain. In the center of the door is a remarkable map[if we have examined the lava tunnel door] of the island[otherwise], carved with equisite detail directly into the wood. After a moment's study you would guess it is of this island[end if]. Tiny relief lines etched into the surface delineate the high points from the low.

Below the map is a smooth arc of ten [if we have examined the lava tunnel door]buttons engraved with symbols[otherwise]stylized symbols. Upon careful examination you notice tiny lines that form a square around each one, as if they are seperate pieces from the main wood[end if]. From left to right the symbols are: volcano, manta ray, turtle, tree, seagull, dragonfly, galaxy, whale, thunderhead, and wave.". Understand "map" or "relief" or "lines" as lava tunnel door.

Instead of opening or pulling or taking the lava tunnel door when the door is closed, say "You see nothing that looks like a handle, and the edges of the door are perfectly flush with the hardened lava." Instead of vague unlocking the door, say "You don't even see a keyhole." Instead of pushing the lava tunnel door when the door is open, try closing the lava tunnel door. Instead of pushing the lava tunnel door, say "You brace yourself and shove against the door with your shoulder, but it doesn't even creak, let alone budge.". Instead of attacking the lava tunnel door, say "You take a running start and ram against the door with your shoulder, but gain nothing but a bruise. The door is solidly constructed and whatever mechanism holds it fast is sturdily built.". Instead of looking under the lava tunnel door, say "The door is almost flush with the floor and surrounding masonry; you cannot see beyond it."

A lava door button is a kind of setpiece. Understand "symbol" as a lava door button. The description of a button is usually "The small button is carved out of wood, the symbol beautifully inlaid into its surface[if we have examined something plaquelike]. They seem to be in the same style as the symbol you saw on the plaque[end if]." Instead of taking a button, say "The symbols seemed to be attached to the door."

To add (n - a thing) to the button table:
	let oldrow be 4;
	while oldrow is at least 1 begin;
		let newrow be oldrow + 1;
		if there is a button in row oldrow of the Table of Buttons Pushed, change the button in row newrow of the Table of Buttons Pushed to the button in row oldrow of the Table of Buttons Pushed;
		decrease oldrow by 1;
	end while;
	change the button in row 1 of the Table of Buttons Pushed to noun.

A procedural rule: if the noun is a lava door button, ignore the can't push what's fixed in place rule.

After pushing a lava door button:
	say "[one of]With a soft clunking sound, the button depresses into the door, then pops back out as you release it[or]The button depresses with a soft clunk, then pops out again[stopping].";
	add noun to the button table;
	if the button in row 1 of the Table of Buttons Pushed is the galaxy button and the button in row 2 of the Table of Buttons Pushed is the dragonfly button and the button in row 3 of the Table of Buttons pushed is the tree button and the button in row 4 of the Table of Buttons Pushed is the wave button and the button in row 5 of the Table of Buttons Pushed is the manta ray button begin;
		now the lava tunnel door is open; now the lava tunnel door is unlocked;
		say "[line break]With a heavy clunk and a wooden grinding, the door swings open, revealing a fissure running into the black lava rock.";
	end if.

A procedural rule: ignore the can't go through concealed doors rule.

The volcano button is a lava door button. The manta ray button is a lava door button. The turtle button is a lava door button. The tree button is a lava door button. The seagull button is a lava door button. The dragonfly button is a lava door button. The galaxy button is a lava door button. The whale button is a lava door button. The thunderhead button is a lava door button. The wave button is a lava door button.

When play begins: now all lava door buttons are part of the lava tunnel door.

Table of Buttons Pushed
button
an object
with 5 blank rows


Part - North Island

North Island is a region.

Section - Rise

Rise is a room in North Island. Rise is northwest of North Beach. Instead of describing when the noun is Rise:
	if raining begin; say "The land drops off on either side of this rise, though the misty rain prevents you from seeing too far in either direction";
	otherwise;
		say "From this small rise, you can see the whole north end of the island stretched out before you";
		if Rise is unvisited then say ". Some distance ahead, near a small wooden shed, the shore curves around to the east. The ground slopes down from here into a low marshy area fed by a stream trickling down from somewhere nearby. [A sentence about the mountain]. Stretching from near the peak to the small shed are two parallel cables, supported in the center from a rock rising out of the marsh";
		otherwise say ", [a phrase about the mountain]. Tenuous cables rising above the swamp connect the peak to a shack on the island's northwest corner";
	end if;
	say ". The beach is to the south, while through some trees to the east [if Hot Springs is unvisited]is the sound of falling water[otherwise]lie the hot springs[end if].".
		
The exits text of Rise is "A faint path winds down north[if day]through some tree stumps towards the shack and the marsh[end if], and you can hear water falling through some brush to the east. A[if day]n easy[end if] scramble down the rocks to the south leads back to the lagoon".

Report going north from Rise: say "You follow the path down a slight mossy slope, enjoying the unobstructed panorama before you." Report going east from Rise: say "You push great leafy fronds out of the way[if raining or rained], shivering as water drips all over you,[end if] and after a few moments break out of the vegetation atop a short rise." Report going southeast from Rise: say "You pick your way [if night]carefully [end if]down the cluster of boulders, [if night or twilight or dawn]taking care not to twist an ankle in the gloom[otherwise]using your hands just to be safe[end if], till your feet touch the smooth beach sand again."

The ambiance table of Rise is the Table of Rise Ambiance.

Table of Rise Ambiance
frequency	start time	end time	text	table		trigger	flag
common		sunrise	sunset	--	Table of Seagull Air Ambiance
rare	sunrise	sunset		"A gull lands by a tiny stream trickling out of the overgrowth and drinks deeply, then begins to clean itself." 	--	seagull
uncommon		--	--	"The distant cables of the chairlift sway gently in the [if morning or midmorning]morning [end if][if afternoon]afternoon [end if][if evening or sunset]evening [end if]breeze."
uncommon		--	--	"A faint sighing sounds from the chairlift cables as they vibrate imperceptibly in the wind."
uncommon	--	--	--	Table of Lacuna Weather Ambiance
uncommon		morning	twilight	--	Table of Lacuna Insect Ambiance

Table of Lacuna Weather Ambiance
frequency		text	table		trigger	flag
common	"A gust of wind catches your hair, tousseling it this way and that before dying down."
common	"[if day]The sun ducks behind a high, fast moving white cloud for a moment, then returns to its former brilliance[end if][if night and moonup]High clouds cover the face of the moon, but in only moments they have moved on[end if][if night and moondown]Faint patterns of clouds move over the galactic spectacle above, as if the stars are one by one winking out and then returning[end if]."
rare		"A drop of water touches your hand. [if rained]Glancing up, however, you see the clouds have mostly moved on[otherwise]Looking up, however, you see no cause for alarm[end if]."

Table of Lacuna Insect Ambiance
frequency		text	table		trigger	flag
rare		"A small red beetle inches its way carefully along the ground near your foot."
rare		"A small black bug twirls past your head, its wings making a dull, lazy buzz."
rare		"A swarm of tiny winged insects, each no bigger than a pinhead, drifts by with the breeze."
superrare		"A tiny spider drifts by on a gust of wind, strands of web catching on a clump of vegetation before it frantically scurries out of sight."

Section - Hot Springs

Hot Springs is a room in North Island. Hot Springs is east of Rise.

Instead of describing when the noun is Hot Springs:
	if night begin;
		say "[if moonup]A single beam of moonlight pierces[otherwise]Only the faintest hint of starlight penetrates[end if] this natural bowl, where a barely-glimpsed waterfall cascades into a hidden pool. [if moonup]Steam dances off the surface of the pool, silver in the moonlight. [end if]The gap leading back to the open is hardly visible, but you think you remember the way.";
	otherwise;
		if dawn or twilight, say "The magical stillness of the half-light is broken, but not completely dissipated, by a clear waterfall cascading into a beautiful pool of deep cerulean";
		if midday, say "Sunlight beams down into this natural bowl, turning the waterfall churning into a round blue pool into thousands of tiny sparkling gemstones, and the surface of the pool itself into a mirror for the cloudless sky";
		otherwise say "Tucked away in a natural bowl, hidden from view, this beautiful pool of deep cerulean is fed by a clear waterfall cascading down from an overhang above";
		say ". Steam rises from the almost perfectly circular pool, which looks deep enough for diving but not so deep that the blue-tinted floor is not visible. [exits].";
	end if.

The exits text of Hot Springs is "A gap in the trees marks the way back out to the open".

The waterfall is a setpiece in Hot Springs. The description is "Stretching about twice your height above the surface of the pool, the waterfall cascades over a natural overhang in the rock[if midday or afternoon], sparkling brightly in the sun overhead[end if]. [if night and moonup]The moonlight brings the complex interplay of water and air to life, an animate sculpture in glass. [end if][if evening or sunset]Beams of failing sunlight penetrating the thick vegetation to the west light up the water intermittently, tiny rippling lines of red illuminating its crystal surface. [end if]The water is surprisingly cool, tempering the hotter liquid bubbling up into the pool from below.". Before touching the waterfall, say "The water is surprisingly cool, running over your hand in thick ribbons of liquid force, smelling faintly of moss and earth." instead. Instead of drinking or taking the waterfall, say "The water thunders down with enough force that you cannot hold any in your hands.".

The pool is an enterable setpiece in Hot Springs. The description is "Striking blue, the surface of this round pool constantly shifts and dances as the waterfall churns it. The waterfall seems to have deepened a natural depression under the mossy overhang, making the pool deep enough for diving, while shallow enough near the far end to comfortably sit on some smoothed submerged rocks. The water is hot and steaming, simultaneously warmed by some scalding source below and cooled by the waterfall." Instead of touching the pool, say "The water is hot, but not uncomfortably so." Instead of tasting the pool, say "You cautiously sip a bit of water gathered in your hand. It seems all right." Instead of drinking the pool, say "Bending to your knees, you scoop a few handfuls of the pool water to your mouth and drink deeply. It is exceedingly refreshing, the taste holding a faint hint of something green. After drinking your fill, you rise to your feet again." Instead of taking the pool, say "You cup two hands together and scoop some of the hot water from the pool, feeling it immediately cool as it trickles through your fingers down your arms to your elbows. You let the water trickle away and enjoy the cool sensation as your hands dry." Understand "water" or "natural" or "bowl" or "hidden" or "blue" or "cerulean" or "perfectly" or "circular" or "round" or "depression" or "far" or "end" as the pool.

Instead of vague swimming when location is Hot Springs, try entering the pool. Instead of swimming in pool, try entering the pool.

After entering the pool, say "With a little thrill of excitement, you dive into the pool. The water is hot, almost too much so for swimming, but feels invigorating and cleansing nonetheless. When you near the waterfall, you can feel the temperature difference between it and the pool distinctly, invisible eddies of heat transference swirling about your legs.

After a while you retreat to the rocks near the shallow end of the pool, and relax for a while in the [if evening or sunset or twilight]fading light[end if][if morning or midmorning]morning air[end if][if midday or afternoon]tropical sunlight[end if][if night]cool night air[end if][if dawn]growing light[end if].".

After exiting when the player is in Hot Springs, say "You climb out into the now chilly-seeming air[if sunup], drying off quickly in the warm breeze[end if]."


Book Two - Treeworld

Chapter - Definitions

Chapter - Views and Backdrop

The Distant Philosopher is a backdrop. Understand "tree" or "gigantic" or "withered" as The Distant Philosopher. The Distant Philosopher is in Top of Spire, Reflecting Pool, Avenue South, Mural Center, and Avenue North. Understand "gigantic", "withered", "tree", "great" as the Distant Philosopher. The description is "The Tree is massive, far, far larger than any you saw on Lacuna. A great set of sweeping stone steps, huge twisted roots running down and around them, runs up to a tiny entrance at its base. The tree itself seems very old, but strong."

The brick pathways are a backdrop. Understand "pathway" or "path" or "paths" or "well-tended" or "road" or "brick" or "bricks" as the pathways. The pathways are in Reflecting Pool, Avenue South, Outside the Dome, Among the Huts, Ancient Temple, Avenue North, and Row of Sheds. The description is "Made of small rounded bricks, ranging in shade between yellow and pink." After touching the pathways, say "Near the center of the path, the warm bricks are rubbed smooth by generations of feet."

Chapter - Ambiance

The ambiance table of Plateau is the Table of Treeworld Ambiance.

Table of Treeworld Ambiance
frequency	start time	end time	text	table		trigger	flag
uncommon		--	--		--	Table of Butterfly Ambiance		butterfly
uncommon		--	--		"[one of]Wind gusts through the forest, sending rippling currents like living creatures through the branches.[or]Leaves swirl in tiny eddies as a hot breeze stirs them up.[or]Harmonic tones in varying pitches sound all around you as a breeze gusts over the plateau.[at random]"
uncommon		--	--		"[one of]Ghost thoughts tug at your mind, whispers of half-heard ideas and dreams.[or]For a moment, you can sense ripples of thought rolling through the forest, slow, but inexorable-- then the sensation passes.[or]Looming somewhere nearby is the presence of an enormous mind. You can feel it, even from this distance.[at random]"
uncommon		--	--		"[one of]Somewhere through the trees is the faint sound of shears.[or]Through the trees you catch a glimpse of a group of red-robed figures, gliding with measured grace along a path.[or]From some faint distance, you think you catch an echo of children's laughter.[at random]"

Table of Butterfly Ambiance
frequency	text	table		trigger	flag
common	"Wings spread wide, a huge yellow butterfly drifts by, hardly flapping as it floats on updrafts."
common	"Two huge yellow butterflies flap gently by, on their way somewhere in the forest."
uncommon		"A large yellow butterfly alights delicately on a tree branch, fanning its wings majestically."
uncommon		"In the sky above you, a flock of huge butterflies drift in the breeze, the red sun lighting up their thin wings like lanterns."

A butterfly is an animal. The description is "Its wingspan is as wide across as your torso, and the wings are thin and delicate."


Chapter - Creatures

The verb to know (it knows, they know, it knew, it is known) implies the carrying relation.

A Lacunite is a kind of person. A Lacunite has some text called descriptor. The descriptor of a Lacunite is usually "man". [Understand "alien" as a Lacunite.]

A robe is a kind of thing. A robe is worn by every Lacunite. The description is "The robe is fashioned from something thin with the texture of felt. A deep, rich red, it is wrapped simply around the owner and trails on the ground behind."

[Rule for printing the name of a Lacunite (called subject): say "[one of][if subject is male]he[otherwise]she[end if][or]the [if a random chance of 1 in 2 succeeds]alien [end if][descriptor of subject][at random]".]

A simple robe is a robe. A simple robe is worn by the player.

The Treeworld Hivemind is an undescribed transparent closed container. The Treeworld Hivemind is either known or alien. The Hivemind is alien. [This tracks whether we've talked to it before.] 

The Hivemind has some text called the greeting text. The Hivemind has some text called the farewell text. The greeting text of Hivemind is "[if Hivemind is alien]'Greetings. Welcome to our world, friend of Progue. You must have many questions. I will answer what I can.'[otherwise]'Greetings. What other questions do you have?'[end if]". The farewell text of Hivemind is "[if Hivemind is alien]'You are free to explore this place, as long as you wish. When you are ready, the Great Philosopher would speak with you.'[otherwise]'It has been a pleasure.'[end if]".

After going when the player is in Treeworld: now the Treeworld Hivemind is in location; continue the action.

After saying farewell to when the alien Hivemind is in location: now Hivemind is known; continue the action.

A beat called t_whereami with printed name "this world" is in Treeworld Hivemind. The description of t_whereami is "'This is our world,' [snl] says, hands spreading to encompass the whole vast landscape, 'the Heart of the Forest.'". Understand "where am i" or "where" or "place" or "here" or "world" or "this" or "planet" as t_whereami. 

A beat called t_questions with printed name "your questions" is in Hivemind. The description of t_questions is "'Yes,' [snl] says, 'so many things must be strange to you. This world and this place you stand in and why and how it came to be; your friend who came before and where to find the way back. Ask, and I will answer.'" The followup of t_questions is "I can tell you about our world, about this shrine you stand in, about why you were brought here, about how you can return to Lacuna, or about our history,' [snl] says." Understand "many" or "question" or "questions" as t_questions. In it are t_shrine, t_return, t_brought and t_history.

A beat called t_strangebody with printed name "the body you inhabit" is in Hivemind. Understand "me" or "body" or "who am i" or "hands" or "body you inhabit" or "inhabit" as t_strangebody. The description is "'Do not be alarmed,' [snl] says. 'Only your mind has travelled here. Your body is still on the world of Lacuna, but the one whose reflection you see has lended you his body and senses, for as long as you visit here.'". After examining the t_strangebody: now LYPNflag is 1.

t_shrine is a beat with printed name "the plateau". Understand "shrine" or "place" or "plateau" as t_shrine. The description is "'This is a sacred place,' [snl] says with a curious lack of inflection, 'a garden built to honor one of our greatest Philosophers. He stands at the end of this avenue, the mightiest and wisest for a great distance.

'He desires to speak with you,' [snl] adds, 'when you are ready.'". 

t_history is a beat with printed name "the history of this place". Understand "history" or "your history" or "mural" or "place" or "this" as t_history. The description of t_history is "'Our history is as long and complex as any of the worlds we have found,' [snl] says, 'but unlike some, most of it can be told in a single story. How the Two Became One. There is a mural that tells this story, if you would care to know it,' [snl] adds, pointing [best route from the location to Mural Far West].". The followup is "'The mural will explain far better than my words,' [snl] says, pointing to the [best route from the location to Mural Far West]."

A beat called t_philosopher with printed name "the Great Philosopher" is in Hivemind. Understand "great" or "greatest" or "philosopher" as t_philosopher. The description of t_philosopher is "'When you are prepared, go to him at the end of the great avenue,' [snl] says, pointing [best route from the location to Base of the Great Tree]. 'But there is no hurry. He is very patient.'".

t_return is a beat with printed name "how to return to Lacuna". Understand "how" or "return" or "lacuna" as t_return. The description is "'Now that the trees and the transmitter on Lacuna have learned to hear your mind,' [snl] says, 'you may come here whenever you wish. To return, simply close your eyes, and when you open them again, you will be back in your own body.'"

t_brought is a beat with printed name "why you were brought here". Understand "why" or "you" or "were" or "brought" or "here" or "request" or "here" as t_brought. The description of t_brought is "'We wanted you to see our world,' [snl] replies, 'but there is also something we have to ask you. A request, we shall say. The Great Philosopher will speak more of this to you, when you are ready.'" The followup of t_brought is "'For now,' [snl] says, 'I will speak no more of this. Visit the Great Philosopher when you wish to know the rest.'"

A beat called t_collectiveness with printed name "individuality" is in Hivemind. Understand "individuality" or "we" or "who" or "you" as t_collectiveness. The description of t_collectiveness is "'Yes,' [snl] smiles, 'when your predecessor came he too was confused. I speak to you with the voice of not just my own mind, but the whole Forest of minds that stretches across this planet and many others. I have my own mind and thoughts, but I share them with the Trees, and they in turn share their wisdom, advice, and genius with me. It is a humbling and noble experience.'" In t_collectiveness is t_Forest.

t_Forest is a beat with printed name "the Forest". Understand "great" or "forest" as t_forest. The description of t_Forest is "'In many ways, the Forest is like one vast mind,' [snl] says eagerly, 'but in many ways not. Thought spreads like ripples from Tree to Tree, propogating if it is useful and dieing out if not. The people, like me, can hear these thoughts if the Trees desire to share them to us, though we cannot understand them all.'"

A beat called t_Progue with printed name "Progue" is in Hivemind. Understand "Progue" or "predecessor" as t_Progue. The description of t_Progue is "'Some time ago, he came to us as you did,' [snl] says. 'The Trees on Lacuna have told you that story, as, perhaps, did he.'"

To say snl: 
	let subject be a random Lacunite in the location;
	say "[one of][if subject is male]he[otherwise]she[end if][or]the [descriptor of subject][at random]".


Chapter - Rooms

Plateau is a region. 



Great Forest Overlook is east of Top of Spire. Top of Spire is northwest from Great Forest Overlook. Southeast of Top of Spire is nowhere. West of Great Forest Overlook is nowhere. Reflecting Pool is down from Top of Spire. Avenue South is northwest from Reflecting Pool. Avenue South is northeast from Reflecting Pool. Reflecting Pool is southeast from Avenue South. Reflecting Pool is southwest from Avenue South.

Outside the Dome is west of Avenue South. Map Room is south of Outside the Dome. Map Room is inside of Outside the Dome. Mural Far West is west from Outside the Dome. Outside the Dome is southeast from Mural Far West. Among the Huts is east of Avenue South. Bare Hut is south of Among the Huts. Bare Hut is inside of Among the Huts. Mural Far East is east from Among the Huts. Among the Huts is southwest from Mural Far East. Northeast of Among the Huts is nowhere. 

East of Mural Far West is a room called Mural West. East of Mural West is Mural Center. East of Mural Center is a room called Mural East. East of Mural East is Mural Far East. Mural Center is north of Avenue South. Avenue North is north of Mural Center. Shrine is inside of Ancient Temple. Shrine is north of Ancient Temple. Ancient Temple is west of Avenue North. Mural Far West is west of Ancient Temple. Ancient Temple is northeast of Mural Far West. Southwest of Ancient Temple is nowhere. Row of Sheds is east of Avenue North. A room called Inside a Shed is inside from Row of Sheds. North of Row of Sheds is Inside a Shed. Mural Far East is east from Row of Sheds. Row of Sheds is northwest from Mural Far East. Southeast of Row of Sheds is nowhere. West of Mural Far East is Mural East. Mural Far West is west of Reflecting Pool. Reflecting Pool is south of Mural Far West. North of Reflecting Pool is nowhere. Mural Far East is east of Reflecting Pool. Reflecting Pool is south of Mural Far East.

Base of the Great Tree is northeast of Avenue North. Base is northwest of Avenue North. Avenue North is southeast of Base. Avenue North is southwest of Base. North of Base of the Great Tree is Inside the Great Philosopher. Inside from the Great Tree is Inside the Great Philosopher.

Great Forest Overlook, Top of Spire, Reflecting Pool, Outside the Dome, Avenue South, Among the Huts, Mural Far West, Mural West, Mural Center, Mural East, Mural Far East, Row of Sheds, Avenue North, Ancient Temple, and Base of the Great Tree are in Plateau.

A region called Treeworld is a region. Plateau, Inside the Great Philosopher, Inside a Shed, Map Room, Bare Hut, and Shrine are in Treeworld.


Section - Rebel Signal Scene

Finding the Rebel Signal is a scene. Finding the Rebel Signal begins when valid ember.

To decide whether valid ember:
	if the location contains a Lacunite, no;
	if the ftrs_room is the location, no; [we have to move on for it to appear again]
	if Finding the Rebel Signal ended successfully, no;
	if the player is in Plateau for less than 10 turns, no;
	if a random chance of 1 in 5 succeeds, yes.
	
Finding the Rebel Signal ends unsuccessfully when the player is not in Treeworld or a Lacunite is in the location or the ember is not in the location. 

When Finding the Rebel Signal begins: move the ember to the location; say "Out of the corner of your eye, a curious light suddenly appears."

Every turn when the ember is in the location: 
	if the ember is in the location for the first turn, say "The ember drifts slowly at the edge of your vision.";
	if the ember is in the location for the second turn, say "Slowly, the yellow-green light circles around, just outside of your ability to see it clearly.";
	if the ember is in the location for the third turn, say "The ember drifts slowly closer to the center of your vision, but you still cannot see it clearly.";
	if the ember is in the location for the fourth turn, say "The ember drifts still closer to you, seeming to exhibit some sort of intentionality.".

Finding the Rebel Signal ends successfully when the ember is in the location for the sixth turn. When Finding the Rebel Signal ends successfully, say "The ember drifts directly in front of your field of vision, and you can finally see it clearly. It is a symbol...[line break]With a sort of mental click, the symbol disappears from view. It leaves no afterimage, but you can still picture the signal very clearly in your mind."

When Finding the Rebel Signal ends, remove the ember from play.

The ember is a described prop. "A tiny yellow-green spark floats serenely in your peripheral vision." Understand "spark" or "light" as the ember. Instead of examining the ember: remove the ember from play; say "As you look over at the spark it instantly disappears. [if ftrs_room is in Plateau][paragraph break]You notice this time that, although it was intensely bright, the light leaves no afterimage on your retinas.[end if]"; now the ftrs_room is the location.

The ftrs_room is a thing that varies. 

Section - Great Forest Overlook.


Great Forest Overlook is a room in Plateau. 

Instead of describing when the noun is Great Forest Overlook:
	say "[if unvisited]...and a moment later lower it, blinking in unexpected brightness and a rich smell of earth and leaves.
	
[end if]You [if unvisited]kneel[otherwise]stand[end if] on a curved platform jutting out over a cliff, overlooking a vast forest of Lacuna trees that stretches in every direction. A huge red-gold sun burns near the horizon, throwing brilliant reflections off the hundreds of streams winding through the forest and illuminating millions of leaves. [exits].[if unvisited][line break]Shaking off vertigo, you rise to your feet. As you do, an earth-covered spade slips from your hand.[end if]". Understand "path" or "edge" as Top of Spire. The exits text of Great Forest Overlook is "A well-kept path curves around the edge of the cliff[if dir] to the northwest[end if]"

Every turn when the location is Great Forest Overlook and the viney plants are undescribed, now the plants are described.

Some viney plants and a gardening spade are props in Great Forest Overlook. Understand "vine" or "vines" or "ivy" as the plants. Understand "soil" or "earth" as the spade. The initial appearance of the plants is "On the ground are some carefully tended vines and a few simple gardening tools." The description of the plants is "Ivy-like, with long skinny leaves fading slowly from green to reddish gold. The patch runs along the edge of the platform, immaculately tended." Instead of taking the plants, say "You see no reason to rip them from the ground." The description of the spade is "The spade is a simple tool, worn from use and stained with fresh, damp earth." Instead of taking the spade, say "You can't think of anything to gain by carrying it around." Instead of smelling the spade, say "The soil smells rich, almost heady." Instead of touching the spade, say "The damp soil feels thick and crumbly under your fingertips."

The overlook vista is a view in Great Forest Overlook. Understand "forest" or "trees" or "streams" or "leaves" as the vista. The description is "The vista is spectacular in the light of the sinking sun. As you study the landscape, you begin to think that the streams are placed too regularly to be wholy natural."

The huge red-gold sun is a view in Plateau. The description is "The star seems much larger and yet dimmer than the one on Lacuna; you can almost look directly at it. Distant clouds passing before it near the horizon emphasize its massive bulk; the reddish-gold light pouring from it is spectacular."

Report going northwest from Great Forest Overlook: say "You walk along the path around the edge of the boulder, bringing the top of a forested plateau into view."

Section - Top of Spire

Top of Spire is a room in Plateau. 

Instead of describing when the noun is Top of Spire: say "You stand on a short, rocky spire atop a great flat ridge, running far off towards snow-capped mountains in the distance. [exits]. [if unvisited][paragraph break]Your heart catches for a moment as you take in another detail: you can also see people, clad in brown, walking amongst the trees or tending to plants along the avenue.[end if]". The exits text of Top of Spire is "Carved stone steps run down this small hill, joining with a cleared grassy avenue that runs toward a gigantic withered Tree perched on the edge of the plateau. A path leads [if dir]east [end if]around the spire back to the overlook". Understand "path" as Great Forest Overlook. Understand "steps" or "avenue" as Reflecting Pool.

The distant tree_people is a view in Top of Spire. Understand "people" or "brown" as tree_people. The description is "You can make out few details from this distance. Perhaps a dozen are in sight."

Report going west from Top of Spire: say "You walk down the worn stone steps to a grassy field at the base of the outcropping."

Section - Reflecting Pool

Reflecting Pool is a room in Plateau.

Instead of describing when the noun is Reflecting Pool: say "A long, shallow reflecting pool, integrated so well into the landscape you aren't sure if it's planned or natural, reflects a broad green avenue lined with Trees gently stretching [if dir]to the north[otherwise]along the plateau[end if]. [exits2]." The exits text is "[if dir]C[otherwise]Two c[end if]arefully tended paths circle [if dir]northeast or northwest [end if]around the reflecting pool, meeting again at the grand avenue across it[if dir] to the north[end if]. [exits2]". To say exits2: say "Smaller paths disappear into trees[if dir] to the east and west[otherwise], one towards the sun and the other into shadows[end if]. Stone steps climb a rocky spire, while a much grander stair descends [if dir]to the south[otherwise]to the valley below[end if]". Understand "sun" or "toward" or "towards" as Mural Far East. Understand "shade" or "into" or "shadows" as Mural Far West. Understand "plateau" or "around" as Avenue South.

Instead of going south in Reflecting Pool, say "You step to the edge of the stairs and look down. Vertigo gnaws in your stomach: the staircase is steep and long, snaking down a sheer cliff that drops a long, long way to the forest below. Perhaps it would be best to stay on this plateau." Instead of going north in Reflecting Pool, say "The pool looks shallow enough, but it is so calm and well-tended you cannot help but take one of the paths running [if dir]northeast or northwest[otherwise]around it[end if], instead."

Going to Avenue South from Reflecting Pool is walking around the pool. Going to Reflecting Pool from Avenue South is walking around the pool. Report walking around the pool: say "You follow the path, perfectly interlocking stone tiles lined by well-tended vegetation, around the edge of the pool [if location is Reflecting Pool]to a flat spot at the base of the spire[otherwise]to the end of a broad avenue[end if]." Report going up from Reflecting Pool: say "You climb the stairs up the steep slope around the rocky spire." Report going west from Reflecting Pool: say "You follow an immaculately tended dirt path through a grove of trees (smaller, and presumably less sentient). The red sun cuts through the shade here and there in great, thick beams of light. The path slowly curves[if dir] around to the north[end if], and you finally step out into a clearing again."

LYPNflag is a number that varies. LYPNflag is 0.

Learning Your Projected Nature is a scene. Learning Your Projected Nature begins when the player has been in Great Forest Overlook for exactly one turn.  Learning Your Projected Nature ends when LYPNflag is 1.

Every turn during Learning Your Projected Nature: if the location is Reflecting Pool, add potential messages from the Table of LYPN.
	
Table of LYPN
frequency	start time	end time	text	table		trigger	flag
frequent	--	--	"Your reflection in the pool catches your eye. Something seems strange about it."

Instead of examining the player in Treeworld:
	if Learning Your Projected Nature is happening, now LYPNflag is 1;
	say "[if Learning Your Projected Nature is happening or we have examined the player]You look down at your body with astonishment: you seem to be wearing a loose red robe. But as your hands move to feel the material, you gasp in shock.
		
They are not your hands.

They are[otherwise]You seem to be wearing a loose, red robe, contrasting with your hands:[end if] brown, with long, thin fingers and nails that are almost purple. Turning them over, you see the faint callouses of a lifelong worker. Raising the strange hands to your face, you feel strange cheekbones and tight, unwrinkled flesh.";
	if Learning Your Projected Nature is happening and a Lacunite is visible begin;
		now a random Lacunite in the location is transparent;
		say "Noticing your astonishment, the [descriptor of a random Lacunite in the location] pauses. [run paragraph on]";
		try examining the t_strangebody;
	end if.
[	otherwise;
		say "This alien body is disorienting to be inside of, when you think about it, but you are astonished at how quickly you are beginning to just accept it as another strange adaptation.";
	end if.]
		

The shallow reflecting pool is a backdrop. It is in Reflecting Pool and Avenue South. Understand "long" as the shallow pool. The description is "The shallow oval pool stretches across this flat spot on the plateau. The water is crystal-clear and the edge is rimmed with flowers. Rippled reflections of the great Tree [if dir]far to the north[otherwise]at the end of the avenue[end if] and of your own distorted form shine up at you." Instead of touching the pool, say "You reach out a hand and the reflection does also. As they meet on the warm surface of the water, ripples distort the strange face into indistinct patterns."

Instead of vague swimming when the reflecting pool is visible, say "This place has a deep presence of order and sacredness: swimming in the calm pool would seem highly inappropriate." Instead of swimming in the pool, try vague swimming.

Your reflection is a backdrop. It is in Reflecting Pool and Avenue South. 

Instead of examining the reflection:
	if Learning Your Projected Nature is happening begin;
		say "As you gaze closer, you gasp in astonishment. Your reflection is not you. It is one of the creatures; large eyes gape back at you, and yellowish hands reach up to touch your face in sync with yours.";
		if a Lacunite is visible begin;
			now a random Lacunite in the location is transparent;
			say "[line break]The [descriptor of a random Lacunite in the location] notices your astonishment and pauses. [run paragraph on]";
			if a random Lacunite in the location is opaque, now a random Lacunite in the location is transparent;
			try examining the t_strangebody;
		end if;
	otherwise;
		say "You study the face staring back at you with a strange but slowly weakening feeling of something like vertigo. It is young, as far as you can tell with these people, and seems healthy. The most curious sensation is staring into the eyes: you cannot decide if you are looking at yourself or another, your mind futilely flipping back and forth, like an optical illusion of depth.";
	end if.

A strange alien woman is a female Lacunite in Reflecting Pool. "[if Treeworld Hivemind is alien]Watching you curiously as she kneels tending the flowers that grow on the pool's edge is a short  woman clad in a long red robe, her expression unsettlingly alien.[otherwise]One of the local women kneels near the pool's edge, tending the flowers that grow there.[end if]". The description is "[if we have not examined alien woman]As you look closer, it becomes apparent that she is not a woman, exactly: at least, not a human woman. The eyes are a little too large, the skin mottled in a strange way; and when she is not moving she holds herself so still to be almost statue-like. [end if]She wears long robes, intricately stitched and trailing along the ground behind her; and long white braids descend from either side of her face, though she does not look old." The descriptor of strange alien woman is "woman". 

After greeting a strange alien woman for the first time, say "She looks uncertain and does not seem to understand, but a moment later a look of comprehension and confidence comes into her eyes and she authoritatively responds, [greeting text of Treeworld Hivemind]".

After greeting a strange alien woman: say "After a moment's uncertainty, that strange look of preternatural knowledge comes into her eyes again, and she says [greeting text of Treeworld Hivemind]".




Section - Avenue South

Avenue South is a room in Plateau. Instead of describing when the noun is Avenue South, say "Running straight as an arrow along a gentle slope [if dir]north [end if]to the highest point of the plateau is a wide, well-kept grassy avenue, lined by Trees. At the end of the avenue, stone stairs rise to a truly enormous Tree, [if we have examined t_philosopher]who must be the Great Philosopher[otherwise]massive, twisted branches reaching high into the sky[end if]. [as_exits2].". To say as_exits2: say "Brick paths run [if dir]east and west[otherwise]perpendicular to the avenue, towards either a dome or some huts[end if], and around the reflecting pool[if dir] to the south[end if]". Understand "avenue" as Mural Center.

The exits text of Avenue South is "A great grassy avenue runs [if dir]north [end if]towards a massive Tree. [as_exits2]"

A teenaged boy is a Lacunite in Avenue South. The descriptor of teenaged boy is "teenager".

Report going east from Avenue South: say "You follow the worn but immaculately tended brick path [if dir]east [end if]through a light forest, towards a series of low structures ahead."

Section - Among the Huts

Among the Huts is a room in Plateau. Instead of describing when the noun is Among the Huts, say "Scattered around the trees here are a few dozen simple structures, not quite as high as your head and made of brick and thatch. [exits]." The exits text of Among the Huts is "The path weaves through the cluster of huts, [if dir]continuing east and west[otherwise]heading back towards the avenue or further into the forest[end if]." Understand "further" or "forest" as Mural Far East.

Some structures are scenery in Among the Huts. Understand "hut" or "huts" as structures. The description is "Though carefully constructed and maintained, the huts are humble in design." Instead of entering structures, try going south.

Report going to Bare Hut: say "You pull aside the straw doorway of one of the huts and, ducking your head, step inside."

A small child is a man in Among the Huts. "A boy, maybe two years old, plays on the grass outside one of the huts." The description is "Other than sharing the skin color and general facial features of the adults you've seen, he seems just like the children you're used to." Instead of greeting in the presence of the small child, say "The child stops playing and looks at you curiously as you begin to speak. He waves a tiny hand at you and giggles." Understand "boy" or "baby" as the child. Instead of taking the child, say "You hoist the boy up in your arms. He is surprisingly light. As you bounce him up and down, he laughs, and reaches out to touch your face. After a moment he grows restless, so you lower him back down to the ground." Instead of touching the child, say "You reach out and toussle the boy's hair, soft and blonde. He scrunches up his face and puts his hand to his head, grabbing a tuft of hair and twirling it."

Bare Hut is a room in Treeworld. Instead of describing when the noun is Bare Hut, say "Your eyes adjust slowly to the dimness in this simple hut"



Section - The Mural

The great slab is a backdrop. The slab is not scenery. The initial appearance is "[if location is Mural Far East]Running straight to the edge of the cliff is[end if][if location is Mural Far West]Rising from the ground near the edge of the trees is[end if][if location is Mural West or location is Mural East]Bisecting the meadow is[end if][if location is Mural Center]Stretching from either side of the spire is[end if] [slab]." The great slab is in Mural Far West, Mural West, Mural Center, Mural East, and Mural Far East. Understand "mural" or "rock" as the slab. 

Definition: a thing is unexamined if we have not examined it.

To say slab:
	if Mural Far West is unvisited and Mural West is unvisited and Mural East is unvisited and Mural Far East is unvisited, say "a great slab of rock"; otherwise say "the rock slab";
	if great slab is unexamined, say ", covered with an incredibly detailed series of etchings";
	if we have examined the great slab exactly once, say ", inscribed with the history of this world";
	say ". It continues ";
	if dir, say "[if location is not Mural Far East]east [end if][if location is not Mural Far East or Mural Far West]and [end if][if location is not Mural Far West]west [end if] through";
	otherwise say "down the center of";
	say " the meadow";	

Before examining the great slab for the first time, say "You step closer to the rock slab, which rises a head shorter than you, and are taken aback by the level of detail. Each square foot of this enormous wall must have taken months of work. Even the finest details are etched, and color and precious stones are inlaid for highlights."

The description of the slab is "[if location is Mural Far West]The first panel depicts a forest of hundreds of Lacuna trees, each twist and curve in every branch chiselled faithfully into the rock. As you follow the mural east, incredibly faint golden lines begin to connect the trees. The lines quickly multiply and become thicker and stronger, and begin to connect to abstract patterns of gold hovering in the sky above the Trees that grow more and more complex.[end if][if location is Mural West]A single tree stands out on this panel, with large-eyed men crawling over and around it. On the farthest branch, a single creature stands stricken, hand to her head and eyes open wide with awe, one tiny golden strand reaching out to touch her head.[end if][if location is Mural Center]The slab rises into a great rounded outcrop here, which shows, in giant size and incredible detail, the picture you saw on the egg on Lacuna: a man, hands outstretched and head a smooth oval, intertwined with the roots of a stretching Tree.[end if][if location is Mural East]An incredibly detailed scene is carved into the rock here. Hundreds of people, each linked to one or more trees by a tiny golden strand, labor to tend trees, carry seeds off to distant lands, and build tools, from baskets to sailing ships to microscopes and stranger vehicles. The people are linked only to the trees; never to each other.[end if][if location is Mural Far East]This part of the epic etching shows the whole planet, covered in trees, with a minutely detailed galaxy behind it. Tiny egg ships depart in all directions, each one carrying a human crew and tree seeds. A good third of the stars in the galaxy glow green, and an impossibly tiny web of golden lines connects them.[end if]".

After examining the great slab, say "[if location is Mural Far East]The mural ends here[otherwise]The mural continues [end if][if location is not Mural Far East and dir]to the east[end if][if location is not Mural Far East and not dir]towards the cliff's edge[end if][if the player has not been in Mural Far West]. It must begin [end if][if the player has not been in Mural Far West and dir]at the western end[end if][if the player has not been in Mural Far West and not dir]farther towards the forest[end if]."

Instead of describing when the noun is Mural Far West, say "Thick forest here marks the edge of [meadow]. [exits]." The exits text of Mural Far West is "The meadow heads [if dir]east [end if]towards a distant cliff, while [if dir]large structures can be seen through the trees to the southeast and northeast[otherwise]angled paths lead through the trees towards a dome and a temple[end if]. A worn path heads [if dir]south [end if]back to the reflecting pool". Understand "path" as Reflecting Pool. Understand "meadow" as Mural West. Understand "cliff" or "edge" as Mural West when location is Mural Far West.

Instead of describing when the noun is Mural West, say "Cutting through the trees, [meadow] continues [if dir]east and west[otherwise]towards the distant cliff and the forest[end if]. Tiny white flowers dot the grass here, gathering in bunches at the base of the central rock slab.". Understand "forest" as Mural Far West when location is Mural West. Understand "edge" or "cliff" as Mural Center when location is Mural West.

Instead of describing when the noun is Mural Center, say "A stone spire marks the center of the plateau, at the intersection of a wide avenue [if dir]running north/south[otherwise]connecting the great Tree with the reflecting pool[end if], and [meadow] running [if dir]east/west[otherwise]from the forest to the edge of the cliff[end if]." Understand "forest" as Mural West when location is Mural Center. Understand "edge" or "cliff" as Mural East when location is Mural Center.

Instead of describing when the noun is Mural East, say "Cutting through the trees, [meadow] continues [if dir]east and west[otherwise]towards the nearby cliff and the forest, here dense to either side." Understand "forest" as Mural Center when location is Mural East. Understand "edge" or "cliff" as Mural Far East when location is Mural East.

Instead of describing when the noun is Mural Far East, say "A sudden dropoff markes the end of [meadow]. The distant forest below glowing in the red light of the giant sun. [exits]." The exits text of Mural Far East is "Paths curve [if dir]south [end if]through the trees towards the reflecting pool and [if dir]northwest [end if] towards [if Row of Sheds is unvisited]a distant structure[otherwise]the row of sheds[end if]". Understand "forest" or "meadow" as Mural East when location is Mural Far East.

To say meadow:
	if Mural Far West is unvisited and Mural West is unvisited and Mural Center is unvisited and Mural East is unvisited and Mural Far East is unvisited, say "a long, meandering grassy meadow";
	otherwise say "the meadow".


Section - The Map Room

Outside the Dome is a room in Plateau. Instead of describing when the noun is Outside the Dome, say "A large stone domed structure rises from the forest here, made of a smooth yellow-grey rock that glows pink in the light of the great red sun. [exits]". The exits text of Outside the Dome is "An open archway leads into the dark interior of the dome, while brick pathways run east and west."

Before going inside from Outside the Dome, say "You step through the stone archway, almost bumping your head, and blink in the dim interior."

Map Room is a room. Instead of describing when the noun is Map Room, say "[if Map Room is unvisited]This large, round room seems dark and empty at first. But as your eyes begin to adjust, you gasp. Suspended in the darkness are millions of tiny points of light, sparkling quietly. As your eyes adjust further, you begin to make out its shape: that of an entire galaxy.[otherwise]The dim galaxy fills this large, round room completely, shimmering quietly before you.[end if] [exits].". The exits text of Map Room is "A few carpeted steps curve around the room's circumference, making the central space under the dome seem even larger, and bright daylight shines through heavy curtains out"

The dim galaxy is a setpiece in Map Room. The description is "As you walk around the edge of the room, you take in the galaxy of stars from several angles. Only near the edges of the room can you make out individual stars, impossibly tiny points of light caught in enormous three dimensional whirls and eddies. Towards the center, they merge into one glowing sphere of light, which seems enormous though you know it must be trillions of times smaller than life." Instead of touching or taking the dim galaxy, say "You move your hand through the stars before you but feel nothing. The tiny points simply disappear as your hand passes through the space they once occupied."

Mapkeeper is a male Lacunite in Map Room. "A male Lacunite stands near the wall of the dome, hands folded before him, waiting patiently."

After greeting Mapkeeper for the first time, say "He nods to you, slowly, and says 'Welcome, traveller, to our map room. If you would like to learn more about the Forest, please, ask.'".

After greeting Mapkeeper, say "'What more can I tell you, friend?' he says.".

A beat called t_m_forest is known by Mapkeeper. Understand "forest" or "galaxy" as t_m_forest. The description is "The man stretches out his arms to encompass the floating galaxy, his red robes ripples of crimson in the twilight. 'Thousands of years ago, the first ships began their journey across the darkness between the stars,' he says. 'And now, the Trees and their People thrive on thousands of worlds across this vast galaxy. All are connected to one immense mind. 'The Forest' is what we call both the empire, and our glorious conciousness.'". In it is t_m_ships, t_m_worlds, and t_m_mind.

The description of Mapkeeper is "[a list of visible things carried by Mapkeeper]".

t_m_ships is a beat. Understand "ships", "thousands", "years", "first", "began" and "journey" as t_m_ships. The description is "In response, the man focuses for a moment, and suddenly the whole galaxy around you is moving, diving in towards a single star. You zoom in farther on a hazy, green-gold planet. From it, hundreds of tiny egg-shaped ships launch. Each accelerates towards a different point in the galaxy.

'It was a great endeavor,' the man says, 'perhaps our finest. The Trees strove for generations to design the egg ships, their propulsion and navigation systems, and the People strove to build them. Each ship carried the soil of its homeworld, the seeds of its colonizers, and the sleeping People to tend them and nurture them till they grew, and both could multiply.

'It was a glorious success,' the man adds. 'There were only a few failures.'" In it is t_m_failures.

t_m_failures is a beat. Understand "failures" and "failure" as t_m_failures. The description is "The man turns his attention to the galactic disc. Thousands of tiny worlds light up green in waves around one central star. But amongst the diaphonous shape of green are a scattering of red dots that do not glow.

'One hundred and sixty eight,' the man says. 'That is the number of ships that left this world and have not joined the Forest mind. We can only guess what happened to them. Some must have failed in flight, and still drift aimless between the stars.' He turns to you. 'But at least one ship crashed,' he says somberly, 'the People perishing and the Trees surviving, alone, frightened, and impotent.'[if we have not greeted the GP][line break]'The Great Philosopher will speak more of this to you,' the man adds, 'when you visit him.'[end if]".

A beat called t_m_lacuna is known by Mapkeeper. Understand "lacuna" as t_m_lacuna. The description is "'That world is one of the hundred and sixty-eight failures,' the man says, 'but I cannot tell you which one. We do not know.[if we have not greeted the GP][paragraph break] The Great Philosopher will speak more of this to you,' the man adds, 'when you visit him.[end if]'".

t_m_worlds is a beat. Understand "worlds", "vast", "empire", and "galaxy" as t_m_worlds. The description is "".

t_m_mind is a beat. Understand "conciousness" and "mind" as t_m_mind. The description is "'When we first crossed oceans,' the man says, 'the Trees thought long about how to keep their minds together. Finally they instructed the People in the building of devices, nodes that could connect the thoughts of the trees together instantaneously, even across the light years. In each egg ship was such a device. This is how we have remained one Forest, even across the vast reaches of space."

[ This may be hard for one like you to understand, but for a Tree, to be alone is to hardly be alive. What is thought with no Other to share it with? ]

[t_m_aliens]

Section - Temple

Instead of describing when noun is Ancient Temple, say "Rising organically above and through the trees is an ancient stone structure with such an air of reverence and solemnity that the world 'temple' immediately comes to mind. The symbol from the egg on Lacuna, of a human form intertwined with the roots of a tree, is inlaid into its front. A deep red double door opens into the interior.[paragraph break][exits]." The exits text of Ancient Temple is "Paths lead [if dir]east [end if]back to the central avenue, or [if dir]southwest [end if]towards one end of the giant mural."

Instead of describing when noun is Shrine, say ""





The GP is a person in Inside the Great Philosopher.

[
The ocean is visible from North Beach, Outside Hut, South Beach, and Rise. The mountain is visible from Rise, North Beach, Outside Hut, South Beach, and Fork.



Instead of describing when the noun is the Fork: 
	if night or raining, say "[if night]Underrr the [light source], the tropical landscape stretching before you is like something from a storybook. [a phrase about the mountain], while the crater of the volcano looms below you to the east. [A sentence about the ocean]. [end if][if raining]Inside a cloud on top of a volcano--it's like being in a dream. Rain falls around the rocky ground here at the lip of the volcano, which curves away from you gently and vanishes into the mist to your east. Below, you can see grey tendrils reach down to mingle with white puffs of steam coming up from the volcano floor, far below. [end if]";
	otherwise say "[if dawn]Only the faint sounds of lapping surf break the unnatural early morning quiet[otherwise][Time of day ambiance][end if] as you [if midday]shield your eyes from the glare, taking[otherwise]take[end if] in the [one of]whole of the island[or]this magical tropical paradise[or]your new home[sticky random] below you. From this high vantage point on the volcano's rim, it's the most striking features that catch your glance: [a phrase about the mountain]; and [a phrase about the sandy beach]. Beneath your feet to the east, steep slopes curve down to the volcano's [if sunrise or morning or evening or sunset]shadowed[otherwise]indistinct[end if] caldera, [one of]where pockets of steam rise amid jumbled rocks and moss[or]where black lava flow stretches from slope to slope[or]where jumbled rocks cause a confusion of lines and angles[sticky random]. ";
	say " [exits]".

The exits text of the Fork is "Wheee!".

North Beach is north of Outside Hut and southeast of Rise. South Beach is south of Outside Hut, northwest of Fork and northeast of Among the Boulders. A room called Hut is east of Outside Hut.

[Sirrus is a man in the Jetty. A rock and a stick are things in the North Beach. The boulder is a supporter in the Forest. The plastic bag is a closed locked transparent container in the Forest. The bird is an animal on the boulder. The sandwich and the pickle are in the plastic bag.]

Beachfront is a region. The ambiance table of Beachfront is the Table of Beach Region Ambiance. North Beach, Outside Hut, and South Beach are in Beachfront. Beachfront is in Outdoors. Fork and Rise are in Outdoors. The ambiance table of North Beach is the Table of North Beach Ambiance.

Outdoors is a region. The ambiance table of Outdoors is the Table of Outdoors Ambiance.

The x of Rise is 10. The y of Rise is 50. The x of North Beach is 20. The y of North Beach is 40. The x of Outside Hut is 20. The y of Outside Hut is 30. The x of South Beach is 20. The y of South Beach is 15. The x of Fork is 30. The y of Fork is 10. The x of mountain is 30. The y of mountain is 45.

The ocean is a view. It is everywhere. 

The sandy beach is a view. The sandy beach is everywhere.

To say a sentence about the sandy beach: 
	say "A white sand beach [if sunup]glistens[otherwise]arcs in a graceful curve[end if] in the [if sunset or evening]setting sun[end if][if dawn or twilight]faint glow of the sky[end if][if night and moonup]moonlight[end if][if night and moondown]starlight[end if][if morning or midmorning or midday or afternoon]sunlight[end if]".
	
To say a phrase about the sandy beach:
	say "in the distance, the beach stretches in a graceful arc".
	
To say a sentence about the ocean: say "Gulls soar over the distant ocean, unbroken blue stretching to the horizon."

To say a phrase about the ocean: say "a wide, blue ocean stretches to the horizon".

The mountain is a view. The mountain is everywhere.



The description of the mountain is "Dominating the northeastern corner of the island, the mountains is steep and tall, seemingly unclimbable. The rocky sides [if range of mountain is near]seem to be composed of sharp volcanic rock[otherwise]are black and smooth[end if].[if the range of mountain is near or medium] Perched near the mountain's summit is a round, domed building that looks like an observatory.[end if]".

To say a sentence about the mountain:
[	if the mountain has not been examined, say "A large, craggy mountain looms up into the clouds." instead;]
	say "The mountain, at a [range of mountain] range, is jauntily attired [if evening or sunset]in the fiey glow of the fading sun[end if][if sunrise]in shadows as the sun rises behind it[end if][if moonup]in a pillowy glow of moonlight[end if].".
	
To say a phrase about the mountain:
	say "[one of]the northeast mountain rises triumphantly over the landscape[or]like a titan, the mountain on the northeast corner lords over the island[or]the mountain continues its rocky vigil to the northeast[sticky random]".


Table of Wind Ambiance
frequency	text	table	trigger	flag
common	"Wind rustles your hair."
common	"A gust of wind blows by, raising tiny eddies."
rare		"An intense gust of wind blows by."

Table of Outdoors Ambiance
frequency	start time	end time	text	table		trigger	flag
rare		midday	--		"The sun beats down hotly from above."	table-name	thing		number
rare		midmorning	afternoon	--	Table of Wind Ambiance
common	moonrise	--	"On the eastern horizon, [moon description] rises above the water."
common	moonset	--	"Off to the west, [moon description] touches the water."

Table of Seagull Ambiance
frequency	text	table	trigger	flag
common	"A flock of seagulls soars gracefully overhead."
common	"Two mangy looking seagulls eye each other warily."
uncommon		"A seagull buzzes by your head."
uncommon		"A cluster of seagulls preen themselves on a rocky outcrop."

Table of Surf Ambiance
frequency	text	table	trigger	flag
common	"A wave crashes to short."
common	"Waves lap around your ankles."

Table of Seaweed Ambiance
frequency	text	table	trigger	flag
common	"Some seaweed washes in to shore."
common	"Flies buzz around drying seaweed lying on the beach."

Table of Beach Region Ambiance
frequency	start time	end time	text	table		trigger	flag
common	--		--		--	Table of Surf Ambiance
common	sunrise	sunset	--	Table of Seagull Ambiance
superrare	evening	sunset	"Far out to see, a whale crests and blows air into the sky in a spectacular shower of mist."
uncommon		--	--		--	Table of Seaweed Ambiance
frequent	--	--	"Another wave crashes against the rocks, sending spray everywhere."

Table of North Beach Ambiance
frequency	start time	end time	text	table		trigger	flag	
rare		sunrise	sunset	"The door of the hut flaps open and closed in the breeze."
rare		--		--		"Wind whirls sand around the door of the hut, making tiny drifts and eddies."
uncommon		high tide	--	"The tide is high."

Large boulder is a setpiece in North Beach.
]

Treehouse is a room. Sloping Meadow is a room. Rim of Volcano is a room.